package

{

        import flash.display.Sprite;

        import flash.events.Event;

        import flash.events.MouseEvent;

        import flash.text.TextField;

        import flash.text.TextFormat;

        import flash.utils.getTimer;

 

        public class Main extends Sprite

        {

                private var _tableSprite:Sprite;

                private var _fpsTextField:TextField;

                private var _lastTime:Number;

                private var _currentTime:Number;

 

                public static const SECOND:Number = 1000;

 

                public function Main()

                {

                        _lastTime = getTimer();

                        _currentTime = _lastTime;

                        _tableSprite = new Sprite();

                        _tableSprite.mouseChildren = false;

                        var tf:TextField;

                        for (var i:int = 0; i < 15; i++)

                        {

                                for (var j:int = 0; j < 500; j++)

                                {

                                        tf = new TextField();

                                        tf.text = "text";

                                        tf.x = i * tf.textWidth;

                                        tf.y = j * tf.textHeight;

                                        _tableSprite.addChild(tf);

                                }

                        }

                        _tableSprite.cacheAsBitmap = true;

                        this.addChild(_tableSprite);

                        _fpsTextField = new TextField();

                        _fpsTextField.defaultTextFormat = new TextFormat( null, null, 0xff0000 );

                        _fpsTextField.background = true;

                        _fpsTextField.backgroundColor = 0xffffff;

                        _fpsTextField.width = 100;

                        _fpsTextField.height = 30;

                        this.addChild(_fpsTextField);

                        stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);

                        stage.addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);

                        stage.addEventListener(MouseEvent.CLICK, clickHandler);

                }

                //----------------------------------------------------------------------

                //

                //  Event handlers

                //

                //----------------------------------------------------------------------

                private function enterFrameHandler(event:Event):void

                {

                        _currentTime = getTimer();

                        var fpsCount:Number = SECOND / (_currentTime - _lastTime);

                        var fpsString:String = fpsCount.toString();

                        _fpsTextField.text = _tableSprite.cacheAsBitmap.toString() + " | " + fpsString.substr(0, 5);

                        _lastTime = _currentTime;

                }

                private function mouseWheelHandler(event:MouseEvent):void

                {

                        _tableSprite.y += event.delta;

                }

                private function clickHandler(event:MouseEvent):void

                {

                        _tableSprite.cacheAsBitmap = !_tableSprite.cacheAsBitmap;

                }

        }

}