Максимальное значение массива.

[SashNone]

Господа, мучаюсь. Как найти максимум и минимум массива??

[BigDan]

Отсортировать его.

[SashNone]

Вот блин. Так и знал... но думал как в php найдётся функция... спасибо..

Тогда встречный вопрос. Как сделать не ссылочную переменную.
Т.е. если я делаю

Array_copy=My_Array
Array_copy.sort()...

То автоматом сортируется и My_Array

[BigDan]

var arr:Array = [4,7,1,9,6,3];
var min:Number = arr[0];
for(var i=0;i<arr.length;i++){
if(arr[i] < min) min = arr[i];
}
trace(min);
аналогично делаешь для max.

[Kikasso]

копия массива:
var arr:Array = [0,1,2,3,4,5,6,7,8,9];
var arr2:Array = arr.concat();
var arr3:Array = arr.slice();
//покажем что массивы разные:
arr2[2] = 222;
arr3[3] = 333;
trace(arr);
trace(arr2);
trace(arr3);
BigDan, точку забыл.

[iNils]

SashNone, есть кнопка http://www.flasher.ru/forum/images/russian/style3/buttons/edit.gif, поэтому не надо создавать несколько сообщений подряд, надо исправить последнее в теме.

[wvxvw]

var _a:Array = [1, 3, 2, 4];
var _b:Array = [].concat(_a);
_b.sort();
trace(_a);
trace(_b);

[SashNone]

iNils, учту.

Остальным, спасибо большое. Сложновато с php переходить на AS.

[Kikasso]

function findMax( inArr:Array ):Number {
var arr:Array = inArr.concat();
var max:Number = Number.MIN_VALUE;
var n:Number;
while( arr.length ){
n = Number (arr.pop());
if( max < n ) max = n;
}
return max;
}
var arr:Array = [0,100,2,3,4,5,-6,7,8,'A'];
trace( findMax(arr));

[BigDan]

Kikasso, а мой метод не легче?:)

[wvxvw]

var _a:Array = [1, 5, 2, -10, 'a', true, -80, 6];
function s(a, b):Number {
if(Number(a)>Number(b)){
return 1;
} else if(Number(a)==Number(b)){
return 0;
} else {
return -1;
}
}
_a.sort(s);
trace(_a); %)
Первое значение в массиве - наименьшее, последнее - наибольшее. Зачем изобретать велосипед? =)

[Kikasso]

Kikasso, а мой метод не легче?:)Зачем изобретать велосипед? =)

function findMax1( inArr:Array ):Number {
var arr:Array = inArr.concat();
var max:Number = Number.MIN_VALUE;
var n:Number;
while( arr.length ){
n = Number (arr.pop());
if( max < n ) max = n;
}
return max;
}
function findMax2( arr:Array ):Number {
var max:Number = Number.MIN_VALUE;
var n:Number = arr.length, k:Number;
for( var i:Number = 0; i < n; i ++){
k = Number( arr[i] );
if( max < k ) max = k;
}
return max;
}
function findMax3(inArr:Array ):Number {
var arr:Array = inArr.concat();
arr.sort( 2 | 16);
return arr[0];
}
var n = 100000;
var arr:Array = new Array();
while (n--)arr.push( Math.random());
var t:Number = getTimer();
trace( findMax1(arr));
trace( getTimer() - t ); //418
trace('---------------');
t = getTimer();
trace( findMax2(arr));
trace( getTimer() - t ); //161
trace('---------------');
t = getTimer();
trace( findMax3(arr));
trace( getTimer() - t ); //930

BigDan wins :)

[SashNone]

Чёрт... :(

var minX:Number = Number.MAX_VALUE;
var maxX:Number = Number.MIN_VALUE;
var minY:Number = Number.MAX_VALUE;
var maxY:Number = Number.MIN_VALUE;
for(i=1;i<arrX.length;i++){
if(arrX[i] < minX){ minX = arrX[i];}
if(arrX[i] > maxX) {maxX = arrX[i];}
if(arrY[i] < minY) {minY = arrY[i];}
if(arrY[i] > maxY) {maxY = arrY[i];}
}

trace(minX); //undefined
trace(maxX);1430.04124197256
trace("---------------");
trace(minY);-2457.88798584466
trace(maxY);299.620049708795

Массивы одинаковой длины, содержат исключительно цифренные генерируемые значения (+/- координаты). Если нужно могу вывести листинг массива.

[BigDan]

i=0,а не 1(в цикле)

[etc]

function findMax1(inArr:Array):Number {
var arr:Array = inArr.concat();
var max:Number = Number.MIN_VALUE;
var n:Number;
while (arr.length) {
n = Number(arr.pop());
if (max < n) {
max = n;
}
}
return max;
}
function findMax2(arr:Array):Number {
var max:Number = Number.MIN_VALUE;
var n:Number = arr.length, k:Number;
for (var i:Number = 0; i < n; i++) {
k = Number(arr[i]);
if (max < k) {
max = k;
}
}
return max;
}
function findMax3(array:Array):Number {
if (!min_cache) {
min_cache = Number.MIN_VALUE;
}
var n:Number = array.length;
var x:Number = min_cache;
while(n) {
var k = array[n--];
if (k > x) {
x = k;
}
}
return x;
}
var n = 100000;
var arr:Array = new Array();
while (n--) {
arr.push(Math.random());
}
var t:Number = getTimer();
trace(findMax1(arr));
trace(getTimer() - t);// 749
trace('---------------');
t = getTimer();
trace(findMax2(arr));
trace(getTimer() - t);// 168
trace('---------------');
t = getTimer();
trace(findMax3(arr));
trace(getTimer() - t);// 148

[Kikasso]

function findBoth( arr:Array ):Array {
var min:Number = Number.MAX_VALUE;
var max:Number = Number.MIN_VALUE;
var n:Number = arr.length, k:Number;
for( var i:Number = 0; i < n; i ++){
k = Number( arr[i] );
if( max < k ) max = k;
if( min > k ) min = k;
}
return [min, max];
}
///////////////
var myArray:Array = [5,7.6, 9, -20, 55, 99, 88];
var rez:Array = findBoth( myArray );
trace( 'min:' + rez[0] + ' max:'+rez[1] );
2__etc: да, while быстрее..