Форум Flasher.ru - JSON -> XML ?

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - JSON -> XML ? (http://www.flasher.ru/forum/showthread.php?t=146869)

Сейчас пользуюсь классом JSON от Adobe, но там преобразование происходит в объект. По ряду причин мне нужно, чтобы это был XML.

Писать самому ручками или есть какое готовое решение? Что-то я не нашел.

А объект после этого в XML это долго разве?

да нет, понятно, что надо пройтись по его свойствам и сформировать xml
при этом, очевидно, на любом уровне может оказаться массив, так что сам обход надо делать с рекурсией

но если есть библиотека, в которой решено все под ключ, то чего изобретать велосипед? потом еще xml->json может понадобиться

интересно, кстати, почему адоб сам не добавил метод JSON.decodeToXML(strJSON) в собственную библиотеку?

потому что Объект - это объект, а ХМЛ - это неведомая штука, в которой не понятно что будет узлами, что атрибутами, что будет заворачиваться в сидату, что нет и т.д..очень много "НО".

да ладно
чего бы не отдавать какой-нибудь вариант simpleXML, состоящий из одних узлов, безо всяких атрибутов и прочей шелухи?

ок..как вариант

Код AS3:

var obj:Object = new Object();

obj.param = "</blabla";

как преобразовать в XML?

Все строковые значения можно пихать в <![CDATA[]]>

видимо, как-то так:

Код:

<obj>

  <param>&lt;/blabla</param>

</obj>

f.g.programmer, не панацея )

Код AS3:

var obj:Object = new Object();

obj.param = "blabla]]>";

mikhailk получается все нужно конвертить..хз насколько состоятельна эта затея (

не конвертить, а экранировать

ну, так получение xml - это ж не самоцель.
я с ним потом работаю.

Не изобретайте велосипед, гляньте на класс SimpleXMLEncoder, вполне способен справится с Вашей задачей.

Код AS3:

private function objectToXML(object:Object, rootNode:String = "root"):XML

{

        import mx.rpc.xml.SimpleXMLEncoder;

 

        var xmlDocument:XMLDocument = new XMLDocument();

        var xmlEncoder:SimpleXMLEncoder = new SimpleXMLEncoder(xmlDocument);

        xmlEncoder.encodeValue(object, new QName(rootNode), xmlDocument);

 

        return new XML(xmlDocument.toString());

}

Правда в чистом виде он тащит за собой около 20Кб флексовых классов, но это не проблема, я когда то делал из него независимую версию, вышло что то около 5Кб по итогу. Если нужно попробую отрыть и прикреплю тут.

о, на что-то такое я и надеялся :)
буду смотреть

Добавлено через 1 час 18 минут
все работает

возможно, кому понадобится полностью (оформил как простой код, поскольку в AS3 перекодируется JSON):

Код:

package 

{

        import flash.display.*;

        import flash.events.*;

        import flash.xml.*;

        import mx.rpc.xml.SimpleXMLEncoder;

        import com.adobe.serialization.json.*;        

        

        public class Main extends Sprite 

        {

                

                public function Main():void 

                {

                        if (stage) init();

                        else addEventListener(Event.ADDED_TO_STAGE, init);

                }

                

                private function init(e:Event = null) : void 

                {

                        removeEventListener(Event.ADDED_TO_STAGE, init);

                        

                        var stringJSON:String = '{"param1":"1","param2":"</blabla","param3":"blabla]]>",'

                                       +'"paramArray":[{"id":"1","value":"111"},{"id":"2","value":"222"}]}';



                        var objXML:XML = jsonToXML(stringJSON);

                        trace(objXML);

                }

                

                private function jsonToXML(stringJSON:String) : XML

                {

                        var obj:Object = JSON.decode(stringJSON); 

                        var objXML:XML = objectToXML(obj);

                        

                        return(objXML);

                }

                

                private function objectToXML(object:Object, rootNode:String = "root") : XML

                {

                        var xmlDocument:XMLDocument = new XMLDocument();

                        var xmlEncoder:SimpleXMLEncoder = new SimpleXMLEncoder(xmlDocument);

                        xmlEncoder.encodeValue(object, new QName(rootNode), xmlDocument);

                 

                        return new XML(xmlDocument.toString());

                }

        }

        

}

вывод:

Код:

<root>

  <param1>1</param1>

  <param2>&lt;/blabla</param2>

  <param3>blabla]]&gt;</param3>

  <paramArray>

    <item>

      <id>1</id>

      <value>111</value>

    </item>

    <item>

      <id>2</id>

      <value>222</value>

    </item>

  </paramArray>

</root>