Форум Flasher.ru - Непостоянство MOUSE

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - Непостоянство MOUSE_LEAVE (http://www.flasher.ru/forum/showthread.php?t=214073)

Непостоянство MOUSE_LEAVE

Всем привет.
Мне нужно ловить событие, когда курсор выходит за пределы окна проектора. Использую MOUSE_LEAVE.
Все нормально работает до тех пор, пока я в своем приложении не переключусь в полноэкранный режим и потом обратно. После этого MOUSE_LEAVE перестает срабатывать.
Но стоит изменить размер окна мышкой, MOUSE_LEAVE снова в деле...
Кто нибудь сталкивался с этим? Глюк?
Компилирую через FlashBuilder. Mac OS 10.9.5

Подробно о том, что делаю:
В программе есть менюшка, которая должна появляться при активности мыши (но только когда мышь находится в пределах окна программы). И при простое - скрываться вместе с курсором.
Кстати, в конструкторе Mouse.hide тоже почему-то не срабатывает - только после первого MOUSE_OVER.. Очень странно..

Код AS3:

public class MainMenu extends MainMenuSWC

{

        private var _timerIdle:Timer;

 

                public function MainMenu()

                {

                        visible = false;

                        Mouse.hide();

 

                        if (stage) initMonitoringMouseMove();

                        else addEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

                }

 

                private function initMonitoringMouseMove(e:Event = null):void

                {

                        removeEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

                        stage.addEventListener(Event.MOUSE_LEAVE, onMouseLeaveHandler);

                        stage.addEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

 

                        _timerIdle = new Timer(2000);

                        _timerIdle.addEventListener(TimerEvent.TIMER, onTimerIdleCompleteHandler);

 

                        onMouseOverHandler();

                }

 

                private function onMouseOverHandler(e:MouseEvent = null):void

                {

                        stage.removeEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

                        stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

                }

 

                private function onMouseLeaveHandler(e:Event):void

                {

                        stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

                        stage.addEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

                }

 

                private function onMouseMoveHandler(e:MouseEvent):void

                {

                        visible = true;

                        Mouse.show();

                        _timerIdle.delay = 2000;

                        _timerIdle.start();

                }

 

                private function onTimerIdleCompleteHandler(e:TimerEvent):void

                {

                        _timerIdle.stop();

                        visible = false;

                        Mouse.hide();

                }

 

                public function destroy():void

                {

                        removeEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

 

                        if (stage)

                        {

                                stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

                                stage.removeEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

                                stage.removeEventListener(Event.MOUSE_LEAVE, onMouseLeaveHandler);

                        }

 

                        if (_timerIdle)

                        {

                                _timerIdle.stop();

                                _timerIdle.removeEventListener(TimerEvent.TIMER, onTimerIdleCompleteHandler);

                        }

                }

}

Mouse.hide() у меня работает сразу в конструкторе. Stage нельзя подписать на MOUSE_OVER.

Mouse.hide() то работает. Но если курсор находится над окном плеера во время запуска, то он не скрывается. Передвигаю курсор с окна и снова навожу - после этого работает как и задумано..

Цитата:

Stage нельзя подписать на MOUSE_OVER.

Это почему? С этим вроде проблем нет, на MOUSE_OVER реагирует нормально..

Цитата:

Но если курсор находится над окном плеера во время запуска, то он не скрывается.

Ну так события MOUSE_OVER то не было)) Когда Вы подписали стейдж на это событие, мышь уже была над. Никакого изменения состояния не произошло — события не было.

Сам stage не реагирует на MOUSE_OVER. Его дети в дисплей-листе реагируют.

Вот немного переписал код. Курсор сразу скрывается при запуске приложения как вы хотите. И продолжает нормально работать после фуллскрина.

Код AS3:

package

{

    import flash.display.Bitmap;

    import flash.display.BitmapData;

    import flash.display.Sprite;

    import flash.display.StageDisplayState;

    import flash.display.StageScaleMode;

    import flash.events.Event;

    import flash.events.MouseEvent;

 

    public class Main extends Sprite

    {

        public function Main()

        {

            var bitmap:Bitmap = new Bitmap();

            bitmap.bitmapData = new BitmapData(800, 600, false, 0);

 

            var sprite:Sprite = new Sprite();

            addChild(sprite);

            sprite.addChild(bitmap);

 

            var mainMenu:MainMenu = new MainMenu();

            addChild(mainMenu);

 

            stage.addEventListener(MouseEvent.CLICK, stage_click);

        }

 

        private function stage_click(e:MouseEvent):void 

        {

            stage.scaleMode = StageScaleMode.EXACT_FIT;

            stage.displayState = StageDisplayState.FULL_SCREEN; 

        }

    }

}

Код AS3:

package

{

    import flash.display.Bitmap;

    import flash.display.BitmapData;

    import flash.events.Event;

    import flash.events.MouseEvent;

    import flash.events.TimerEvent;

    import flash.ui.Mouse;

    import flash.utils.Timer;

 

    public class MainMenu extends Bitmap

    {

        private var _timerIdle:Timer;

 

        public function MainMenu()

        {

            bitmapData = new BitmapData(100, 100, false, 0xff0000);

 

            visible = false;

            Mouse.hide();

 

            if (stage) initMonitoringMouseMove();

            else addEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

        }

 

        private function initMonitoringMouseMove(e:Event = null):void

        {

            removeEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

            stage.addEventListener(Event.MOUSE_LEAVE, onMouseLeaveHandler);

            stage.addEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

 

            _timerIdle = new Timer(2000);

            _timerIdle.addEventListener(TimerEvent.TIMER, onTimerIdleCompleteHandler);

 

            onMouseOverHandler();

        }

 

        private function onMouseOverHandler(e:MouseEvent = null):void

        {

            stage.removeEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

            stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

        }

 

        private function onMouseLeaveHandler(e:Event):void

        {

            trace('mouseLeave');

            stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

            stage.addEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

        }

 

        private function onMouseMoveHandler(e:MouseEvent):void

        {

            visible = true;

            Mouse.show();

            _timerIdle.delay = 2000;

            _timerIdle.start();

        }

 

        private function onTimerIdleCompleteHandler(e:TimerEvent):void

        {

            _timerIdle.stop();

            visible = false;

            Mouse.hide();

        }

 

        public function destroy():void

        {

            removeEventListener(Event.ADDED_TO_STAGE, initMonitoringMouseMove);

 

            if (stage)

            {

                stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMoveHandler);

                stage.removeEventListener(MouseEvent.MOUSE_OVER, onMouseOverHandler);

                stage.removeEventListener(Event.MOUSE_LEAVE, onMouseLeaveHandler);

            }

 

            if (_timerIdle)

            {

                _timerIdle.stop();

                _timerIdle.removeEventListener(TimerEvent.TIMER, onTimerIdleCompleteHandler);

            }

        }

    }

}

Цитата:

Сам stage не реагирует на MOUSE_OVER. Его дети в дисплей-листе реагируют.

А разве ивент не баблится от дитя до корня?

Цитата:

Wolsh, так я то пытаюсь скрыть курсор сразу при инициализации в конструкторе... и не работает..

Цитата:

Сообщение от undefined (Сообщение 1200088)

А разве ивент не баблится от дитя до корня?

Событие то баблится, но нужно обеспечить чтобы у стейджа был ребенок, размером с проектор.

callme, попробовал Ваш скрипт ) Точно так же как и у меня в проекте - не работает как надо. Вы видимо не заметили.. Курсор за пределами экрана не должен исчезать и ввлиять на появление менюшки. Когда внутри окна - то при движении мыши менюшка появляется, если простаивает - через 2 сек исчезает вместе с курсором. Все отлично - работает как и задумывалось.

Но теперь попробуйте перейти кликом в FullScreen и потом обратно в оконный режим. После этого MOUSE_LEAVE уже не ловится.. - и поэтмоу курсор за пределами окна начинает себя вести также, как и внутри... Если после этого мышкой изменить размер окна - MOUSE_LEAVE снова начинает работать.

Цитата:

Сообщение от djken (Сообщение 1200093)

Но теперь попробуйте перейти кликом в FullScreen и потом обратно в оконный режим. После этого MOUSE_LEAVE уже не ловится.. - и поэтмоу курсор за пределами окна начинает себя вести также, как и внутри... Если после этого мышкой изменить размер окна - MOUSE_LEAVE снова начинает работать.

Нет, у меня все работает как вы хотите. (на Windows, flash player 25.0.0.152 beta)

Похоже у вас баг плеера.

Менять курсор плеер может только в пределах своего окна.
Отлавливать MOUSE_MOVE плеер может только в пределах своего окна.

Скажите какая у вас версия плеера, проверю на ней. Чтобы узнать версию плеера, надо щелкнуть правой клавишей мыши в окне плеера. Либо trace(Capabilities.version);