Остановить (найти) интервал в подгружаемом клипе?

[wvxvw]

Вот, такая ситуация:
Подгружается SWF (в один и тот же клип), в нем setIntervalom вызывается какая-то функция. Один раз - все хорошо, второй раз - интервалов становится 2, третий раз - 3, ну и так далее. Просто clearInterval() перед setInterval() не помогает... почему-то после того, как клип выгружается, интервал остается... и достать его уже не знаю как =/

[Molecula]

Посмотреть бы на это.

[wvxvw]

Вот, упрощенный пример.
Код в loaded.swf
var itr:Number;
onEnterFrame = function(){
clearInterval(itr);
itr = setInterval(counter, 1000);
delete this.onEnterFrame;
}
function counter(){
trace(getTimer()+" interval call");
}
код в loader.swf
b_mc.onPress = function(){
_root._mc.loadMovie("loaded.swf");
}

[lowka]

Вам нужно перед загрузкой нового мувика удалять интервал внутри старого.

[Kikasso]

setTimeout.
или очищайте интервал ВНУТРИ самой функции. Передать можно параметром..
function f(intId){
clearInterval(intId);
trace ("called and killed");
}
intId = setInterval( f, 1000, intId );

[wvxvw]

Ну, это хорошо, если интервал можно найти. А если клип с сетИнтервалом не мой, и я вообще не знаю/не уверен есть ли он там. Как тогда?

[Kikasso]

http://flasher.ru/forum/showpost.php?p=636116&postcount=5

[wvxvw]

2 Kikasso:
Не... меня вполне устраивает наличие интервала, пока флешка загружена. Хотелось бы какой-то способ поудалять _любые_ интервалы которые она понасоздавала после того, как она выгрузилась...
Хотя... что-то в этом есть... можно попробовать изменить прототип так, чтобы он проверял наличие переменной, к которой был привязан.

[Kikasso]

Юзай таймауты, и сажай их каждый раз заново, если надо.

[etc]

Можно хранить номер интервала в _global (предварительно убедившись, что ролики одной версии).

[wvxvw]

__etc:
В том то вся и фишка, что номер интервала каждый раз меняется.
Ну, вот чего наворотил. Страшно, конечно, но, вроде как работает...
var intervalWatcher:Function = function (obj, itr2clear) {
trace("watcher called "+obj._width);
if (obj._width == 0) {
clearInterval(itr2clear);
clearInterval(++itr2clear);
trace("Interval "+itr2clear+" cleared");
}
return itr2clear;
};
Object.prototype.setInterval1 = function(o:Object, f:Function, t:Number) {
var i = ASnative(250, 0)(f, t);
ASnative(250, 0)(intervalWatcher, t, o, i);
return i;
};
Object.prototype.setInterval = function() {
if (typeof (arguments[0] == "function")) {
setInterval1(this, arguments[0], arguments[1]);
}
};
b_mc.onPress = function() {
_root._mc.loadMovie("loaded.swf");
};
c_mc.onPress = function() {
_root._mc.unloadMovie();
};
Только нужно придумать более универсальный способ проверки исчезновения объекта, который вызвал setInterval. Если вам прийдет в голову как - пожалуйста, не стесняйтесь =)

[etc]

Что это? Зачем это? Зачем хаки? Чем не устроил _global? Зачем вообще интервал?

[wvxvw]

__etc:
а как узнать, что это тот же интервал? а не другой, но нужный, вызваный из того же места? и, в догонку, почему такая штука не работает?
var __obj:Object = new Object(_root._mc);
trace(__obj._width);
__obj.watch("_width", widthWathcer);
var widthWathcer:Function = function(){
trace("widthWathcer");
}

[Kikasso]

ну во-первых там 3 параметра должно быть, во-вторых, поменяйте местами объявление функции и watch или пишите
function widthWathcer(p, o, n){
trace( p + " " + o + " " + n);
return n;
}
вместо var что-то = function(){}
а в третьих, геттер/сеттер на watch не поймаешь, и наконец на обжекте это сработает, при учете пп 1, 2 и 3. Достаточно п. 3

Совет прежний - передавай id интервала параметром функции.

[wvxvw]

третий параметр у watch не обязательный, а вот про геттер/сеттер не знал, спасибо.
Совет прежний - передавай id интервала параметром функции. Да как же я его узнаю, если, теоретически, его может даже и не быть? Задача в том, чтобы убрать любые интервалы, когда объект, который их созал исчез. При этом, ни их количество, ни путь к объекту, который их создавал не известны.
Т.е. представим ситуацию:
существует банерная програма, она загружает в себя SWF, и после того, как выгружает, должна удалить все, что может быть с ним связано. SWF может содержать какие угодно setInterval'ы вызванные где угодно. Как их все удалить, когда он выгрузится?

[Kikasso]

Третий параметр надо вернуть, иначе свойство будет undefined. Так-то и первый необязательный, смысла только в этом мало.
prop = "test1";
trace( prop );
this.watch("prop", trace );
prop = "test2";
trace( prop );
this.watch("prop", function(){ trace ("ep, I watch it"); } );
prop = "test3";
trace( prop );
this.watch("prop", function(p,o,n){return n;} );
prop = "test4";
trace( prop );
this.watch("prop", function(){return "it's me";} );
prop = "test5";
trace( prop );
А интервалы.. Да сажай таймауты, и продлевай.
Ну или массив ссылок на таймауты в подгружаемом клипе, а убивая клип, вызываешь что-то вроде
while ( intToKill = inrArr.pop() ) clearInterval ( intToKill );

[wvxvw]

эм... тут какое-то жестокое недопонимание =) Ну не могу я ничего сделать в подгружаемой флешке, я ее вообще не делал и не хочу. Мне готовую принесли =) А мне нужно после того, как она выгрузится из моей, поубивать все интервалы, которые она создала. Конечно. я могу попросить человека, который ее делал переписать что-то, чтобы мне было проще... но не хочется, чужая работа - все-тки деньги =)

[Kikasso]

_global.idsArray = [];
ASSetPropFlags(_global, [setInterval], 0, 7); //оказалось - не нужно
_global.oldI = _global.setInterval;
_global.setInterval = function(){
trace(arguments);
var i = oldI.apply( null, arguments);
idsArray.push( i );
return(i);
}
ASSetPropFlags(_global, ["setInterval", "oldI"], 7, 7);//можно и не делать
setInterval ( trace, 1000, "interval");
setInterval ( trace, 1100, "interval2");
function f(){
trace ( arguments.join("") );
}
setInterval(this, "f", 5000, "син", "так", "сис", "2" );
function xMan(){
var i;
while( i = idsArray.pop() )clearInterval( i );
trace ("мусорщик пришел и все смел");
}
var i1 = oldI( trace, 2000, "а это наш интервал, его пока не убиваем" );
var i2;
var temp = function(){
clearInterval(i1);
clearInterval(i2);
trace ("ну и наших убъем");
}
var i2 = oldI( temp, 10000 );
setInterval ( xMan, 5500 );
trace( idsArray );:bye:
PS> тоже хак, конечно, но поддерживает оба синтаксиса и переменное число аргументов userData. Enjoy, короче.

[this.create]

А мне нужно после того, как она выгрузится из моей, поубивать все интервалы, которые она создала.
Тоже самое не забудьте предусмотреть для листенеров.

[etc]

Я не понимаю, чего машает:

clearInterval(_global.id)
_global.id = setInterval(…)
Ролик хоть обзапускайся.

[Molecula]

А если в подгружаемом swf есть такие строчки:

setInterval(Zer, 200);
function Zer()
{
trace("Yo!")
}


И всё, т.е. трейсит "Уо".

Как убрать (очстить) такой интервал в swf, в которую подгрузили?

[etc]

var int = setInterval(function() {},200);
for (var i = 0;i<=int;i++) {
clearInterval(i);
}

[Molecula]

Да нет.
А если клип с сетИнтервалом не мой, и я вообще не знаю/не уверен есть ли он там. Как тогда?

Просто в 2005 году, криворукое тело написало такое...код рабоает? работает...ну так что ещё надо. А теперь wvxvw в 2007 году пытается удалить эту конитель.

Как остановить, очистить Интервал Криворукого Дегроида, пример которого описан выше?

clearInterval(_global.id)

тут подойдет?

[etc]

Если решение из 20-го поста, то нет. Если из 22-го, то скорее всего да.

[Molecula]

Понял.

[wvxvw]

var int = setInterval(function() {},200);
for (var i = 0;i<=int;i++) {
clearInterval(i);
}
Ну, только это кроме всего остального угробит твины (если такие были) использовавшие setInterval, и возможно, запущенные вовсе не из загруженного клипа.
Вобщем, я больше склоняюсь к решению Kikasso, но еще надо будет немного поэксперементировать.

[etc]

Я предложил убивать вообще все интервалы. К тому же, твины без FPS не используют интервал.

[Kikasso]

А если в подгружаемом swf есть такие строчки:

setInterval(Zer, 200);
function Zer()
{
trace("Yo!")
}


И всё, т.е. трейсит "Уо".

Как убрать (очстить) такой интервал в swf, в которую подгрузили?
Читайте пост №18. Все работает. Если в мой мувик загружать другие, он все id интервалов будет собирать в мешок.
Если твин с FPS, он работает на интервале. Если без, на ентерфрейме - и сам удалится.
Я понял, wvxvw хочет подстраховаться от криворуких баннероделальщиков.
__etc, ваш вариант убъет все интервалы, в том числе и ваши, посаженные до этого.