Форум Flasher.ru - Кнопка в кнопке.

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - Кнопка в кнопке. (http://www.flasher.ru/forum/showthread.php?t=185575)

Кнопка в кнопке.

Добрый вечер! Никак не могу решить проблему: мне нужно сделать мувик, чтобы при наведении на икноке появлялась плашка с кнопкой на этой плашке.

Я сделал отдельно мувик btn_irradiar, иконку - btn_irradiar_icon, плашку btn_irradiar_pl и кнопку. Первое с чем сталкнулся - плашка у меня на расстоянии от иконке - когда курсор попадал туда все начинало мигать - решил это через прозрачную плашку-переход btn_hidden_1.

Чтобы плашка не пропадала при наведении на нее и наведении на кнопку, я сделал так:

Если делаю btn_irradiar.btn_irradiar_iconю.mouseChildren = false;

Все хорошо, но кнопка не работает...

Тогда я сделал выборочно, вот так:

Код AS3:

btn_irradiar.btn_irradiar_icon.btn_irradiar_pl.mouseEnabled = false;

btn_irradiar.btn_irradiar_icon.btn_hidden_1.mouseEnabled = false;

Теперь при наведении на кнопку - плашка начинает мигать.

А как сделать, чтобы плашка не пропадала и кнопка работала я не могу понять, может кто-то сталкивался с таким?

Код AS3:

package {

        import flash.display.*;

        import flash.events.*;

 

        public class Main extends Sprite {

 

                public function Main():void {

                        if (stage) init();

                        else addEventListener(Event.ADDED_TO_STAGE, init);

                }

 

                private function init(e:Event = null):void {

                        removeEventListener(Event.ADDED_TO_STAGE, init);

                        var someMc:SomeMovieClip = new SomeMovieClip();

                        addChild(someMc);                        

                }                

        }        

}

Код AS3:

package {

        import flash.display.*;

        import flash.events.*;

 

        public class SomeMovieClip extends Sprite {

                private var layout:export_layout;

                private var plashka:MovieClip;

 

                public function SomeMovieClip() {

                        layout = new export_layout();

                        plashka = layout.getChildByName('plashka') as MovieClip;

                        plashka.visible = false;

                        addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);

                        addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);

                        addChild(layout);

                }

 

                private function onMouseOver(e:MouseEvent):void {

                        plashka.visible = true;                        

                }

 

                private function onMouseOut(e:MouseEvent):void {

                        plashka.visible = false;

                }                

        }

}

соответственно, export_layout - мувик, в котором два объекта:
1) бэкграунд какой-нить
2) плашка

в плашке, соответственно, два объекта:
1) бэкграунд какой-нибудь
2) кнопка

Вот это спасибо! Именно то, что нужно!