//Импорт TweenMax и plugin для blur filter

import com.greensock.TweenMax;

 

//Запомним длину контента и маски.

//Присвойте длину вашего контента здесь!

var CONTENT_WIDTH:Number = 1500;

var MASK_WIDTH:Number = 330;

 

//Мы хотим знать, какая была предыдущая x-координата для контента (для анимации)

var oldX:Number = myContent.x;

 

//Располагаем контент в левом верхнем углу маски

myContent.x = myMask.x;

myContent.y = myMask.y;

 

//Установим маску для нашего контента

myContent.mask = myMask;

 

//Создадим прямоугольник, который будет действовать как ограничитель для scrollMC.

//Это способ, при помощи которого scrollMC можно перетаскивать только вдоль линии.

var bounds:Rectangle = new Rectangle(scrollMC.x,scrollMC.y,700,0);

 

//Мы хотим знать, когда пользователь скроллирует

var scrolling:Boolean = false;

 

//Слушаем, когда пользователь нажимает мышь на scrollMC

scrollMC.addEventListener(MouseEvent.MOUSE_DOWN, startScroll);

 

//Слушаем когда пользователь вращает колесико мыши

stage.addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);

 

//Слушаем, когда пользователь отпускает кнопку мыши

stage.addEventListener(MouseEvent.MOUSE_UP, stopScroll);

 

//Эта функция вызывается, когда пользователь перетаскивает scrollMC

function startScroll(e:Event):void {

 

        //Установим scrolling равным true

        scrolling = true;

 

        //Начинаем перетаскивать scrollMC 

        scrollMC.startDrag(false,bounds);

}

 

//Эта функция вызывается, когда пользователь заканчивает перетаскивание scrollMC

function stopScroll(e:Event):void {

 

        //Установим scrolling равным false

        scrolling = false;

 

        //Остановим перетаскивание

        scrollMC.stopDrag();

}

//Добавим ENTER_FRAME чтобы анимировать скроллирование

addEventListener(Event.ENTER_FRAME, enterHandler);

 

//Эта функция выполняется в каждом фрейме

function enterHandler(e:Event):void {

 

        //Проверяем, происходит ли скроллирование

        if (scrolling == true) {

 

                //Вычисляем расстояние scrollMC от левого края

                var distance:Number = Math.round(scrollMC.x - bounds.x);

 

                //Вычисляем процентное содержание расстояния по отношению к длине линии.

                //Итак, когда scrollMC слева, percentage равно 0 ,

                // а когда справа - percentage равно 1.

                var percentage:Number = distance / MASK_WIDTH;

 

                //Сохраним старую x - координату

                oldX = myContent.x;

 

                //Вычисляем новую x -координату (targetX) для контента.

                //Мы вычитаем длину маски из длины контента.

                //Таким образом, контент должен двигаться влево, когда мы прокручиваем вправо.

                //Удалите вычитание, чтобы убедиться лично!

                var targetX:Number = -((CONTENT_WIDTH - MASK_WIDTH) * percentage) + myMask.x;

 

                //Мы хотим анимировать скроллирование только если старый х отличается от нового х.

                //В нашем мувике мы анимируем прокрутку, если разница больше чем 5 пикселов.

                if (Math.abs(oldX - targetX) > 5) {

 

                        //Твин контента на новую позицию.

                        //Вызываем функцию tweenFinished() когда твин завершится.

                        TweenMax.to(myContent, 2, {x: targetX, blurFilter:{blurX:0, blurY:0}, onComplete: tweenFinished});

                }

        }

}

//Эта функция вызывается, когда твин завершается

function tweenFinished():void {

        //твин для возврата контента к нормальному состоянию (= удалим blur)

        TweenMax.to(myContent, 0.3, {blurFilter:{blurX:0, blurY:0}});

}

function mouseWheelHandler(event:MouseEvent):void {

        if ((event.delta < 0 && scrollMC.x > bounds.x) ||

                (event.delta > 0 && scrollMC.x < bounds.x + bounds.width))

        {

                scrolling = true;

                scrollMC.x = scrollMC.x + (event.delta * 9);

        }

}