Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)
-   -   Не правильно срабатывает Event.MOUSE_LEAVE (http://www.flasher.ru/forum/showthread.php?t=150585)

Dragon rideR 14.02.2011 15:05

Не правильно срабатывает Event.MOUSE_LEAVE
 
Подскажите пожалуйста не правильно срабатывает Event.MOUSE_LEAVE, теоретически он должен сработать когда курсор покидает флэшку, а у меня он срабатывает когда курсор покинул флэшку и я отпустил кнопку.
Код AS3:

private function onDown(e:Event)
                {
                        //подписываем на отпускание мыши и покидание экрана
                        //stage.addEventListener(MouseEvent.MOUSE_UP, onUp, false, 0, true);
                        stage.addEventListener(Event.MOUSE_LEAVE, onUp, false, 0, true);
                        stage.addEventListener(MouseEvent.MOUSE_MOVE, drawFon, false, 0, true);
                        var bounds:Rectangle=new Rectangle(rectX, rectY, rectWidth, rectHeight);
                        Params.game.startDrag(false, bounds);
                }
        private function onUp(e:Event)
                {
                        stage.removeEventListener(MouseEvent.MOUSE_UP, onUp);
                        stage.removeEventListener(Event.MOUSE_LEAVE, onUp);
                        stage.removeEventListener(MouseEvent.MOUSE_MOVE, drawFon);
                        this.stopDrag();
}


nOobCrafter 14.02.2011 15:31

это нормальное явление. При нажатии можно подписаться на ентерфрейм и отслеживать координату курсора.

Dragon rideR 14.02.2011 15:58

спасибо помог

Omar2002 06.06.2011 15:44

Спасибо - тоже помогло :)

alatar 06.06.2011 16:30

Цитата:

При нажатии можно подписаться на ентерфрейм и отслеживать координату курсора.
Лучше на MOUSE_MOVE, зачем каждый фрейм следить?

nOobCrafter 06.06.2011 20:07

Цитата:

зачем каждый фрейм следить?
затем что мышкой двигаем чаще нежели происходит ентерфрейм.

alatar 06.06.2011 20:23

Цитата:

Сообщение от nOobCrafter (Сообщение 1001667)
затем что мышкой двигаем чаще нежели происходит ентерфрейм.

Чаще, события мыши, приходить просто "физически" не смогут. Флеш-плеер на такое не способен. Но в отличие от ENTER_FRAME, мышка может и не двигаться.

gloomyBrain 06.06.2011 20:47

Цитата:

Чаще, события мыши, приходить просто "физически" не смогут
Смогут и будут происходить. И будут висеть в очереди, пока не наступит новый кадр и их не обработают. При этом есть вполне осязаемый шанс выполнять один и тот же код обработчика 2-3 раза за кадр (рано как и ни одного раза)

tsarapkabel 06.06.2011 21:20

Цитата:

Сообщение от alatar (Сообщение 1001673)
Чаще, события мыши, приходить просто "физически" не смогут. Флеш-плеер на такое не способен. Но в отличие от ENTER_FRAME, мышка может и не двигаться.

updateAfterEvent как раз и предназначен для того, чтобы события обрабатывались чаще чем ENTER_FRAME, я правильно понимаю?

Hidest 06.06.2011 21:51

Цитата:

Сообщение от tsarapkabel (Сообщение 1001680)
updateAfterEvent как раз и предназначен для того, чтобы события обрабатывались чаще чем ENTER_FRAME, я правильно понимаю?

Он нужен чтобы принудительно отрисовать экран при наступлении события.

alatar 07.06.2011 12:46

Цитата:

Смогут и будут происходить. И будут висеть в очереди, пока не наступит новый кадр и их не обработают. При этом есть вполне осязаемый шанс выполнять один и тот же код обработчика 2-3 раза за кадр (рано как и ни одного раза)
Поясню свою мысль, возможно неясно выразился. Да, событие мыши может возникать чаще чем enterFrame, но только пока длится фаза событий, если эту фазу нагрузить, то события мыши не будут приходить вообще, в отличие от enterFrame (у плеера нет отдельного модуля, который следит за событиями).
Небольшой тест.
Код AS3:

package 
{
        import flash.display.*;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;
 
        public class Main extends Sprite
        {
                private var _slowButton:Sprite;
                private var _fastButton:Sprite;
 
                public function Main():void
                {
                        stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
 
                        var g:Graphics = graphics;
                        g.beginFill(0);
                        g.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
                        g.endFill();
 
                        _slowButton = new Sprite();
                        drawButton(_slowButton.graphics, 0xFF0000);
                        _slowButton.x = 20;
                        _slowButton.y = 20;
                        _slowButton.addEventListener(MouseEvent.CLICK, slow);
                        addChild(_slowButton);
 
                        _fastButton = new Sprite();
                        drawButton(_fastButton.graphics, 0x00FF00);
                        _fastButton.x = 140;
                        _fastButton.y = 20;
                        _fastButton.addEventListener(MouseEvent.CLICK, fast);
                        addChild(_fastButton);
 
                        stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                        addEventListener(Event.EXIT_FRAME, onExitFrame);
                }
 
                private function drawButton(g:Graphics, color:uint):void
                {
                        g.beginFill(color);
                        g.drawRect(0, 0, 100, 20);
                        g.endFill();
                }
 
                private function slow(event:MouseEvent) : void { 
            trace("Slow Event - Start"); 
 
            var i : int = 0 
            while(i < 10000000) { 
                i++; 
            } 
            /* Пока работает цикл
                        * новые события не принимаются.
                        * Если в этот момент вывести мышь
                        * за stage, то ни одного
                        * события mouseMove не возникнет.
                        * Если поводить мышкой и оставить
                        * в области stage, то возникнет
                        * только одно событие mouseMove
                        */

            trace("Slow Event - Finish"); 
        } 
 
        private function fast(event:MouseEvent) : void { 
            trace("Fast Event"); 
        }
 
                private function onExitFrame(e:Event):void
                {
                        trace("exit");
                }
 
                private function onEnterFrame(e:Event):void
                {
                        trace("enter");
                        var i : int = 0 
            while(i < 3000000) { 
                i++; 
            } 
                }
 
                private function onMouseMove(e:MouseEvent):void
                {
                        trace("move");
                }
        }
}



Часовой пояс GMT +4, время: 12:18.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.