Форум Flasher.ru - Timeline button

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - Timeline button (http://www.flasher.ru/forum/showthread.php?t=187332)

У кнопки есть по идеи 4 состояния up over down hit. Как можно достучаться до каждого из них? Просто скажем если переменная равняется 4, то у кнопки button мы выбираем состояние hit, если переменная равняется 3, то down....

Напишите свой класс кнопки, который будет слушать события MouseEvent.ROLL_OVER, MouseEvent.ROLL_OUT, MouseEvent.MOUSE_DOWN, MouseEvent.MOUSE_UP. И куда можно будет добавлять различный контент. Так и получите доступ к состояниям кнопки.

Получить DisplayObject'ы с состояниями кнопки можно через ее свойства upState, overState, downState и hitTestState. Но при этом SimpleButton не позволяет программно устанавливать текущее состояние.
Для того, чтобы управлять состоянием кнопки программно, нужно, как сказал bav, написать свою реализацию кнопки на основе Sprite или MovieClip.

пфф) Думал что будет совсем все просто. Куда мне писать свою реализацию кнопки?) Я же совсем не знаю ас) Можете хоть примерно подсказать как будет выглядить этот класс?

Что-то вроде:

Код AS3:

package {

        import flash.display.Sprite;

        import flash.events.MouseEvent;

        import flash.text.TextField;

 

        public class MyButton extends Sprite {

                private var _myText:TextField;

 

                public function MyButton(){

                        super();

                        this.buttonMode = true;

                        this.mouseChildren = false;

 

                        _myText = new TextField();

                        addChild(_myText);

                        _myText.text = "я кнопка"

 

                        addEventListener(MouseEvent.MOUSE_OVER, buttonMouseOver);

                        addEventListener(MouseEvent.MOUSE_OUT, buttonMouseOut);

                        addEventListener(MouseEvent.MOUSE_DOWN, buttonMouseDown);

                        addEventListener(MouseEvent.MOUSE_UP, buttonMouseUp);

                }

                private function buttonMouseOver(e:MouseEvent):void{

                        _myText.text = "я кнопка"

                }

                private function buttonMouseOut(e:MouseEvent):void{

                        _myText.text = "я кнопка и на мне мышь"

                }

                private function buttonMouseDown(e:MouseEvent):void{

                        _myText.text = "я кнопка и я нажата"

                }

                private function buttonMouseUp(e:MouseEvent):void{

                        _myText.text = "я кнопка"

                }

        }

}

Мужики, ребята)! А скажите как удалить кнопку из символа? Есть символ Main как удалить из него кнопку button?

Код AS3:

var child:DisplayObject = Main.getChildByName("button");

if (child)

    Main.removeChild(child);

Цитата:

не знаю зачем тут писать отдельный класс кнопки, достучаться до любого состояния SimpleButton можно так:

Код AS3:

my_btn.upstate = ... //присваивайте что хотите

my_btn.overstate = ...

И что туда можно приписывать?

Спрайт, например?

Цитата:

Сообщение от Nickolai (Сообщение 1105120)

И что туда можно приписывать?

DisplayObject. Чтобы подобных вопросов не возникало, почитайте про SimpleButton.

Код AS1/AS2:

b_page1 = visual.getChildByName("b_page1") as SimpleButton;

                        b_page1.upstate = true;

Выдает ошибку

Там по ссылке даже пример написан:

Код AS3:

package {

    import flash.display.Sprite;

 

    public class SimpleButtonExample extends Sprite {

        public function SimpleButtonExample() {

            var button:CustomSimpleButton = new CustomSimpleButton();

            addChild(button);

        }

    }

}

 

import flash.display.DisplayObject;

import flash.display.Shape;

import flash.display.SimpleButton;

 

class CustomSimpleButton extends SimpleButton {

    private var upColor:uint   = 0xFFCC00;

    private var overColor:uint = 0xCCFF00;

    private var downColor:uint = 0x00CCFF;

    private var size:uint      = 80;

 

    public function CustomSimpleButton() {

        downState      = new ButtonDisplayState(downColor, size);

        overState      = new ButtonDisplayState(overColor, size);

        upState        = new ButtonDisplayState(upColor, size);

        hitTestState   = new ButtonDisplayState(upColor, size * 2);

        hitTestState.x = -(size / 4);

        hitTestState.y = hitTestState.x;

        useHandCursor  = true;

    }

}

 

class ButtonDisplayState extends Shape {

    private var bgColor:uint;

    private var size:uint;

 

    public function ButtonDisplayState(bgColor:uint, size:uint) {

        this.bgColor = bgColor;

        this.size    = size;

        draw();

    }

 

    private function draw():void {

        graphics.beginFill(bgColor);

        graphics.drawRect(0, 0, size, size);

        graphics.endFill();

    }

}

Цитата:

Сообщение от Nickolai (Сообщение 1105146)

Код AS1/AS2:

b_page1 = visual.getChildByName("b_page1") as SimpleButton;

b_page1.upstate = true;

Вы присваиваете булево значение true, а надо присваивать DisplayObject. Например, в приведённом мной коде, DisplayObject'ом является Shape.

да поспешил, правильно - upState и т.д. но тут в кодв видно

Мне кажется, автор хочет программно переводить кнопку в нажатое состояние, а не задавать внешний вид для этого состояния.

Gaen, совершенно верно.

я тут уже выкладывал пример кода, как можно программно задавать симплбаттону нажатые и прочие состояния: http://www.flasher.ru/forum/showthre...eButton&page=9