обращение к переменной мувиклипа из функции...

[zeus_sk]

посмотрите код внизу...
программно создаю мувиклип mc1...
внитри mc1 программно создаю клип test...
внутри mc1["test"] присваиваю переменной slovo значение "Hello world!"...
в test подгружаю картинку через loadMovie...
функция myDraw просто должна значение mc1["test"].slovo через trace...

при прямом вызове myDraw выводит значение, а при вызове myDraw из другой функции пишет undefined...

в чем проблема?


import flash.display.BitmapData;

var mc1:MovieClip = _root.createEmptyMovieClip('mc1',_root.getNextHighestDepth());
mc1.createEmptyMovieClip("test",mc1.getNextHighestDepth());

mc1["test"].slovo='Hello world!'; //можно ли так делать??????
mc1["test"].loadMovie("img.jpg");

function myDraw(mc:MovieClip) {
mc._x+=10;
trace(mc["test"].slovo);
}

myDraw(mc1); // Hello world!
_root.onMouseDown = function() {
myDraw(mc1); // undefined
}

[iNils]

Вот эту строчку уберите и будет работать :D
mc1["test"].loadMovie("img.jpg");

[zeus_sk]

Вот эту строчку уберите и будет работать :D
mc1["test"].loadMovie("img.jpg");
:) а если серьезно???
мне нужно туда подгрузить картинку )) просто необходимо... )

[Molecula]

Очень напоминает:
Забегает мужчина к хирургу в кабинет и кричит:
- Доктор, доктор, у меня в ухе отвертка, что делать?
Хирург смотрит - действительно отвертка торчит.
Он её резко выдергивает и втыкает ему в глаз:
- Голубчик, у меня рабочий день закончился, идите к окулисту, он до 19:00 работает.

Вам loadMovie действительно не стоит использовать, и вот это:
mc1["test"].slovo='Hello world!';
Не в том месте вставляете.
Для начала используйте MovieClipLoader для загрузки картинки.

Если у Вас большие вложения, используйте ссылку:
var test:MovieClip = mc1.createEmptyMovieClip("test",mc1.getNextHighestDepth());
test._id=someThing;

Что бы не писать таких длинных фраз - mc1["test"]...
И как то странно, что Вы пытаетесь строковую константу присвоить динамически созданному св-ву мувика.

[udaaff]

Создайте в mc1["test"] контейнер и грузите картинку туда.

[Molecula]

Так он же test в mc1 создал, что бы в test грузить.

[zeus_sk]

люди... помогите мне просто понять, почему при вызве функции myDraw из другой функции происходит так?
причем trace(mc["test"]) выводит _level0.map.test..

пробовал MovieClipLoader... не помогло

[iNils]

Смысл общий такой.
Все содержимое мувиклипа: графика, свойства и методы определенный пользователем, сразу после инициализации загрузки удаляется. Но сама загрузка происходит асинхронно выполнению кода. И именно поэтому, хотя вы и вызвали loadMovie, он не сразу удалил свойство slovo, а через некоторое время, поэтому прямой вызов myDraw дал результат, а вызов при нажатии уже нет.
Есть два варианта:
1. Использовать MovieClipLoader и назначать slovo после окончания загрузки в событии onLoadInit
2. Загружать не в mc1.test, а создать клип-контейнер mc1.img и грузить туда, а slovo хранить в том же mc1.test (хотя что мешает грузить в mc1.test, а slovo хранить в mc1?)

[zeus_sk]

iNils


myDraw(mc1); // Hello world!
setTimeout(trace,1000,mc1["test"].slovo); // Hello world!
setTimeout(myDraw,2000,mc1); //undefined
setTimeout(trace,3000,mc1["test"].slovo); // Hello world!

а вот так? напрямую mc1["test"].slovo доступно и через 3 секунды и через 10.... а вот при вызове из другой функции undefined

[iNils]

Весь код полностью приведите. А то вот такой вариант, везде дает Hello world!
var mc1:MovieClip = _root.createEmptyMovieClip ('mc1', _root.getNextHighestDepth ());
mc1.createEmptyMovieClip ("test", mc1.getNextHighestDepth ());
mc1["test"].slovo = 'Hello world!';
function myDraw (mc:MovieClip) {
mc._x += 10;
trace (mc["test"].slovo);
}
myDraw (mc1);
setTimeout (trace, 1000, mc1["test"].slovo);
setTimeout (myDraw, 2000, mc1);
setTimeout (trace, 3000, mc1["test"].slovo);

[zeus_sk]

с клип лоадером получилось.....
но вот этот код не понятен... просто хочется вникнуть в эту магию)


var mc1:MovieClip = _root.createEmptyMovieClip ('mc1', _root.getNextHighestDepth ());
mc1.createEmptyMovieClip ("test", mc1.getNextHighestDepth ());
mc1["test"].slovo = 'Hello world!';
mc1["test"].loadMovie("img.jpg"); // вот эта строка вносит непонятки
function myDraw (mc:MovieClip) {
mc._x += 10;
trace (mc["test"].slovo);
}
myDraw (mc1); // Hello world!
setTimeout (trace, 1000, mc1["test"].slovo); // Hello world!
setTimeout (myDraw, 2000, mc1); // undefined
setTimeout (trace, 3000, mc1["test"].slovo); // Hello world!

[iNils]

Пример.
a = 555;
function test (val) {
trace (val);
}
function test2 () {
trace (a);
}
test (a); // 555
setTimeout (trace, 1000, a); // 555
setTimeout (test, 2000, a); // 555
setTimeout (test2, 3000); // 444
a = 444;
test (a); // 444
При вызове через setTimeout указывается значение аргемнта, а не ссылка на него. Поэтому синий код дает 555, а если использовать желтый и ссылку, то 444