Удержание нажатой кнопки мыши

[Zizilk]

задача:
Имеется scrollrect, который надо сдвигать пока нажата кнопка мыши.
С использованием события Click, при каждом щелчке скролрект движется как надо, но вот как организовать контроль удержания...

ДУмал событие MOUSE_DOWN отвечает за удержание клавиши

[goodguy]

MOUSE_DOWN срабатывает единовременно, в момент когда кнопка зажата, по этому событию можно присвоить значение какой-нибудь переменной, например

var mouseDown:Boolean = false;

function onMouseDown(e:MouseEvent):void {
mouseDown = true;
}

а по MOUSE_UP менять на false

и пока переменная true таскать скроллрект

[Zizilk]

я пробовал так но поход вылетает в бесконечный цикл, надо будет проверить

Добавлено через 6 минут
на MouseDown вызывается функция fright переменная объявленная за функциями flag принимает значение 1 и вызывает функцию roll в которой цикл прокручивается пока flag==1
На MouseUP вызывается функция fdright flag присваивается значение 0, по идее цикл должен остановится, но по трассировки не смотря на то что мышь отпущена, событие отпускания мыши срабатывает, ток когда Адоб сам не остановит цикл с ошибкой.

Добавлено через 7 минут
function roll()
{
while(flag==1)
{
xs-=10;
box.scrollRect = new Rectangle(xs,ys,100,100);
trace(0);
}
}
function fright(e:MouseEvent)
{
flag=1;
roll();
trace(2);
}
function fdright(e:MouseEvent)
{
flag=0;
trace("2a");
}

[silin]

тут такое дело, специфика работы плеера: цикл в этом roll() прокрутится очень быстро очень много раз (видимо достаточно для создания ошибки), прежде чем сбросится flag по MouseUP, смысла в этом цикле нет никакого - визуальное изменение scrollRect все равно будет по окончательному результату работы цикла..
обычный подход в таких случаях это по MouseDown запускать ( по MouseUP останавливать ) какой-нибудь циклический обработчик (ENTER_FRAME, TIMER), а в нем уже что нужно, двигать тот же scrollRect, например
package
{
import flash.display.*;
import flash.events.*;
import flash.utils.*;


public class Main extends Sprite
{

private var timer:Timer = new Timer(50);
private var xs:Number = 0;
public function Main():void
{
stage.addEventListener(MouseEvent.MOUSE_DOWN, stage_mouseDown);
stage.addEventListener(MouseEvent.MOUSE_UP, stage_mouseUp);
timer.addEventListener(TimerEvent.TIMER, timer_timer);
}

private function stage_mouseUp(e:MouseEvent):void
{
timer.stop();
}

private function stage_mouseDown(e:MouseEvent):void
{
timer.start();
}

private function timer_timer(e:TimerEvent):void
{
xs -= 10;
//box.scrollRect = new Rectangle(xs,ys,100,100);
trace( "xs : " + xs );
}

}

}