Форум Flasher.ru - Помогите разобраться с наследованием и переопределением

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

Помогите разобраться с наследованием и переопределением

Доброго!
Пришло время повторного использования классов и переопределение методов, но вот беда, я так и не понял как это правильно делать
вот отрывок класса родителя

Код AS3:

package singleton.sGroundUnits.bankMucus

{

        import classesGame.killUnits.KillGroundUnit;

        import classesGame.options.OptionsUnits;

        import IParentCommon;

        import flash.events.Event;

        import nape.phys.Body;

        import nape.phys.BodyType;

        import nape.shape.Polygon;

 

        public class BankMucus extends IParentCommon

        {

                protected var body:Body;

 

                public function BankMucus()

                {

                        body = new Body(BodyType.KINEMATIC);

                        body.shapes.add(new Polygon(Polygon.box(35, -35)));

                        body.align();

                        body.userData.tempSpeed = 0;

                }

 

                private var sprite:bankMukus_mc = new bankMukus_mc();

 

                override public function init(e:Event):void

                {

                        super.init(e);

 

                        sprite.scaleY = 0.8;

                        this.addChild(sprite);

                        this.addEventListener(Event.ENTER_FRAME, updateSprite);

                        this.addChild(new KillGroundUnit(sprite, body));

                }

 

                protected function updateSprite(e:Event):void

                {

                        sprite.x = body.position.x - sprite.width / 2;

                        sprite.y = body.position.y - sprite.height / 2;

                }

 

                public function get getBody():Body

                {

                        return body;

                }

 

                public function get getSprite():bankMukus_mc

                {

                        return sprite;

                }

 

                public function get getLength():uint

                {

                        return OptionsUnits.lengthBankMucus;

                }

 

                override public function removeInit(e:Event):void

                {

                        super.removeInit(e);

                        this.removeChild(sprite);

                        this.removeEventListener(Event.ENTER_FRAME, updateSprite);

                }

        }

}

мне нужно создать почти такой же класс, только заменить sprite надобно

Код AS3:

package singleton.sGroundUnits.fatso

{

        import classesGame.options.OptionsUnits;

        import flash.events.Event;

        import singleton.sGroundUnits.bankMucus.BankMucus;

 

        public class Fatso extends BankMucus

        {

 

                public function Fatso()

                {

                }

 

                private var sprite:fatso_mc = new fatso_mc();

 

                override public function init(e:Event):void

                {

                        super.init(e);

                }

 

                override public function get getLength():uint

                {

                        return OptionsUnits.lengthFatso;

                }

        }

}

и чёт болты, ни на что не ругается, просто не работает. Чё я делаю не так?

переопределять можно только методы.Решение - описывай свой спрайт как private var sprite:MovieClip и выноси его инициализацию в конструктор/спец. метод(типа init)

Добавлено через 3 минуты
ПС: в конструкторе класса-наследника принято вызывать конструктор супер-класса.(относится к обоим классам)

Можно сделать sprite protected и инициализировать его, например, в конструкторе Fatso().
Больше ничего не нужно.
Хотя, тогда не понятно, зачем делать отдельный класс ради изменения одной переменной

я так сделал, заработало, лучше как можно?

Код AS3:

        public class BankMucus extends IParentCommon

        {

                protected var body:Body;

                private var sprite:MovieClip;

 

                public function BankMucus()

                {

                        body = new Body(BodyType.KINEMATIC);

                        body.shapes.add(new Polygon(Polygon.box(35, -35)));

                        body.align();

                        body.userData.tempSpeed = 0;

                        sprite = newSprite()

                }

 

                protected function newSprite():MovieClip 

                {

                        return  new bankMukus_mc();

                }

 

                override public function init(e:Event):void

                {

                        super.init(e);

 

                        sprite.scaleY = 0.8;

                        this.addChild(sprite);

                        this.addEventListener(Event.ENTER_FRAME, updateSprite);

                        this.addChild(new KillGroundUnit(sprite, body));

                }

Код AS3:

package singleton.sGroundUnits.fatso

{

        import classesGame.options.OptionsUnits;

        import flash.display.MovieClip;

        import flash.events.Event;

        import singleton.sGroundUnits.bankMucus.BankMucus;

 

        public class Fatso extends BankMucus

        {

 

                public function Fatso()

                {

                        super();

                }

 

                override protected function newSprite():MovieClip 

                {

                         return new fatso_mc;

                }

 

                override public function init(e:Event):void

                {

                        super.init(e);

                }

 

                override public function get getLength():uint

                {

                        return OptionsUnits.lengthFatso;

                }

        }

}

neonoviiwolf, можно, но смысл происходящего не понятен.

Цитата:

Сообщение от illuzor (Сообщение 1194508)

neonoviiwolf, можно, но смысл происходящего не понятен.

а чё не понятного, создаётся физ объект, к нему цепляется мувик, ну и методы get/set

непонятно зачем тут наследование.Если объекты будут отличаться только этим спрайтом, лучше сделать один класс с возможностью устанавливать ему это свойство.

Цитата:

Сообщение от undefined (Сообщение 1194510)

Именно. Наследование для этой задачи не нужно.

Цитата:

Сообщение от illuzor (Сообщение 1194511)

Именно. Наследование для этой задачи не нужно.

ну у меня много юнитов будет, остальные будут отличаться сильнее

Еще раз:
Переопределение касается методов, функций, действий. НЕ свойств.
Если ваши юниты будут ПО-РАЗНОМУ выполнять команду стреляй(), то смысл есть.
Если разница будет только в том, что один делает стреляй(простоПуля) а другой стреляй(серебрянаяПуля), то разница опять только в свойствах и переопределение не нужно.
Если выполняются одни и те же действия, но с разными объектами или параметрами, то они так и остаются одними и теми же действиями.
Поэтому, чтобы разбираться с темой топика, нужен правильный пример, где действительно используется переопределение метода. Иначе будет только путаница.