Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 1.0/2.0 (http://www.flasher.ru/forum/forumdisplay.php?f=93)
-   -   Возврат действий (http://www.flasher.ru/forum/showthread.php?t=118873)

KiL33 05.12.2008 19:56
Возврат действий
 
Код AS1/AS2:
var color = 0x9999FF;

this.onMouseDown = function() {

        penUp = false; 

        this.moveTo(_xmouse, _ymouse);

        this.lineStyle(5, color);

};

this.onMouseMove = function() {

        if (!penUp) {

                this.lineTo(_xmouse, _ymouse);

                updateAfterEvent();

        }

};

this.onMouseUp = function() {

        penUp = true;

};
Принцип простейшего рисования линий.

Как сделать возврат к предыдущей нарисованной линии?
Т.е. по типу стрелочки вперед / назад.

urasfinks 05.12.2008 21:27
А ты записывай нарисованные координаты линии в массив. А далее напишу функцию перерисовки по массиву. Тоесть если назад переместишь то рисовать будешь по массиву (цикл i=0;i<array.length-2;i++).

KiL33 05.12.2008 21:50
Интересное предложение, думаю, реализовать мне его будет всё же несколько сложно. Если у Вас будет свободное время и хорошее настроение, помогите разобрать этот вопрос)

Kuruki 05.12.2008 21:56
А мне не кажется этот вариант сложным, но кажется не рациональным, каждый раз перерисовывать все... На мой взгляд лучше помещать каждую нарисованную линию в отдельный клип, а при нужде удалять его. При большом кол-ве линий думаю это будет быстрей работать...

KiL33 06.12.2008 10:05
Попытался сделать, как посоветовал Kuruki, но всё равно клипы не хотят удаляться, что бы ни делал.
Код AS1/AS2:
count = 0;

var mc = this.createEmptyMovieClip("line", 1);

var color = 0x9999FF;

mc.onMouseDown = function() {

        penUp = false; 

        mc.moveTo(_xmouse, _ymouse);

        mc.lineStyle(5, color);

                count=count+1;

                mc.createEmptyMovieClip("inLine"+count,this.getNextHighestDepth());        

        }; 

mc.onMouseMove = function() {

        if (!penUp) {

                mc.lineTo(_xmouse, _ymouse);

                updateAfterEvent();

        }

};

mc.onMouseUp = function() {

        penUp = true;

};

Kuruki 06.12.2008 16:43
Я бы посоветовал использовать onPress, onRelease чтобы не было проблем с обработкой других кнопок (при нажатии на них происходило бы рисование). Для этого придется нарисовать "планшет", т.е. лист, на чем мы будем рисовать. В вашем случае проблема была в том, что вы создавали клипы для линий, а рисовали всеравно в главном (mc).
Код AS1/AS2:
var lineCount:Number = 0;

var lineColor:Number = 0x9999FF;

var planshetColor:Number = 0xFFFF00;

var penUp:Boolean = false;

 

var planshet_mc:MovieClip = drawPlanshet(container);

 

function drawPlanshet(target_mc:MovieClip):MovieClip{

        var mc:MovieClip = target_mc.createEmptyMovieClip('mc', target_mc.getNextHighestDepth());

        mc.useHandCursor = false;

 

        mc.beginFill(planshetColor);

        mc.lineTo(Stage.width, 0);

        mc.lineTo(Stage.width, Stage.height);

        mc.lineTo(0, Stage.height);

        mc.lineTo(0,0);

        mc.endFill();

 

        return mc;

}

 

planshet_mc.onPress = function() {

        penUp = false; 

        lineCount++;

        this.createEmptyMovieClip("inLine" + lineCount, this.getNextHighestDepth());

        this['inLine' + lineCount].moveTo(_xmouse, _ymouse);

        this['inLine' + lineCount].lineStyle(5, lineColor);

}; 

planshet_mc.onMouseMove = function() {

        if (!penUp) {

                this['inLine' + lineCount].lineTo(_xmouse, _ymouse);

                updateAfterEvent();

        }

};

planshet_mc.onRelease = function() {

        penUp = true;

};

 

function undo(){

        planshet_mc['inLine' + lineCount].removeMovieClip();

        lineCount--;

}

undo_btn.onRelease = undo;

KiL33 06.12.2008 19:03
Большущее Спасибо!:)

KiL33 07.12.2008 09:44
Вложений: 1
Появился ещё один вопрос.

Для выбора фона пользуюсь компонентом ColorPicker 2.

В начале работы фоном у меня служил динамик.текст и задавал его таким образом
Код:
bg.backgroundColor = "0x"+evt.getRGB()
Разумеется сейчас так не получается, пытался вот так сделать
Код:
var planshetColor = "0x"+evt.getRGB()
Фон всё равно не меняется.

Kuruki 07.12.2008 12:39
Должна была вылететь ошибка несоответствия типов. В метод beginFill вы передаете строку, а нужно число.
Код AS1/AS2:
var planshetColor:Number = Number("0x" + evt.getRGB());

KiL33 07.12.2008 14:27
хммм...всё равно не хочет работать

Kuruki 07.12.2008 15:01
Цитата:
Сообщение от KiL33 (Сообщение 782085)
Разумеется сейчас так не получается, пытался вот так сделать
Код:
var planshetColor = "0x"+evt.getRGB()
Фон всё равно не меняется.
Естественно, с чего он будет меняться, если вы меняете только значение этой переменной. Фон надо еще и перерисовать с новым цветом!
Делать все за вас не буду, лучше дам совет. Функцию рисования фона надо немного изменить; чтобы с каждой перерисовкой не накладывать фоны друг на друга, будем заменять его.Для этого будем каждый раз создавать клип с тем же именем и в той же глубине.
Код:
function drawPlanshet(target_mc:MovieClip):MovieClip{
    var mc:MovieClip = target_mc.createEmptyMovieClip('mc', 1);
    mc.useHandCursor = false;
 
    mc.beginFill(planshetColor);
    mc.lineTo(Stage.width, 0);
    mc.lineTo(Stage.width, Stage.height);
    mc.lineTo(0, Stage.height);
    mc.lineTo(0,0);
    mc.endFill();
 
    return mc;
}
Извлекать выбранный цвет можно не только из аргумента функции change, но и из свойства color КолорПикера, оно изменяется при смене цвета.
Код:
function drawPlanshet(target_mc:MovieClip):MovieClip{
    var mc:MovieClip = target_mc.createEmptyMovieClip('mc', 1);
    mc.useHandCursor = false;
 
    mc.beginFill(cpicker.color);
    mc.lineTo(Stage.width, 0);
    mc.lineTo(Stage.width, Stage.height);
    mc.lineTo(0, Stage.height);
    mc.lineTo(0,0);
    mc.endFill();
 
    return mc;
}
Попробуйте догадаться, что еще нужно сделать, чтобы цвет менялся после его выбора.

KiL33 07.12.2008 20:23
Цитата:
Сообщение от Kuruki (Сообщение 782101)
Попробуйте догадаться, что еще нужно сделать, чтобы цвет менялся после его выбора.
Видимо обращаться к функции drawPlanshet при выборе цвета:)
Спасибо ещё раз за помощь!
_____________

ОЙ_сейчас проверил, видимо фон всё же накладывается поверх линий, тогда над этим мне надо будет ещё по размышлять:)

Добавлено через 22 часа 19 минут
Что-то ни как не получается решить проблему с изменением фона.
После выбора цвета нарисованные линии исчезают и стопорится рисование.

Может быть, при вызове функции drawPlanshet я убиваю инстанту мувика в котором происходит рисование?

Kuruki 12.12.2008 11:28
Цитата:
Сообщение от KiL33 (Сообщение 782149)
Может быть, при вызове функции drawPlanshet я убиваю инстанту мувика в котором происходит рисование?
Да, правильно. Я не заметил, что функции-обработчики вешаются на сам "планшет", а нужно на контейнер, его содержащий.
Код AS1/AS2:
var lineCount:Number = 0;

var lineColor:Number = 0x9999FF;

var planshetColor:Number = 0xFFFF00;

var penUp:Boolean = false;

 

container.useHandCursor = false;

 

drawPlanshet(container);

 

function drawPlanshet(target_mc:MovieClip):MovieClip{

    var mc:MovieClip = target_mc.createEmptyMovieClip('mc', 1);

 

 

    mc.beginFill(cpicker.color);

    mc.lineTo(Stage.width, 0);

    mc.lineTo(Stage.width, Stage.height);

    mc.lineTo(0, Stage.height);

    mc.lineTo(0,0);

    mc.endFill();

 

    return mc;

}

 

container.onPress = ...

container.onMouseMove = ...

container.onRelease = ...

 

function undo(){

    container['inLine' + lineCount].removeMovieClip();

    lineCount--;

}


Часовой пояс GMT +4, время: 15:10.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.