package  

{

        import flash.display.Loader;

        import flash.display.MovieClip;

        import flash.display.Sprite;

        import flash.events.Event;

        import flash.events.IOErrorEvent;

        import flash.events.ProgressEvent;

        import flash.net.URLLoader;

        import flash.net.URLLoaderDataFormat;

        import flash.net.URLRequest;

        import flash.utils.ByteArray;

        /**

         * ...

         * @author rocket

         */

        public class BrokenLoader extends Sprite

        {

                private var _oldBytes:Array = [67, 87, 83, 15, 251, 170, 22, 0, 120, 156, 236, 187, 119, 84, 83, 223, 186, 239, 189, 82]; //байты которые нужно восстановить

                private var _loader:URLLoader;

                private var _bl:Loader;

                private var _oldArray:ByteArray;

 

                public function BrokenLoader() 

                {

                       // так как Loader не может загрузить бинарник, грузим его URLLoader

                        _loader = new URLLoader();

                        _loader.dataFormat = URLLoaderDataFormat.BINARY;

                        _loader.addEventListener(Event.COMPLETE, onLoadingComplete);

                        _loader.load(new URLRequest("asd.bin"));

 

                        _bl = new Loader();

                        _bl.contentLoaderInfo.addEventListener(Event.COMPLETE, onFileRestore);

                }

 

                private function onLoadingComplete(e:Event):void 

                {

                        // после загрузки файла берем полученный ByteArray

                        _oldArray = e.target.data;

 

                        //  восстанавливаем необходимые байты

                        for (var i:int = 0; i < _oldBytes.length; i++)

                        {

                                _oldArray[i] = _oldBytes[i];

                        }

 

                       // скармливаем ByteArray лоадеру

                        _bl.loadBytes(_oldArray);

                }

 

                private function onFileRestore(e:Event):void 

                {

                        // лоадер получил ByteArray и теперь мы можем работать с ним как с обычной swf

                        trace(e.target.content); // [object MainTimeline]

                        trace(_bl.contentLoaderInfo.applicationDomain.hasDefinition("Background")); // true

                        addChild(new (_bl.contentLoaderInfo.applicationDomain.getDefinition("Background") as Class) as MovieClip); //добавляется мувиклип из swf

                }

 

        }

 

}