Форум Flasher.ru
Ближайшие курсы в Школе RealTime
Список интенсивных курсов: [см.]  
  
Специальные предложения: [см.]  
  
 
Блоги Правила Справка Пользователи Календарь Поиск рулит! Сообщения за день Все разделы прочитаны
 

Вернуться   Форум Flasher.ru > Блоги > Inet_PC

Оценить эту запись

Загадки

Запись от Inet_PC размещена 17.03.2014 в 22:22
Обновил(-а) Inet_PC 20.03.2014 в 14:43 (Добавлено еще 3 загадки)

Загадка №1:
Есть класс TestBase:
Код AS3:
package
{
    public class TestBase
    {
        public function TestBase()
        {
            super();
        }
 
        public function foo(a:int, b:int):void
        {
            trace("TestBase#foo()");
        }
    }
}
Необходимо написать наследника (Test) этого класса так, чтобы следующий код скомпилился и выполнился без ошибок:
Код AS3:
var t:TestBase = new Test();
t.foo.apply(null, [1, 2, 3]);//TestBase#foo()
Сигнатуру метода менять нельзя!

Загадка №2:
Код AS3:
private function foo():void
{
        // какой-то код здесь
        // использовать ключевое слова var нельзя
        player = null;
}
foo();
Код должен скомпилиться и не упасть при выполнении.

Загадка №3:
Имеется класс:
Код AS3:
package
{ 
    public class TestClass
    { 
        public function TestClass()
        {
            super(); 
        }
 
        public function foo():void
        {
            trace("foo");
        }
 
        public function change(value:Function):void
        {
 
        }
    }
}
Нужно, чтобы следующий код вывел в trace:
foo
--> foo <--
Код AS3:
public function Main()
{
    var test:TestClass = new TestClass();
    test.foo();//foo
    test.change(myTrace);
    test.foo();//--> foo <--
}
private function myTrace(...args):void
{
    args.push   ("<--");
    args.unshift("-->");
    trace.apply(null, args);
}
  • менять код класса Main нельзя;
  • использовать var, const, dynamic, prototype нельзя;
  • менять метод foo нельзя;
  • наследоваться нельзя.

Загадка №4:
Необходимо, не меняя значения переменных, изменить результат их сравнения.
Код AS3:
var a:Point = new Point(5);
var b:Point = new Point(1);
trace(a, "<", b, "=", a < b);//(x=5, y=0) < (x=1, y=0) = false
// какой-то код здесь
trace(a, "<", b, "=", a < b);//(x=5, y=0) < (x=1, y=0) = true
Загадка №5:
Необходимо вызвать метод foo, так, чтобы в трейс вывелось: «foo» и «after foo»:
Код AS3:
private function foo(...args):void
{
    trace("foo");
    throw new Error();
}
 
// здесь нужно как-то вызвать foo
trace("after foo");
-использовать try/catch нельзя;
-должно работать как в debug, так и в release FP;
-изменять метод foo нельзя;
-никаких окон с ошибками не должно быть.

Загадка №6:
Имеется класс Color, с перечислением цветов (фактически Enum):
Код AS3:
public class Color
{
    public static const RED:Color = new Color(0xFF0000);//it's OK
    public static const GREEN:Color = new Color(0x00FF00);//it's OK
    public static const RANDOM:Color = new Color(Math.random() * 0xFFFFFF);//it's OK
    // остальные объявления цветов
 
    private var _value:uint;
 
    public function Color(value:uint)
    {
        super();
        _value = value;
 
        // какой-то код здесь
    }
 
    public function toString():String
    {
        return _value.toString();
    }
}
Необходимо написать проверку в конструкторе класса так, чтобы она выкидывала ошибку, если мы пытаемся
создать еще один экземпляр класса Color:
Код AS3:
trace(Color.RED, Color.GREEN, Color.RANDOM);//0xFF0000 0x00FF00 0xF67D53
trace(new Color(Math.random() * 0xFFFFFF));//здесь должно упасть в run-time
-код проверки можно писать только внутри конструктора класса Color;
-использовать динамику нельзя.

Некоторые задачи имеют несколько решений. Так же некоторые задачи используют недокументированные
возможности FP. Используйте их (лучше не используйте) на свой страх и риск. Вообщем это все just for fun!
Всего комментариев 80

Комментарии

Старый 18.03.2014 19:03 СлаваRa вне форума
СлаваRa
 
Аватар для СлаваRa
Код AS3:
class Test extends TestBase {
	public override function foo(a:int, b:int):void {
		arguments;
		super.foo(a, b);
	}
}
Старый 18.03.2014 19:34 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
СлаваRa, именно)
Обновил(-а) Inet_PC 20.03.2014 в 09:09
Старый 18.03.2014 22:24 carrotoff вне форума
carrotoff
 
Аватар для carrotoff
Если кому интересно, внесу пояснение к решению:

Цитата:
Если в теле функции есть ссылки на объект arguments, ActionScript 3.0 позволяет включать в вызов функции больше параметров, чем указано в определении функции
Старый 18.03.2014 23:21 MikroAcse вне форума
MikroAcse
 
Аватар для MikroAcse
Читеры
Старый 19.03.2014 11:07 PainKiller вне форума
PainKiller
 
Аватар для PainKiller
Класс, спасибо!
Старый 20.03.2014 02:22 etc вне форума
etc
 
Аватар для etc
Вторую не понял, куда код пишем?
Старый 20.03.2014 02:44 etc вне форума
etc
 
Аватар для etc
Третий простой слишком

Код AS3:
package { 
	import flash.utils.getDefinitionByName;
 
	public class TestClass {
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function TestClass() {
			super();
		}
 
		//--------------------------------------------------------------------------
		//
		//  Properties
		//
		//--------------------------------------------------------------------------
 
		public var trace:Function = getDefinitionByName('trace') as Function;
 
		//--------------------------------------------------------------------------
		//
		//  Public methods
		//
		//--------------------------------------------------------------------------
 
		public function foo():void {
			trace("foo");
		}
 
		public function change(value:Function):void {
			this.trace = value;
		}
	}
}
Старый 20.03.2014 04:07 in4core вне форума
in4core
 
Аватар для in4core
Код AS3:
private function foo():void
		{
			function player():void {}
			player = null;
			// oh... it simple
 
		}
Старый 20.03.2014 09:06 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
etc, к сожалению решение неверное, использовать ключевое слово var нельзя!
in4core, именно!
Старый 20.03.2014 10:32 etc вне форума
etc
 
Аватар для etc
@Inet_PC, ну хорошо, с const можно?

Код AS3:
package { 
	import flash.utils.getDefinitionByName;
 
 
	public class TestClass {
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function TestClass() {
			super();
		}
 
		//--------------------------------------------------------------------------
		//
		//  Properties
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */
		private const _foo:Object = new Object();
 
		//--------------------------------------------------------------------------
		//
		//  Public methods
		//
		//--------------------------------------------------------------------------
 
		public function foo():void {
			trace("foo");
		}
 
		public function change(value:Function):void {
			this._foo['trace'] = value;
		}
 
		//--------------------------------------------------------------------------
		//
		//  Private methods
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */
		private function trace(...args):void {
			((this._foo['trace'] as Function) || (getDefinitionByName('trace') as Function)).apply(null, args);
		}
	}
}
Если нельзя, то указывай)
Старый 20.03.2014 11:01 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
@etc, я упустил момент с const, его использовать тоже нельзя, согласитесь, иначе слишком простое задание получается.
Старый 20.03.2014 11:52 ChuwY вне форума
ChuwY
 
Аватар для ChuwY
Ко второй загадке:

Код AS3:
private function foo():void
{
	({}).// ну или Object(this).constructor.
	player = null;
}
Про такое ничего сказано не было.
Старый 20.03.2014 11:59 etc вне форума
etc
 
Аватар для etc
Ну можно тогда опереться на то, что Class динамический

Код AS3:
package { 
	import flash.utils.getDefinitionByName;
 
 
	public class TestClass {
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function TestClass() {
			super();
		}
 
		public function get trace():Function {
			return (TestClass['trace'] || getDefinitionByName('trace')) as Function;
		}
 
		//--------------------------------------------------------------------------
		//
		//  Public methods
		//
		//--------------------------------------------------------------------------
 
		public function foo():void {
			trace("foo");
		}
 
		public function change(value:Function):void {
			TestClass['trace'] = value;
		}
	}
}
trace как геттер или метод — не принципиально уже.
Есть ещё один хардкор вариант, но приводить не буду пока
Старый 20.03.2014 12:19 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
ChuwY, решение засчитывается!
etc, именно, решение засчитано! Но эту задачу можно решить и другим путем, не используя динамические объекты! Возможно Ваш хардкор вариант подойдет?
Старый 20.03.2014 12:27 ChuwY вне форума
ChuwY
 
Аватар для ChuwY
Решение задачи три.

Код AS3:
internal class TestClass
{ 
	public function TestClass()
	{
		super();
	}
 
	public function foo():void
	{
		trace("foo");
	}
 
	public function change(value:Function):void
	{
		Object(this).constructor.userTraceFunction = value;
	}
 
	public function trace(...args):void
	{
		if(Object(this).constructor.userTraceFunction)
		{
			Object(this).constructor.userTraceFunction(args);
		}
		else
		{
			getDefinitionByName("trace")(args)
		}
	}
}
}
Гм. У товарища етца ожидаемо изящнее вышло.
Старый 20.03.2014 12:37 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
ChuwY, решение правильное, но оно аналогично решению etc, так как использует динамический объект, попробуйте решить без использования динамических объектов.
Старый 20.03.2014 12:39 etc вне форума
etc
 
Аватар для etc
Мой хардкор вариант тоже динамику использует.
Щас подумаем над вариантом без динамики.
Старый 20.03.2014 13:17 etc вне форума
etc
 
Аватар для etc
Без динамики, но с const

Код AS3:
package { 
	import flash.utils.getDefinitionByName;
 
	public class TestClass {
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function TestClass() {
			super();
 
			if (arguments.length > 0) {
				this['trace'] = arguments[0];
			} else {
				this['t'] = arguments.callee;
			}
		}
 
		//--------------------------------------------------------------------------
		//
		//  Properties
		//
		//--------------------------------------------------------------------------
 
		public const t:Object = null;
 
		public const trace:Function = function():void {
			(getDefinitionByName('trace') as Function).apply(null, arguments);
		}
 
		//--------------------------------------------------------------------------
		//
		//  Public methods
		//
		//--------------------------------------------------------------------------
 
		public function foo():void {
			trace("foo");
		}
 
		public function change(value:Function):void {
			this['t'](value);
		}
	}
}
Старый 20.03.2014 13:38 in4core вне форума
in4core
 
Аватар для in4core
Вставлю свои 5 копеек. (мои задачки )

Задача 1 : "trace"
Код AS3:
function one():void  {  doIt() }
function two():void  { doIt() }
function three():void  { doit() }
function doIt():void  { 
// code only here 
}
one();
two();
three();
в оутпут должно вывалится
1
2
3
Суть в том, что нельзя использовать счетчики, да собственно говоря, счетчики у вас сделать и неполучится, ибо писать можно только в теле doIt внешне писать нигде ничего нельзя

Задача 2 : "многоножка ( совсем для маленьких задачка)"

Код AS3:
function foo()  
{
   // code here.  
   lev1.lev2.lev3.lev4.lev5 = 5;
}
Что нужно написать выше, чтобы конструкция ниже не выдала ошибок
Старый 20.03.2014 14:06 etc вне форума
etc
 
Аватар для etc
@in4core, если это всё в кадрах флеша, то в первой задаче this динамический, счётчик на ходу можно завести.
Вторая задача решается просто:

Код AS3:
   var lev1:XML = <lev1/>;
Старый 20.03.2014 14:08 ChuwY вне форума
ChuwY
 
Аватар для ChuwY
Итак. Вариант "извращенный с допущениями".
Пришлось немного изменить Main (сделать myTrace публичными) и он уже не мейн даже, но в качестве шутки пойдет.

Код AS3:
package by.ppchu.tests
{
	import flash.display.Sprite;
 
	public class TrueMain extends Sprite
	{
		public function TrueMain()
		{
			new FakeMain();
		}
	}
}
Код AS3:
package by.ppchu.tests
{
	public class FakeMain
	{
		public function FakeMain()
		{
			var test:TestClass = new TestClass();
			test.foo();//foo
			test.change(myTrace);
			test.foo();//--> foo <--
		}
 
		public function myTrace(...args):void
		{
			args.push   ("<--");
			args.unshift("-->");
			trace.apply(null, args);
		}
	}
}
Код AS3:
package by.ppchu.tests
{
	import flash.net.getClassByAlias;
	import flash.net.registerClassAlias;
	import flash.sampler.getSavedThis;
	import flash.utils.ByteArray;
	import flash.utils.getDefinitionByName;
 
	public class TestClass extends ByteArray
	{ 
		public function TestClass()
		{
			super();
		}
 
		public function foo():void
		{
			trace("foo");
		}
 
		public function change(value:Function):void
		{
			try
			{
				getClassByAlias("FakeMainClass")				
			}
			catch(error : *)
			{
				registerClassAlias("FakeMainClass", FakeMain);
				writeObject(getSavedThis(value));
			}
		}
 
		public function get trace():Function
		{
			if(length)
			{
				position = 0;
				return readObject().myTrace;
			}
 
			try
			{
				getClassByAlias("FakeMainClass")
			}
			catch(error : *)
			{
				return getDefinitionByName("trace") as Function;
			}
 
			return dummy;
		}
 
		private function dummy():void
		{
			arguments;
		}
	}
}
Хм. А наследовать TestClass ни от чего нельзя или только друг от друга их нельзя?
Старый 20.03.2014 14:16 in4core вне форума
in4core
 
Аватар для in4core
Цитата:
@in4core, если это всё в кадрах флеша, то в первой задаче this динамический, счётчик на ходу можно завести.
Вторая задача решается просто:
Никаких кадров! Никаких счетчиков и не используется this)) Это очень хитрая задача одновременно на логику и знание приципов работы.

По первому вопросу, да. Но есть и другой вариант ( об хмл я кстати не подумал, когда создавал вопрос )
Старый 20.03.2014 14:21 in4core вне форума
in4core
 
Аватар для in4core
И в догоночку тоже простенькая

3. "returner"

Код AS3:
function foo(a:String) : String
{
   return ???;
}
foo("hello"); // hello
Кроме как вместо вопросов писать нигде нельзя, ключевое слово var , this - Нельзя. Соотвественно нельзя написать return a
Старый 20.03.2014 14:27 etc вне форума
etc
 
Аватар для etc
@in4core, если я правильно понял, что должно вывалиться в трейс, то

Код AS3:
function foo(a:String) : String
{
   return trace.call(null, a);
}
foo("hello"); // hello
Старый 20.03.2014 14:33 etc вне форума
etc
 
Аватар для etc
@in4core, ты кстати с многоножкой foo вообще вызываешь или нет?
Старый 20.03.2014 15:33 in4core вне форума
in4core
 
Аватар для in4core
Цитата:
@in4core, ты кстати с многоножкой foo вообще вызываешь или нет?
А есть разница? По сути нет. Там вместо XML объект используется, вот второе решение.

По ретурнер, да принято. А вот про doIt ! Реши попробуй, я думаю как раз ты знаешь, как ее решать )))
Старый 20.03.2014 15:35 etc вне форума
etc
 
Аватар для etc
Задача недостаточно хорошо поставлена, не указана среда выполнения и допускается ли использовать дебажные методы.

А разница есть, запускать foo() или нет. Если нет, то достаточно просто создать var lev1:Object. Если запускать, то надо создавать такой объект, который на любое запрошенное свойство возвращает новый.
Старый 20.03.2014 15:49 etc вне форума
etc
 
Аватар для etc
Ну и задача от меня:

Код AS3:
package {
 
	/**
	 * @author					etc
	 * @version					1.0
	 * @playerversion			Flash 10
	 * @langversion				3.0
	 * @date					Mar 20, 2014
	 */
	public class SomeClass {
 
		//--------------------------------------------------------------------------
		//
		//  Class constants
		//
		//--------------------------------------------------------------------------
 
		public static const TEST:String = 'test';
 
		//--------------------------------------------------------------------------
		//
		//  Class methods
		//
		//--------------------------------------------------------------------------
 
		public static function test():void {
			// Код только здесь
 
			trace(x.TEST); // test
		}
 
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function SomeClass() {
			super();
		}
	}
}
При вызове статического метода test вывести в трейс значение константы TEST. Обращаться напрямую к SomeClass нельзя, равно как и использовать дебажные методы Flash Player (типа getSavedThis и т. д.). Т. е. код должен работать в релизном плеере. Код писать можно только в теле метода test()
Обновил(-а) etc 20.03.2014 в 16:49
Старый 20.03.2014 16:10 in4core вне форума
in4core
 
Аватар для in4core
Цитата:
Задача недостаточно хорошо поставлена, не указана среда выполнения и допускается ли использовать дебажные методы.
Среда выполнения FP 11+ , дебажные разрешены! ))
Старый 20.03.2014 16:17 in4core вне форума
in4core
 
Аватар для in4core
Цитата:
Ну и задача от меня:
А вот тут действительно непонятно поставлена задача, как по мне.
Если я верно понял запустить так нельзя SomeClass.test() - а как же ее тогда вообще запустить?! Или внутри где то надо запустить?!
Код AS1/AS2:
trace(...);
Это не скомпилится, или вместо ... тоже что то должно быть написано?! Просто указано КОД ТОЛЬКО ЗДЕСЬ, выше трейс.
Старый 20.03.2014 16:23 etc вне форума
etc
 
Аватар для etc
Ну раз разрешены, то можно в Flash IDE запустить в режиме Debug:

(в первом кадре)
Код AS3:
function one():void  {  doIt() }
function two():void  { doIt() }
function three():void  { doIt() }
function doIt():void  {
	var s:String = (new Error()).getStackTrace();
	var l:Array = s.split('\n');
	s = l[2];
	s = s.match(/(?<=:)(\d+)/g)[0];
	trace(s);
}
one();
two();
three();
Старый 20.03.2014 16:24 etc вне форума
etc
 
Аватар для etc
in4core, запускается как раз SomeClass.test(); Нельзя внутри test() писать SomeClass в каком-либо виде.
Трейс там должен выводить значение константы TEST.
Старый 20.03.2014 16:26 rumc вне форума
rumc
 
Аватар для rumc

решение задачи 3

Код AS3:
package {
 
    import flash.events.StatusEvent;
    import flash.net.LocalConnection;
    import flash.utils.getDefinitionByName;
 
    public class TestClass {
 
        //--------------------------------------------------------------------------
        //
        //  Constructor
        //
        //--------------------------------------------------------------------------
 
        public function TestClass() {
            super();
            (function (lc:LocalConnection):void {
                lc.connect('trace1');
                lc.client = {
                    f: function (a:Array):void {
                        (getDefinitionByName('trace') as Function).apply(null, a);
                        lc.close();
                    }
                };
            })(new LocalConnection);
 
        }
 
        //--------------------------------------------------------------------------
        //
        //  Public methods
        //
        //--------------------------------------------------------------------------
 
        public function foo():void {
            trace("foo");
        }
 
        public function change(value:Function):void {
            (function (lc:LocalConnection):void {
                lc.connect('trace2');
                lc.client = {f: function (a:Array):void {value.apply(null, a)}};
            })(new LocalConnection);
 
        }
 
        public function trace(...args):void {
            (function (lc:LocalConnection):void {
                lc.addEventListener(StatusEvent.STATUS, function (e:StatusEvent):void {});
                lc.send('trace1', 'f', args);
                lc.send('trace2', 'f', args);
            })(new LocalConnection);
        }
    }
}
Старый 20.03.2014 16:32 in4core вне форума
in4core
 
Аватар для in4core
etc - с моей задачей - да , все ок молодцом. Но с вашей, я опять недопонимаю , если я напишу просто trace(TEST) разве это не будет удовлетворять вашим условиям?
Старый 20.03.2014 16:49 etc вне форума
etc
 
Аватар для etc
in4core, поправил чутка. Короче задача сводится к тому чтобы в x получить ссылку на SomeClass
Старый 20.03.2014 19:20 in4core вне форума
in4core
 
Аватар для in4core
etc, не знаю пойдет ли, но

Код AS3:
public static function test():void
		{
			registerClassAlias("cls" , SomeClass);
 
			trace( getClassByAlias("cls").TEST );
 
		}
Старый 20.03.2014 19:32 etc вне форума
etc
 
Аватар для etc
Конечно не пойдёт, SomeClass явно в коде указан.
Старый 20.03.2014 20:07 in4core вне форума
in4core
 
Аватар для in4core
Ну тогда я наверное сдамся, посмотрим, кто решит - загадка интересна. Ибо других утилитных методов я не знаю, а дебажными stackTrace ты запретил пользоваться. Наверняка какое то шаманставо с function/apply/call/arguments/getDefinition и т.п.

В ответку, я тоже поставлю нестандартный вопрос : помнишь решение с doIt() ? Вопрос остается открытым, нужно вызывать, для простоты скажем в первом кадре или в кнострукторе main - Три раза метод doIt() и получить 1,2,3 в трейсе. Только релиз, нельзя this, код пишем ТОЛЬКО в теле doIt. Никаких других методов кроме doIt не существует, нельзя использовать рекурсию и счетчики, а так же соответсвено поля класса.
Старый 20.03.2014 20:10 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
Код AS3:
public static function test():void 
{
    // Код только здесь
    var x:Object = prototype.constructor;
    trace(x.TEST); // test
}
Так?
Старый 20.03.2014 20:12 etc вне форума
etc
 
Аватар для etc
Можно и так, но есть вариант без этого. Но таки да, меджик.

in4core, посмотрю попозже.
Старый 20.03.2014 20:21 rumc вне форума
rumc
 
Аватар для rumc
Код AS3:
public static function test():void {
    (function ():void {
        var b:XML = describeType(this);
        trace(getDefinitionByName(b.constant.@type).TEST);
    })();
}
вот )
Обновил(-а) rumc 20.03.2014 в 21:32
Старый 20.03.2014 20:30 in4core вне форума
in4core
 
Аватар для in4core
Цитата:
in4core, посмотрю попозже.
Буду ждать, интересно, вдруг есть еще какой то вариант, кроме моего.
Старый 20.03.2014 20:36 alatar вне форума
alatar
 
Аватар для alatar
Inet_PC, а откуда в статичном методе доступ к prototype?
Старый 20.03.2014 21:04 in4core вне форума
in4core
 
Аватар для in4core
Да кстати это феил. как то неусмотрели. arguments.callee.prototype.constructor тоже не взлетит.
Старый 20.03.2014 21:38 etc вне форума
etc
 
Аватар для etc
Ага, не работает prototype. Ещё варианты?
Старый 20.03.2014 21:42 in4core вне форума
in4core
 
Аватар для in4core
etc а вроде уже ответили. с дескрайбТайп
Старый 20.03.2014 21:52 etc вне форума
etc
 
Аватар для etc
Да я видел, принимается. Есть ещё вариант, похожий, но без функции.
Старый 20.03.2014 22:19 Inet_PC вне форума
Inet_PC
 
Аватар для Inet_PC
Цитата:
Inet_PC, а откуда в статичном методе доступ к prototype?
Из доки:
Цитата:
A reference to the prototype object of a class or function object. The prototype property is automatically created and attached to any class or function object that you create. This property is static in that it is specific to the class or function that you create. For example, if you create a class, the value of the prototype property is shared by all instances of the class and is accessible only as a class property. Instances of your class cannot directly access the prototype property.
Цитата:
Ага, не работает prototype. Ещё варианты?
Flex SDK 4.11, работает, это в ASC перестало работать. В примере из доки можно обращаться к прототипу из статического конструктора (по идее и из статической функции тогда должно быть можно). Но новый компилятор по каким-то причинам запрещает, инфы по этому поводу не нашел.
Обновил(-а) Inet_PC 21.03.2014 в 22:50
Старый 21.03.2014 02:56 in4core вне форума
in4core
 
Аватар для in4core
etc - ну так что, сдаешься по моей задаче? 1:1 или поборешься?
Старый 21.03.2014 14:15 etc вне форума
etc
 
Аватар для etc
Нет времени сейчас, потом.
 
Последние записи от Inet_PC

 


Часовой пояс GMT +4, время: 00:53.


Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2024, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.