package mvc.view.shaders 

{

        import starling.textures.Texture;

        import flash.display3D.Context3D;

        import flash.display3D.Program3D;

        import starling.animation.IAnimatable;

        import starling.filters.FragmentFilter;

        import flash.display3D.Context3DProgramType;

 

 

        /**

         * Чёрно-белый шейдер.

         * @author iiNode

         */

        public class NoColor extends FragmentFilter{

 

                // Приват

                private var _program:Program3D;                                                // Шейдер отрисовки

                private var _parameters:Vector.<Number>;                        // Вектор для передачи параметров фильтра

 

 

                /// Создать фильтр чёрно-белого вывода.

                public function NoColor() {

                        super();

 

 

                        _parameters                        = new Vector.<Number>(4, true);

                        _parameters[0]                = 3;

                        _parameters[1]                = 0;

                        _parameters[2]                = 0;

                        _parameters[3]                = 0;

                }

 

 

                // ОПРЕДЕЛЕНИЕ

                override protected function activate(pass:int, context:Context3D, texture:Texture):void {

                        context.setProgramConstantsFromVector(Context3DProgramType.FRAGMENT, 0, _parameters);

                        context.setProgram(_program);

                }

        protected override function createPrograms():void {

 

                        var fragmentProgramCode:String =

 

                                // Среднее арифметическое от суммы цветовых каналов.

                                // Чёрно-белый цвет.

 

                                "tex ft0, v0, fs0 <2d, clamp, linear, mipnone>         \n" +

                                "add ft1.x, ft0.x, ft0.y                                                 \n" +

                                "add ft1.x, ft1.x, ft0.z                                                 \n" +

                                "div ft0.x, ft1.x, fc0.x                                                 \n" + 

                                "mov ft0.yz, ft0.xx                                                         \n" + 

                                "mov oc, ft0                                                                        \n";

 

                        _program                         = assembleAgal(fragmentProgramCode, STD_VERTEX_SHADER);

        }

 

 

                // УДАЛЕНИЕ

                public override function dispose():void{

                        _program.dispose();

                        super.dispose();

                }

        }

}