Форум Flasher.ru - Растрирование изображения

Я делал это вот так в ActionScript 3.0

class Pixilate.as

Код:

package effects

{

        import flash.events.EventDispatcher;

        import flash.events.TimerEvent;

        import flash.utils.Timer;

        import flash.display.BitmapData;

        import flash.filters.BlurFilter;

        import flash.filters.BitmapFilterQuality;

        import flash.geom.Point;

        import flash.display.Bitmap;

        import flash.geom.Rectangle;



        public class Pixilate extends EventDispatcher

        {                

                /**

                 * @private

                 */

                protected var _originalImage:BitmapData;

                /**

                 * @private

                 */

                protected var _bluredImage:BitmapData;

                /**

                 * @private

                 */

                protected var _currentStep:uint;

                /**

                 * @private

                 */

                protected var _totalSteps:uint;

                

                public function Pixilate(originalImage:BitmapData)

                {

                        _originalImage = originalImage;

                }

                

                public function get originalImage():BitmapData

                {

                        return _originalImage;

                }

                

                public function createPixelatedImage(pixelSize:uint):BitmapData

                {

                        var result:BitmapData = new BitmapData(_originalImage.width, _originalImage.height);

                        

                        var vPixelsAmmount:uint = Math.ceil(result.height/pixelSize);

                        var hPixelsAmmount:uint = Math.ceil(result.width/pixelSize);

                        var halfPixel:Number        = Math.ceil(pixelSize/2);

                        

                        for (var h:uint = 0; h < vPixelsAmmount ; h++)

                        {

                                for (var w:uint = 0; w < hPixelsAmmount ; w++)

                                {

                                        trace("drawing");

                                        var currentX:Number = w*pixelSize;

                                        var currentY:Number = h*pixelSize;

                                        

                                        var color:uint = _originalImage.getPixel32(currentX+halfPixel, currentY+halfPixel);

                                        var rect:Rectangle = new Rectangle(currentX, currentY, pixelSize, pixelSize);

                                        

                                        trace(color);

                                        

                                        result.fillRect(rect, color);

                                }

                        }

                        

                        return result;

                }

                

                /**

                 * @private

                 */

                protected function blurImage(blurCoof:uint):void

                {

                        var blur:BlurFilter = new BlurFilter(blurCoof, blurCoof, BitmapFilterQuality.LOW);

                        _bluredImage = new BitmapData(_originalImage.width, _originalImage.height);

                        _bluredImage.draw(_originalImage);

                        _bluredImage.applyFilter(_bluredImage, _originalImage.rect, new Point(0, 0), blur);

                }

        }

}

class PixilateExample.as

Код:

package {

        import flash.display.Sprite;

        import flash.display.Loader;

        import flash.net.URLRequest;

        import flash.events.Event;

        import flash.display.BitmapData;

        import flash.display.DisplayObject;

        import flash.display.Bitmap;

        import flash.display.LoaderInfo;

        import flash.display.StageAlign;

        import flash.display.StageScaleMode;

        import effects.Pixilate;

        import flash.utils.Timer;

        import flash.events.TimerEvent;

        import flash.events.MouseEvent;



        public class PixilateExample extends Sprite

        {

                private var pixilate:Pixilate;

                private var bitmap:Bitmap;

                

                public function PixilateExample()

                {

                        initStage();

                        

                        var loader:Loader = new Loader();

                                loader.load(new URLRequest("3.jpg"));

                                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded);

                                

                        stage.addEventListener(MouseEvent.CLICK, startPixilate);

                }

                

                private function onImageLoaded(event:Event):void

                {                        

                        var image:DisplayObject = (event.target as LoaderInfo).loader.content;

                        

                        var bmpd:BitmapData = new BitmapData(image.width, image.height);

                                bmpd.draw(image);

                        

                        pixilate = new Pixilate(bmpd);

                        bitmap = addChild(new Bitmap()) as Bitmap;

                        bitmap.bitmapData = bmpd;

                }

                

                private function startPixilate(event:MouseEvent):void

                {

                        if(pixilate != null)

                        {

                                var timer:Timer = new Timer(20, 10);

                                        timer.addEventListener(TimerEvent.TIMER, onTimerTick);

                                        timer.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);

                                        timer.start();

                        }

                }

                

                

                private function onTimerTick(event:TimerEvent):void

                {

                        trace("tick");

                        bitmap.bitmapData = pixilate.createPixelatedImage((event.target as Timer).currentCount*3);

                }

                

                private function onTimerComplete(event:TimerEvent):void

                {

                        

                }

                

                private function initStage():void

                {

                        stage.align         = StageAlign.TOP_LEFT;

                        stage.scaleMode = StageScaleMode.NO_SCALE;

                }

        }

}

Вложение 16337