Проблема с заменой содержимого Мувиклипа динамически подружаемой PNG картинкой

[phayst11]

Всем доброго времени суток! Прошу о помощи: есть мувиклип в котором происходит плавное проявление или затухание картинки через изменение альфа канала. Картинка представляет из себя изображение персонажа в формате PNG. Предполагается наличие нескольких сотен картинок, отражающих состояние персонажа, расположенных а той же папке, что и экзешник.
Код динамической загрузки изображения я нашел и реализовал. А вот как заменить картинку мувика на загруженную картинку - никак не получается. Исходник прилагаю. По возможности, предлагайте, пожалуйста код, т.к. изучать actionScript стал недавно

P.S. пишу на CS5, as 3.0.

[samana]

Я так понимаю, что вы хотите в мувике Germiona, заменить картинку, которая уже разбросана по кадрам с участием анимации появления/исчезания. Дело в том, что это проблема, так как заменить что-то в разных кадрах мувика с помощью кода - наверно можно, но очень сложно.
Так как анимация у вас простая (появление/исчезание), то лучше создайте однокадровый мувик (спрайт), и с помощью кода изменяйте его прозрачность, и изменить картинку в нём не составит труда. Лоадер, это тот же спрайт, только он умеет загружать в себя что-то.
Например:
// создаёте лоадер и заргужаете в него картинку
var pictLdr:Loader = new Loader();
loadNewImage("01.png");
//loadNewImage("02.png");
//loadNewImage("03.png");
this.addChild(pictLdr);

function loadNewImage(imageURL:String)
{
pictLdr.load(new URLRequest(imageURL));
}

//----------------------------------------------
// скорость исчезновения и появления лоадера
var speedAlpha:Number = 0.1;
// флаг контроля и исчезновения и появления лоадера, по-умолчанию лоадер неСкрыт
var isHide:Boolean=false;

//----------------------------------------------
// метод показать/скрыть лоадер плавно через альфу
function hideLoader():void
{
isHide=true;
removePictLdrEnterFrames();
if(pictLdr.alpha>0) pictLdr.addEventListener(Event.ENTER_FRAME,pictLdrHide_enterFrame);
}

function showLoader():void
{
isHide=false;
removePictLdrEnterFrames()
if(pictLdr.alpha<1) pictLdr.addEventListener(Event.ENTER_FRAME,pictLdrShow_enterFrame);
}

// ентер фреймы для исчезновения и появления лоадера, их вызывать напрямую НЕ нужно,
// используйте методы hideLoader и showLoader
function pictLdrShow_enterFrame(e:Event):void
{
pictLdr.alpha+=speedAlpha;
if(pictLdr.alpha>=1)
{
pictLdr.alpha=1;
pictLdr.removeEventListener(Event.ENTER_FRAME,pictLdrShow_enterFrame);
}
}

function pictLdrHide_enterFrame(e:Event):void
{
pictLdr.alpha-=speedAlpha;
if(pictLdr.alpha<=0)
{
pictLdr.alpha=0;
pictLdr.removeEventListener(Event.ENTER_FRAME,pictLdrHide_enterFrame);
}
}

function removePictLdrEnterFrames():void
{
pictLdr.removeEventListener(Event.ENTER_FRAME,pictLdrShow_enterFrame);
pictLdr.removeEventListener(Event.ENTER_FRAME,pictLdrHide_enterFrame);
}

//---------------------------------
// по нажатию кнопки, показываем или скрываем лоадер
stage.addEventListener(KeyboardEvent.KEY_DOWN, mtn);
function mtn(e:KeyboardEvent):void
{
if (e.keyCode == Keyboard.CONTROL)
{
if(isHide) showLoader();
else hideLoader();
}
}