Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)
-   -   Тип * (http://www.flasher.ru/forum/showthread.php?t=123556)

willis83 04.04.2009 14:53

Тип *
 
Вот интересно знать, для общего развития, оправдано ли использование типа * для переменных и другой нечисти? Когда в проекте размножаются переменные, функции и объекты как грибы после дождя, и определение новых превращается в рутинное дело, вредит ли проекту определение их типа как * соблюдая все связи по коду? Вообщем велико ли влияние использование типа * на работоспособность и использование памяти мувиком? Я понимаю, что такой проект очень трудно будет читать, но над проектом работает один человек и помнит что куда влезает и откуда вылезает.

etc 04.04.2009 15:36

На память не повлияет, а на скорости скажется отрицательно.

wvxvw 04.04.2009 15:39

такой тип необходимо ставить только когда значение может быть undefined. Если вы знаете, что значение этой переменной может быть undefined, то вы никакой другой тип туда не придумаете т.как РТЕ будут. А если нет - то и смысл использования мне не понятен.

willis83 04.04.2009 15:42

Спасибо, понял.

Crash512 05.04.2009 11:20

Ещё есть такой момент: Даже если над проектом работает один человек, и якобы всё помнит... Через полгода-год он может не вспомнить ничего=) Имею опыт по этой части=) После пары обломов начал давать переменным чёткие понятные имена и строгую типизацию. Чтобы не возникало потом "... а что это за икс такой?.."=)))

willis83 05.04.2009 12:18

8) с этим я тоже сталкивался.... пару часиков посидеть пришлось как-то раз, чтобы восстановить ход мысли

litebox 06.04.2009 13:26

Типизация данных, это, безусловно, хорошо, и на этапе компиляции позволяет выловить много ошибок. А нужно ли типизировать массивы?
Например, код выполняется в ENTER_FRAME:
Код AS3:

for (var i:int = 0; i < 4; i++)
{
  alpha = (dy + oneSector * (i - 1.5)) / rad;
 
  destPoint.y = Math.round(radius * Math.sin(alpha));
 
  reelLine[i].y = destPoint.y;
 
  if (reelLine[i].visible == true)
    lineBitmap.copyPixels(bitmaps[reelLine[i].bitmapIndex], symbolRect, destPoint);
}

выполняется как то быстрее, чем код:
Код AS3:

for (var i:int = 0; i < 4; i++)
{
  alpha = (dy + oneSector * (i - 1.5)) / rad;
 
  destPoint.y = Math.round(radius * Math.sin(alpha));
 
  (reelLine[i] as VideoSymbol).y = destPoint.y;
 
  if ((reelLine[i] as VideoSymbol).visible == true)
    lineBitmap.copyPixels(bitmaps[(reelLine[i] as VideoSymbol).bitmapIndex], symbolRect, destPoint);
}

Хотя второй вариант предпочтительнее и более строгий

etc 06.04.2009 13:36

А если бы вынесли ссылку на i-ый элемент, то было бы вообще замечательно.

litebox 06.04.2009 13:48

Об этом я думал... но есть ли смысл создавать дополнительный указатель, если к элементу массива я обращаюсь всего 3 раза? И если его делать, то объявлять в классе, а не локально в функции ENTER_FRAME?

BlooDHounD 06.04.2009 14:00

ваши всего 3 раза и дают замедление.

litebox 06.04.2009 14:10

попробовал такой вариант:
Код AS3:

private var currSymbol:VideoSymbol; // объявлена в классе глобально
 
for (var i:int = 0; i < 4; i++)
{
  currSymbol = reelLine[i];
 
  angle = (dy + oneSector * (i - 1.5)) / rad;
 
  destPoint.y = Math.round(radius * Math.sin(angle));
 
  currSymbol.y = destPoint.y;
 
  if (currSymbol.visible == true)
    lineBitmap.copyPixels(bitmaps[currSymbol.bitmapIndex], symbolRect, destPoint);
}

работать стало немножко медленне :(

BlooDHounD 06.04.2009 14:36

а в локальную переменную не?

litebox 06.04.2009 14:45

Думаю не, т.к. в часто вызываемых функциях (будь то цикл ENTER_FRAME, или main loop win32-приложения) лучше не плодить локальные переменные, т.к. на каждый ENTER_FRAME будет выделяться память для ее создания и, как следствие, больше работы для сборщика мусора.

etc 06.04.2009 14:54

Переменные в цикле не являются локальными только лишь относительно тела цикла. Они являются локальными относительно всего метода, поэтому никаких пересоздаваний и выделения памяти не будет.

BlooDHounD 06.04.2009 14:55

litebox, у Вас очень усреднённое понятие о работе приложений на АС3.

CrazyFlasher 06.04.2009 15:20

я юзаю в 2-х случаях:
1. когда делал кастомный логгер
2. когда делаю кастомне событие, которому дабавляю переменную dataObj:*

wvxvw 06.04.2009 15:21

Кроме всего прочего:
Код AS3:

if (currSymbol.visible == true)

по крайней мере MXMLC должен был бы выдать предупреждение о том, что сравнение с булевыми значениями - это просто бессмысленные несколько символов в вашем коде. Переменные булевого типа не могут быть чем-то кроме true или false - соответственно, сравнивать их с true или false бессмысленно.

litebox 06.04.2009 15:57

Цитата:

Переменные в цикле не являются локальными только лишь относительно тела цикла. Они являются локальными относительно всего метода, поэтому никаких пересоздаваний и выделения памяти не будет.
Я знаю, я писал не про переменную в цикле, а про локальную переменную функции ENTER_FRAME.

Цитата:

litebox, у Вас очень усреднённое понятие о работе приложений на АС3
Очень дельный совет ))

Несколько бессмысленных символов в коде меня не пугают, главное, чтобы это хорошо читалось и через месяц, и через год. Если для компилятора есть какая-то разница между
Код AS3:

if (currSymbol.visible == true)

и
Код AS3:

if (currSymbol.visible)

в плане быстродействия, я, конечно, уберу проверку.

Gaen 06.04.2009 16:30

litebox, какое-то время назад здесь поднималась тема, в которой было эксперементально доказано, что обращение к локальной переменной работает в разы быстрее, чем обращение к свойству объекта.

wvxvw 06.04.2009 16:44

@litebox:
Код AS3:

if (currSymbol.visible == true)

Это не просто плохо читается, это не компилируется при стандартных настройках...

litebox 06.04.2009 16:57

И что же я такого настроил во Flash IDE?

Цитата:

litebox, какое-то время назад здесь поднималась тема, в которой было эксперементально доказано, что обращение к локальной переменной работает в разы быстрее, чем обращение к свойству объекта
Я не спорю, что оно работает быстрее. Просто есть определенные рамки, когда быстрее, а когда нет, например, если есть массив экземпляров классов, скажем, MovieClip'ов, то код
Код AS3:

for (var i:int = 0; i < 150; i++)
{
  var clip:MovieClip = arr[i];
 
  clip.visible = true;
}

врядли будет работать быстрее, чем
Код AS3:

for (var i:int = 0; i < 150; i++)
{
  arr[i].visible = true;
}


wvxvw 06.04.2009 17:37

А при чем тут Флеш?

BlooDHounD 06.04.2009 17:52

провёл тупой тест. второй способ быстрее в 2 раза.
Код AS3:

function test():void {
        const l:uint = 10E3;
        var i:uint;
        var arr:Array = new Array();
        for ( i=0; i<l; i++ ) {
                arr.push( new MovieClip() );
        }
        var t:Number;
        // тест скорости 1
        t = getTimer();
        for ( i=0; i<l; i++ ) {
                arr[ i ].visible = false;
        }
        for ( i=0; i<l; i++ ) {
                arr[ i ].visible = true;
        }
        trace( getTimer() - t );
        // тест скорости 2
        t = getTimer();
        for ( i=0; i<l; i++ ) {
                ( arr[ i ] as MovieClip ).visible = false;
        }
        for ( i=0; i<l; i++ ) {
                ( arr[ i ] as MovieClip ).visible = true;
        }
        trace( getTimer() - t );
}
test();


etc 06.04.2009 17:52

Цитата:

Сообщение от litebox (Сообщение 811225)
И что же я такого настроил во Flash IDE?


Я не спорю, что оно работает быстрее. Просто есть определенные рамки, когда быстрее, а когда нет, например, если есть массив экземпляров классов, скажем, MovieClip'ов, то код
Код AS3:

for (var i:int = 0; i < 150; i++)
{
  var clip:MovieClip = arr[i];
 
  clip.visible = true;
}

врядли будет работать быстрее, чем
Код AS3:

for (var i:int = 0; i < 150; i++)
{
  arr[i].visible = true;
}


Достаточно провести примитивный тест, чтобы убедиться в обратном:

Код AS3:

function test():void {
        var c:uint = 1e5;
        var i:uint;
        var a:Array = new Array();
 
        for (i = 0;i < c;i++) {
                a.push(new Sprite());
        }
 
        var t:uint = getTimer();
 
        for (i = 0;i < c;i++) {
                a[i].visible = false;
        }
 
        trace(getTimer() - t); // 65
        t = getTimer();
 
        for (i = 0;i < c;i++) {
                var s:Sprite = a[i] as Sprite;
                s.visible = true;
        }
 
        trace(getTimer() - t); // 17
}
test();


BlooDHounD 06.04.2009 17:54

так второй способ стал ещё быстрее
Код AS3:

function test():void {
        const l:uint = 15E3
        var i:uint;
        var arr:Array = new Array();
        for ( i=0; i<l; i++ ) {
                arr.push( new MovieClip() );
        }
        var t:Number;
        // тест скорости 1
        t = getTimer();
        for ( i=0; i<l; i++ ) {
                arr[ i ].visible = false;
                arr[ i ].visible = true;
        }
        trace( getTimer() - t );
        // тест скорости 2
        var mc:MovieClip;
        t = getTimer();
        for ( i=0; i<l; i++ ) {
                mc = arr[ i ] as MovieClip;
                mc.visible = false;
                mc.visible = true;
        }
        trace( getTimer() - t );
}
test();

Добавлено через 30 секунд
__etc, я быстрее ;)

litebox 06.04.2009 18:01

Цитата:

Сообщение от wvxvw (Сообщение 811219)
@litebox:
Код AS3:

if (currSymbol.visible == true)

Это не просто плохо читается, это не компилируется при стандартных настройках...

Во Flash IDE это компилируется со стандартными настройками

За примеры спасибо, буду разбираться :)

CrazyFlasher 06.04.2009 18:07

Цитата:

Во Flash IDE это компилируется со стандартными настройками
а зря

Stargazer 06.04.2009 18:15

Цитата:

Цитата:

Во Flash IDE это компилируется со стандартными настройками
а зря
Почему зря?

Не могу понять, где противоречие с точки зрения логики.
2 операнда сравниваются на логическое равенство - в чём необходимость запрещать это делать и на каких основаниях?

CrazyFlasher 06.04.2009 18:21

елси правда равна правде...или если правда равна вранью...мягко говоря не звучит, да?

iNils 06.04.2009 18:27

Цитата:

2 операнда сравниваются на логическое равенство - в чём необходимость запрещать это делать и на каких основаниях?
По сути идет такое сравнение
Код AS3:

if (true==true) {}


BlooDHounD 06.04.2009 18:34

iNils, мпоню на форме вылазило что-то типа того:
Код AS3:

if ( !( urrSymbol.visible.toString().length > 4 == true ) ) {...


wvxvw 06.04.2009 18:35

>> Во Flash IDE это компилируется со стандартными настройками
Во Flash IDE настройки не стандартные.

iNils 06.04.2009 18:41

Цитата:

Сообщение от BlooDHounD (Сообщение 811284)
iNils, мпоню на форме вылазило что-то типа того:
Код AS3:

if ( !( urrSymbol.visible.toString().length > 4 == true ) ) {...


Что-то такое помню. Посидели в офисе, посмеялись. :D

litebox 06.04.2009 18:54

Цитата:

Сообщение от iNils (Сообщение 811281)
По сути идет такое сравнение
Код AS3:

if (true==true) {}


if (true==true) {}
Ну, если так рассуждать..., а если бы это был int, то можно было бы написать:
Код AS3:

if (3==3) {}

или
Код AS3:

if (5==5) {}

Есть дискретное множество, из которого можно выбрать несколько вариантов, какая разница, это множество int, или множество из двух элементов?

Gaen 06.04.2009 19:00

litebox, аналогия неверная

тут скорее if(3==3) эквивалентно if(true)
а вот if((3==3)==true) есть то самое if(true==true)

iNils 06.04.2009 19:33

Цитата:

Есть дискретное множество, из которого можно выбрать несколько вариантов, какая разница, это множество int, или множество из двух элементов?
Дело не в количестве элементов, а в их природе. Для работы условия нужно булево значение. И если переменная также является булевым типом, то сравнение избыточно. А вот с числами значении мало, нужно их сопоставить, и это сопоставление и даст вам результат для работы условия.

Stargazer 06.04.2009 20:19

Цитата:

Сообщение от iNils (Сообщение 811281)
По сути идет такое сравнение
Код AS3:

if (true==true) {}


Ну да. Но всё равно не понимаю, почему это неправильно.
Это просто избыточно или это и правда в каком-то смысле неправильно?

А что насчёт конструкции
Код AS1/AS2:

if (a == false)

?

CrazyFlasher 06.04.2009 20:24

2Stargazer: похоже вы так и не поняли о чём речь

VVall 06.04.2009 20:28

== и прочие условия - это операторы сравнения, возвращающие true или false. if сам по себе ничего не сравнивает, он срабатывает, если аргумент true. Поэтому if(a==true) или if(a==false) избыточно - сначала оператор сравнения возвращает true или false, а потом if смотрит возвращённое значение. В этом нет смысла, так как можно сразу смотреть значение.

BlooDHounD 06.04.2009 20:29

@Stargazer
ситуация. ноут умеет принимать 2 положения. открытое и закрытое. узнать, в каком он состоянии, можно просто посмотрев на него. и мозг сам даст Вам сигнал о том, в каком он состоянии. но можно пойти другим путём: взять транспортир и отмерить угол, под которым находится крышка. в итоге мозг получит тот же сигнал.


Часовой пояс GMT +4, время: 00:15.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.