var image:DisplayObject = this.loader.content;

image.x -= image.width / 2;

image.y -= image.height / 2;

image.rotation = 90;

// функция поворота на угол в градусах относительно точки,

// находящейся в пределах отображаемого объекта

function rotateAroundPoint(doInstance:DisplayObject, angleDegrees:Number, ptRotationPoint:Point):void

{

        var m:Matrix = doInstance.transform.matrix;

 

        ptRotationPoint = m.transformPoint(ptRotationPoint);

 

        m.tx -= ptRotationPoint.x;

        m.ty -= ptRotationPoint.y;

        m.rotate( angleDegrees * (Math.PI / 180) );

        m.tx += ptRotationPoint.x;

        m.ty += ptRotationPoint.y;

        doInstance.transform.matrix = m;

}

 

// аналогичная функция, только для масштабирования отностительно точки,

// лежащей внутри отображаемого объекта

function scaleFromPoint(doInstance:DisplayObject, sx:Number, sy:Number, ptScalePoint:Point):void

{ 

        var m:Matrix = doInstance.transform.matrix;

 

        ptScalePoint = m.transformPoint(ptScalePoint);

 

        m.tx -= ptScalePoint.x;

        m.ty -= ptScalePoint.y;

        m.scale(sx, sy);

        m.tx += ptScalePoint.x;

        m.ty += ptScalePoint.y;

 

        doInstance.transform.matrix = m;

}

 

// задаем "точку регистраци" в центре someDisplayObject

var centerPoint:Point = new Point(someDisplayObject.width * .5, someDisplayObject.height * .5);

 

// поворачиваем someDisplayObject на 45 градусов относительно центра

rotateAroundPoint(someDisplayObject, 45, centerPoint);

// увеличиваем масштаб someDisplayObject в 2 раза относительно центра

scaleFromPoint(someDisplayObject, 2, 2, centerPoint);

package eee 

{

        import flash.display.*;

        import flash.geom.*;

        import flash.utils.*;

        import flash.events.*;

 

        public class NewClass extends MovieClip

        {

                private var trans:Transform;

                private var myMatrix:Matrix = new Matrix;

                private var fig:Object;

                private var bm:Bitmap;

                private var i:int;

                private var sX:int;

                private var sY:int;

                public function NewClass() 

                {

                        bm = new Bitmap(new BMD_Start(0, 0));

                        addChild(bm);

                        trans = new Transform(bm);

                        sX = bm.width/2;

                        sY = bm.height/2;

                        addEventListener(Event.ENTER_FRAME, enterFrameHandler);

                }

 

                private function enterFrameHandler(evt:Event):void {

                        i++; if (i > 360) i = 0;

                        setTransform(100, 100, i, sX, sY);

                }

 

                public function setTransform(_x:int, _y:int, _ang:int, centrX:int=20, centrY:int=40):void {

                        myMatrix.identity();

                        myMatrix.tx -= centrX;

                        myMatrix.ty -= centrY;

                        myMatrix.rotate( _ang * Math.PI/180 );

                        myMatrix.tx += _x;

                        myMatrix.ty += _y;

                        trans.matrix = myMatrix;

                }

        }

 

}