Жирный текст, без видимого тега <b>

[getelse]

Салют флешерам!

Есть текстовое поле(input) с текстом
При выделении фрагмента текста и нажатии определенной кнопки фрагмент заключается в тег <b>

до
фрагмент текста

после
<b>фрагмент текста</b>

Можно ли, сделать так, чтобы после нажатия кнопки(заключения в тег),
текст в текстовое поле(input) выглядел так(без тегов, просто жирно (но теги как бы существовали))

вот
фрагмент текста

Спасибо!

[udaaff]

Они никуда и не исчезают:
var txt:TextField = createTextField("txt", 0, 0, 0, 200, 100);
txt.html = true;
txt.htmlText = "<b>asdf</b>";
trace(txt.htmlText)

[getelse]

Спасибо.

[getelse]

Простите, за мой второй пост подряд.
Создается dynamic текстовое поле, и там текст жирный и без тегов(как надо)
А, можно сделать чтобы было input текстовое поле с жирным текстом без тегов(так же)

а то в dynamic TextField Жирный текст
а в input TextField <b> Жирный текст <b>

Чтобы в input стало как в dynamic (жирно - без тегов)

[udaaff]

Можно, а в чем проблема то?

[getelse]

Что-то вроде этого
http://img-fotki.yandex.ru/get/3704/l576.0/0_1456b_1ba42ef9_orig.gif

[udaaff]

Символы < > и иже с ними заменяются на html сущности, когда вы их вводите. Нет смысла реализовывать вариан, который вы показали. Обычно текст сначала выделяется мышкой, а затем уже выделенный фрагмент, допустим, при нажатии на кнопку, берется в теги. Т.е. получаем начальный и конечный индексы выделения, и затем правим свойство htmlText.

[getelse]

Спасибо за ответ.
Есть такое дело, выделенный фрагмент текста после нажатия на кн. заключается в тег <b>.
Как включить html отображение текста для input TextField?
(т. е. отображение без тегов)

[udaaff]

Мне только один вариант в голову пришол:
1. Получаете индексы.
2. Вставляете на эти позиции в свойстве text какие-нибудь маркеры. Символы, которые не заменяются на сущности.
3. Затем ищите их в свойтве htmlText, и заменяете на соответствующие теги.

[getelse]

Спасибо.
Вот есть флешка.
fla (http://narod.ru/disk/12428845000/button.fla.html)
swf (http://narod.ru/disk/12428850000/button.swf.html)

Как сделать так, чтобы обычный button, выполнял ту же функцию,
что и флеш компонент button?


var mouseListener:Object = new Object();
mouseListener.onMouseUp = function() {
if (getProperty(Selection.getFocus(), _name) == "input_txt") {
_global.beginIndex = Selection.getBeginIndex();
_global.endIndex = Selection.getEndIndex();
}
};
Mouse.addListener(mouseListener);
var styleListener:Object = new Object();
styleListener.change = function(eventObj:Object) {
Selection.setFocus(null);
applyStyle(eventObj);
};
styleListener.click = function(eventObj:Object) {
applyStyle(eventObj);
Selection.setFocus(input_txt);
Selection.setSelection(_global.beginIndex, _global.endIndex);
};
bold_button.addEventListener("click", styleListener);
function applyStyle(eventObj:Object) {
var my_fmt:TextFormat = input_txt.getTextFormat(_global.beginIndex);
switch (eventObj.target._name) {
case 'bold_button' :
my_fmt.bold = !my_fmt.bold;
break;
}
input_txt.setTextFormat(_global.beginIndex, _global.endIndex, my_fmt);
}


подробнее в fla и swf.

Еще раз спасибо.

[udaaff]

bold.onRelease = bold_onReleaseHandler;
bold.onReleaseOutside = bold_onReleaseHandler;

function bold_onReleaseHandler():Void
{
var my_fmt:TextFormat = input_txt.getTextFormat(_global.beginIndex);
my_fmt.bold = !my_fmt.bold;
input_txt.setTextFormat(_global.beginIndex, _global.endIndex, my_fmt);
}
Именно эти же функции ни к чему.

[getelse]

Именно эти же функции ни к чему.
Ты прав
http://tbn3.google.com/images?q=tbn:nBB_l-pAXlJWlM:http://forum.qip.ru/customavatars/avatar9078_1.gif

[udaaff]

var txt:TextField = createTextField("txt", 0, 0, 0, 200, 200);
txt.text = "asdf";
var fmt:TextFormat = new TextFormat();
fmt.bold = true;
txt.setTextFormat(fmt);
txt.html = true;
trace(txt.htmlText);

//<P ALIGN="LEFT"><FONT FACE="Times New Roman" SIZE="12" COLOR="#000000" LETTERSPACING="0" KERNING="0"><B>asdf</B></FONT></P>

Почему-то совсем и не подумал, что простое форматирование текстформатом в html тексте отобразиться... Так что способ с маркерами, конечно же бредятина, который я предложил. Хотя и рабочий.

[getelse]

Так правильно, для текста который нах. в скрипте
или напечатан внутри Input TextField - до ctrl enter(до создания swf)

Как же сделатьa, так:

есть:
Input TextField, name - txt;
button name - butt //заключение выделенного фрагмента текста(Input TextField) в тег <b>

В swf (после ctrl enter) печатаю текст, выделяю фрагмент и нажимаю кн. butt
текст заключается в тег <b> и отображается так <b>Текст</b>,
а надо чтобы отображался, так Текст.
Т. е. кн. butt заключала его в тег <b>, а в Input TextField он отображался жирным(без тегов).

http://img-fotki.yandex.ru/get/3703/l576.0/0_145d6_d30f8313_orig.gif

[mooncar]

Сделать-то так легко, но одноразово (см. вложение).
То есть один раз написали текст - один раз обозначили все болды. А вот как сделать так, чтобы было возможным дальнейшее редактирование....

UPD: В приведенном мною примере только одно выделение можно сделать, а даже не "все болды".. Нужно как-то организовать конвеер для таких выделенеий.

[mooncar]

bold_btn.onRelease = function () {
doBold();
};

function doBold() {
input_tf.html = false ;
var startIndex:Number = Selection.getBeginIndex();
var endIndex:Number = Selection.getEndIndex();
var stringToBold:String = input_tf.text.substring(startIndex, endIndex);
if (startIndex != endIndex) { //чтобы не вставилось пустое место, обрамленное <b></b>
input_tf.replaceText(startIndex, endIndex, '<b>' + stringToBold + '</b>');
}
input_tf.html = true ;
input_tf.htmlText = input_tf.text ;
}

[udaaff]

Нужно как-то организовать конвеер для таких выделенеий.
Выделять текстформатом.

[mooncar]

Выделять текстформатом.
Поясните.

[udaaff]

Смотри пример в 13 посте.

[mooncar]

Немного не понимаю, что это дает. Форматировать с пом. TextFormat мы же можем только все поле целиком?
UPD: Вопрос снимается, ступил.

[udaaff]

public setTextFormat([beginIndex:Number], [endIndex:Number], textFormat:TextFormat) : Void

[getelse]

что получилось та?

[getelse]

Ребят, я что-то с тех пор не соображу.

Вот флешка
site (http://www.city.tu2.ru/index.html)

После выделения текста и нажатия кн. Ж, текст заключается в тег <b>,
а надо чтобы он становился жирным(без тегов),
а если его сохранить, в файле выглядел с тегом <b>

zip(fla,swf,html,php) (http://narod.ru/disk/13052417000/fox.exe.html)

[KiL33]

txt_input.onChanged = getIndexs;
var mouseListener:Object = new Object();
mouseListener.onMouseUp = getIndexs;
Mouse.addListener(mouseListener);
function getIndexs(){
if(Selection.getBeginIndex() != -1 && Selection.getEndIndex() != -1){
startIndex= Selection.getBeginIndex();
endIndex= Selection.getEndIndex();
}
}

function checkFormat(val, startIndex, endIndex):Boolean{
var my_fmt:TextFormat = txt_input.getTextFormat(startIndex,endIndex);
return my_fmt[val];
}

function doChange(val):Void {
var stat:Boolean;
stat = (checkFormat(val, startIndex, endIndex)) ? false: true;
var format2_fmt:TextFormat = new TextFormat();
format2_fmt[val] = stat;
txt_input.setTextFormat(startIndex,endIndex,format2_fmt);
setSelection();
}


///button
var btn:MovieClip = this.createEmptyMovieClip("btn", 3);
btn.beginFill(0xFF0000);
btn.moveTo(10,10);
btn.lineTo(160,10);
btn.lineTo(160,40);
btn.lineTo(0,40);
btn.lineTo(0,10);
btn.endFill();
btn._y = 210;
btn._x = 0;

var my_fmt:TextFormat = new TextFormat();
var pole_txt:TextField = btn.createTextField("pole_txt", 4, 120, 15, 0, 0);
pole_txt.autoSize = true;
my_fmt.color = 0xFFFFFF;
my_fmt.size = 14;
pole_txt.html = true;
pole_txt.htmlText = '<b>Ж</b>';
pole_txt.setTextFormat(my_fmt);
btn.onPress = function(){
doChange("bold");
}

txt_input=this.createTextField("txt_input",2,10,10,300,200);
var my_fmt_input:TextFormat = new TextFormat();
txt_input.border=true
txt_input.type = "input"
txt_input.html = true;
txt_input.setTextFormat(my_fmt_input);

[getelse]

Спасибо за код, KiL33

Единственно, после сохранение текста(with php), вот:

Допустим текст TextField:
Черный виноград

сохраняемый(енный) текст(в файле) выглядит так
Черный виноград

А надо чтобы(сохраняемый текст) выглядел так (как раньше)
Черный <b>виноград</b>

Как сделать так?

[KiL33]

По идеи так надо
var my_lv:LoadVars = new LoadVars();
var my_ret:LoadVars = new LoadVars();

function save_txt_file(){
url="http://localhost/www/save_txt.php";

my_lv.save_txt = txt_output.text

my_lv.sendAndLoad(url, my_ret, "GET");
my_ret.onLoad = function(){
trace(my_lv.save_txt)
}
}

txt_input.onChanged = getIndexs;
var mouseListener:Object = new Object();
mouseListener.onMouseUp = getIndexs;
Mouse.addListener(mouseListener);
function getIndexs(){
if(Selection.getBeginIndex() != -1 && Selection.getEndIndex() != -1){
startIndex= Selection.getBeginIndex();
endIndex= Selection.getEndIndex();
}
txt_output.text=txt_input.htmlText

}

function checkFormat(val, startIndex, endIndex):Boolean{
var my_fmt:TextFormat = txt_input.getTextFormat(startIndex,endIndex);
return my_fmt[val];
}

function doChange(val):Void {
var stat:Boolean;
stat = (checkFormat(val, startIndex, endIndex)) ? false: true;
var format2_fmt:TextFormat = new TextFormat();
format2_fmt[val] = stat;
txt_input.setTextFormat(startIndex,endIndex,format2_fmt);
setSelection();
}


///button
var btn:MovieClip = this.createEmptyMovieClip("btn", 3);
btn.beginFill(0xFF0000);
btn.moveTo(10,10);
btn.lineTo(160,10);
btn.lineTo(160,40);
btn.lineTo(0,40);
btn.lineTo(0,10);
btn.endFill();
btn._y = 210;
btn._x = 0;

var my_fmt:TextFormat = new TextFormat();
var pole_txt:TextField = btn.createTextField("pole_txt", 4, 120, 15, 0, 0);
pole_txt.autoSize = true;
my_fmt.color = 0xFFFFFF;
my_fmt.size = 14;
pole_txt.html = true;
pole_txt.htmlText = '<b>Ж</b>';
pole_txt.setTextFormat(my_fmt);
btn.onPress = function(){
doChange("bold");
}
//
var btn_sav:MovieClip = this.createEmptyMovieClip("btn_sav", 5);
with(btn_sav){
beginFill(0xFF0000);
moveTo(10,10);
lineTo(160,10);
lineTo(160,40);
lineTo(0,40);
lineTo(0,10);
endFill();
_y = 250;
_x = 0;
}
var my_fmt_sav:TextFormat = new TextFormat();
var pole_txt:TextField = btn_sav.createTextField("pole_txt", 4, 35, 15, 0, 0);
pole_txt.autoSize = true;
my_fmt_sav.color = 0xFFFFFF;
my_fmt_sav.size = 14;

pole_txt.html = true;
pole_txt.htmlText = '<b>Сохранить</b>';
pole_txt.setTextFormat(my_fmt_sav);
btn_sav.onPress = save_txt_file
//


txt_input=this.createTextField("txt_input",2,10,10,300,200);
var my_fmt_input:TextFormat = new TextFormat();
txt_input.border=true
txt_input.type = "input"
txt_input.html = true;
txt_input.setTextFormat(my_fmt_input);
//
txt_output=this.createTextField("txt_output",6,320,10,200,200);
txt_output.wordWrap = true;
txt_output.border=true
//txt_output.html=true

<?php
session_start();
$result_name=strip_tags($_GET['save_txt']);

$newitems =$result_name;

$items = $newitems . file_get_contents('bold.txt');
file_put_contents('bold.txt', $items);
?>

НО не работает. Теги распознаются либо не корректно, либо вообще не сохраняются..

[getelse]

Молодец KiL33 +

А как сделать чтобы в swf - в txt_output вместо всего этого:
<TEXTFORMAT LEADING="2"><P ALIGN="LEFT"><FONT FACE="Verdana" SIZE="11" COLOR="#404040" LETTERSPACING="0" KERNING="0">Черный <B>виноград</B></FONT></P></TEXTFORMAT>

отображалось только это
Черный <B>виноград</B>

[Жень Шень]

На demiart.ru я дал неполный вариант. Здесь же более доработанный.
Единственное, что надо сделать, просчитать ситуацию, когда выделен как болд и первый символ.

[KiL33]

Жень Шень, здравствуйте.
Меня интересует такой вопрос, почему при сохранении в текстовый файл теги не сохраняются? (в приведенном мною примере)

[getelse]

Салют, Жень Шень

Ваш код, можно применить

bold <b>
italic <i>
underline <u>

А что если из выделенного текста, нужно сделать линк(ссылку)?

[Жень Шень]

А что если из выделенного текста, нужно сделать линк(ссылку)?
Привет!
Если одно выделение - то просто.
А а на счет применить, то до всего, что выдает setTextFormat
this.createTextField("dyn_txt", this.getNextHighestDepth(), 0, 0, 100, 200);
dyn_txt.text = "Frank";
dyn_txt.setTextFormat(new TextFormat());
var my_fmt:TextFormat = dyn_txt.getTextFormat();
for (var prop in my_fmt) {
trace(prop+": "+my_fmt[prop]);
}

[getelse]

Имеется в виду, как добавлять что-то вроде этого:
<a href="http:// + Выделеный текст + " target="_blank">link</a>

А отобржалось это так: link

[Жень Шень]

Ну, тогда два стринга: один отображаемый (на нем выделять), другой в памяти держать (который с линком будет). А манипулировать в том же духе - в массиве помнить координаты выделения. Если только это будет одна замена: болда на линк. Если будет и другое форматирование, то надо искать что-то другое.
To Kil33
почему при сохранении в текстовый файл теги не сохраняются?
PHP не мой конек (а жаль!). Но, думаю, дело в нем. Например, если на сайте выделить текст и сохранить в Ворде, то сохранится и форматирование. Другое дело Блокнот - сохраняет только как текст. Возможно и PHP так поступает. Может скобки тегов заменить на "&код"?

[KiL33]

Может скобки тегов заменить на "&код"?
В таком варианте сохраняет, но ведь потом придется париться, чтобы флеш при загрузке переварил эти строки.

[getelse]

Для Вас это легко, а для меня пока сложно.

Ну, тогда два стринга: один отображаемый (на нем выделять), другой в памяти держать (который с линком будет). А манипулировать в том же духе - в массиве помнить координаты выделения. Если только это будет одна замена: болда на линк.

извините за назойливость,
не могли бы вы показать, как этот код, примерно, будет выглядеть.?

[KiL33]

Если сохранять в текстовый файл с помощью Цинка, то все теги сохраняются корректно видимо дело действительно в ПХП.

Добавлено через 7 часов 55 минут
to getelse
Я ступанул с ПХП функцией. В strip_tags необходимо было указать второй аргумент при котором тег выделения <b> не будет удоляться. Спасибо etc за внимательность.

<?php
session_start();
$result_name=strip_tags($_GET['save_txt'],'<b>');

$newitems =$result_name;

$items = $newitems . file_get_contents('bold.txt');
file_put_contents('bold.txt', $items);
?>

И все дела.

[codfelix]

И у меня с ссылкой проблема
Как сделать, чтобы выделенный текст становился ссылкой?

есть 3 кнопки для изменения выделенного текста
жирность, курсив, ссылка.
первые две реализовал.
А последнею, ни как не получается.

[KiL33]

Можно так

var outputTextField:TextField;
var startIndex:Number;
var endIndex:Number;
var txt:String;
btn.onPress = rep_select;
function rep_select():Void {
startIndex = Selection.getBeginIndex();
endIndex = Selection.getEndIndex();
txt = outputTextField.text.substring(startIndex, endIndex);
trace(txt);
outputTextField.replaceText(startIndex,endIndex,'<a href="'+txt+'"></a>');
}

А вообще смотрите последний пост dimarik'a

http://www.flasher.ru/forum/showthread.php?t=127441&highlight=var+pattern%3A+String+%3D+%27%26lt%3Ba+href%3D%7Bs%7D%26gt%3B%26lt%3B%2Fa%26gt%3B%27%3B&page=2

[codfelix]

Спасибо KiL33

Но, я говорю не совсем об этом.

Как сделать, чтобы в одном TextField (после выд. и нажатия кн.) отображалось так:
link

А в другом TextField отображалось так (как писал getelse)
<a href="http:// + Выделенный текст + " target="_blank">link</a>

Как в примере Жень Шень в 28 посту 28 (http://www.flasher.ru/forum/showpost.php?p=850903&postcount=28), только здесь, выделенный текст, становился бы ссылкой(линком)(кликабельный текст) в одном TextField, а не просто жирным текстом.

[Жень Шень]

Обратите внимание на asfunction - должени помочь (в ХЭЛПе хорошо описано).
1. Вставляете вместо тега <b> <a href=\"asfunction:playMP3,track1.mp3\">
2. Lалее текст link меняете на <b>link</b></a>
Естественно, заменить линк.
У меня небольшая запарка на работе - заглядываю на форум буквально на мунуты, так что готовый пример не прикладываю.

[codfelix]

Спасибо за наводку Жень Шень
Может я не до конца понимаю
Но ведь, так сказать 'layMP3' у меня всегда разный, смотря какой текст выделен?
здесь же ведь нельзя задать его через function
Как быть?

Добавлено через 9 часов 42 минуты
Вот скрипт Жень Шеня, только если теперь
выделить текст и нажать на кнопку bold
выделенный текст становится подчеркнутым //(в TextField name: txt_txt)
и если нажать кнопку send заключается в
<a href="http:// + Выделеный текст + " target="_blank">link</a> //(в TextField name: t1_txt)

Единственно, как сделать чтобы link(в TextField name: txt_txt) был кликабельный?

Вот код (Спасибо Жень Шень)


var arr:Array = [];
var n = 0;
var m = arr.length/2-1;
Selection.setFocus("txt_txt");
Selection.setSelection(arr[n], arr[n+1]);
//
function getIndexs() {
if (Selection.getBeginIndex() != -1 && Selection.getEndIndex() != -1) {
startIndex = Selection.getBeginIndex();
endIndex = Selection.getEndIndex();
}
}
function checkFormat(val, startIndex, endIndex) {
var obj1 = txt_txt.getTextFormat(startIndex, endIndex);
return (obj1[val]);
}
function doChange(val) {
var varBoolen;
varBoolen = checkFormat(val, startIndex, endIndex) ? (false) : (true);
var obj1 = new TextFormat();
obj1[val] = varBoolen;
txt_txt.setTextFormat(startIndex, endIndex, obj1);
setSelection();
}
txt_txt.onChanged = getIndexs;
var mouseListener = new Object();
mouseListener.onMouseUp = getIndexs;
Mouse.addListener(mouseListener);
//
function calculatePositionBold() {
arr = [];
var changing:Boolean = false;
for (var i:Number = 0; i<txt_txt.text.length; i++) {
var fmt:TextFormat = txt_txt.getTextFormat(i, i+1);
var fmtc = fmt.underline;
if (fmtc == 0 && changing == true) {
arr.push(i);
changing = false;
} else if (fmtc != 0 && changing == false) {
arr.push(i);
changing = true;
}
}
if (changing == true) {
arr.push(txt_txt.text.length+1);
changing = false;
}
}
//calculatePositionBold();
//
btn.onPress = function() {
doChange("underline");
};
mb.onPress = function() {
t1_txt.text = "";
calculatePositionBold();
ss = txt_txt.text;
ss = pars(ss);
t1_txt.text = ss+"\n\n\n А это координаты выделения "+arr;
};
function pars(ss) {
var l = arr.length;
var arr2:Array = [];
if (arr[0] != 0) {
for (i=0; i<l; i += 2) {
arr2[i] = ss.substring(i, arr[i]);
arr2[i+1] = "<a href = 'http://"+ss.substring(arr[i], arr[i+1])+"'>link</a>";
}
trace(i)
arr2[i] = ss.substring(arr[i-1],arr[l]);
}
return (arr2.join(""));
}


Добавлено через 24 часа 21 минуту
Друзья Флешеры, очень нужна Ваша помощь.

[getelse]

Кто-нибудь, может помочь решить эту проблему 28 (http://www.flasher.ru/forum/showpost.php?p=850903&postcount=28)
__________________________
Единственное, что надо сделать, просчитать ситуацию, когда выделен как болд и первый символ.

[codfelix]

Помогите дописать парсер

Вот по этому принципу (код FaMinor)
Для кнопки сенд нужно дописать парсер.
Принцип его такой:
Для формирования строки для отправки создается 2 массива. В первом (arr) записываюся координаты начала применения любых тегов.
Во второй (arrBI) - признак набора тегов.
Если признак = 1 - то это болд
Если признак = 2 - то это италик
Если признак = 3 - то это болд и италик
Если признак = 0 - теги были закрыты.
Останется согласно первого массива разбить весь текст на куски и согласно вторго раставить теги. При этом следует следить когда теги открываются и когда закрываются. Для этого ввести еще 2 переменные в которых фиксировать состояние тегов.

Код флешки
var arr:Array = [];
var arrBI:Array = [];
var n = 0;
var m = arr.length/2-1;
Selection.setFocus("txt_txt");
Selection.setSelection(arr[n], arr[n+1]);
//
function getIndexs() {
if (Selection.getBeginIndex() != -1 && Selection.getEndIndex() != -1) {
startIndex = Selection.getBeginIndex();
endIndex = Selection.getEndIndex();
}
}
function checkFormat(val, startIndex, endIndex) {
var obj1 = txt_txt.getTextFormat(startIndex, endIndex);
return (obj1[val]);
}
function doChange(val) {
var varBoolen;
varBoolen = checkFormat(val, startIndex, endIndex) ? (false) : (true);
var obj1 = new TextFormat();
obj1[val] = varBoolen;
txt_txt.setTextFormat(startIndex, endIndex, obj1);
setSelection();
}
txt_txt.onChanged = getIndexs;
var mouseListener = new Object();
mouseListener.onMouseUp = getIndexs;
Mouse.addListener(mouseListener);
//
function calculatePositionBold_and_italic() {
arr = [];
arrBI = [];
var changing:Boolean = false;
var setFormat:Number = 0;
var setFormat1:Number = 0;
for (var i:Number = 0; i<txt_txt.text.length-1; i++) {
setFormat = 0;
var fmt:TextFormat = txt_txt.getTextFormat(i, i+1);
var fmtc = fmt.bold;
var fmti = fmt.italic;
if (fmtc) {
setFormat = 1;
}
if (fmti) {
setFormat += 2;
}
if (setFormat == 0 && changing == true) {
arr.push(i);
arrBI.push(setFormat);
changing = false;
} else if (setFormat>0 && setFormat != setFormat1) {
arr.push(i);
arrBI.push(setFormat);
changing = true;
} else if (setFormat>0 && changing == false) {
arr.push(i);
arrBI.push(setFormat);
changing = true;
}
setFormat1 = setFormat;
setFormat = 0;
}
if (changing == true) {
arr.push(txt_txt.text.length+1);
changing = false;
}
}
function calculatePositionItalic() {
arr = [];
var changing:Boolean = false;
for (var i:Number = 0; i<txt_txt.text.length; i++) {
var fmt:TextFormat = txt_txt.getTextFormat(i, i+1);
var fmtc = fmt.italic;
if (fmtc == 0 && changing == true) {
arr.push(i);
changing = false;
} else if (fmtc != 0 && changing == false) {
arr.push(i);
changing = true;
}
}
if (changing == true) {
arr.push(txt_txt.text.length+1);
changing = false;
}
}
btn.onPress = function() {
doChange("bold");
};
btni.onPress = function() {
doChange("italic");
};
mb.onPress = function() {
calculatePositionBold_and_italic();
trace(arr);
trace(arrBI);
};
function pars(ss) {
var l = arr.length;
var arr2:Array = [];
if (arr[0] != 0) {
for (i=0; i<l; i += 2) {
arr2[i] = ss.substring(i, arr[i]);
arr2[i+1] = "<b>"+ss.substring(arr[i], arr[i+1])+"</b>";
}
arr2[i] = ss.substring(arr[i-1], arr[l]);
} else {
arr2[0] = "<b>"+ss.substring(0, arr[1])+"</b>";
for (i=1; i<l-1; i += 2) {
arr2[i] = ss.substring(arr[i]+1, arr[i+1]);
arr2[i+1] = "<b>"+ss.substring(arr[i+1], arr[i+2])+"</b>";
}
arr2[i] = ss.substring(arr[i-1], arr[l]);
}
return (arr2.join(""));
}
function parsi(ss) {
var l = arr.length;
var arr2:Array = [];
if (arr[0] != 0) {
for (i=0; i<l; i += 2) {
arr2[i] = ss.substring(i, arr[i]);
arr2[i+1] = "<i>"+ss.substring(arr[i], arr[i+1])+"</i>";
}
arr2[i] = ss.substring(arr[i-1], arr[l]);
} else {
arr2[0] = "<i>"+ss.substring(0, arr[1])+"</i>";
for (i=1; i<l-1; i += 2) {
arr2[i] = ss.substring(arr[i]+1, arr[i+1]);
arr2[i+1] = "<i>"+ss.substring(arr[i+1], arr[i+2])+"</i>";
}
arr2[i] = ss.substring(arr[i-1], arr[l]);
}
return (arr2.join(""));
}