[goodguy]

Да, собственно, он и нафиг не нужен. Можно легко обойтись без вышеуказанного контейнера.
Вот, по-быстренькому набросал пример класса, который крутит циферблат без вращения цифр.

package  {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	/**
	 * ...
	 * @author Серов Константин
	 */
	public class DigitsRotation extends Sprite {
 
		private var _angleStep:	int 			= 360 / 12;
		private var _faceRadius:	Number			= 100;
		private var _allDigits:	Vector.<TextField>	= new Vector.<TextField>();
		private var _initialAngle:	int			= 0;
		private var _increment:	Number 			= 1;
		private var _cX:		Number;
		private var _cY:		Number;
		private var _degRad:	Number		           = Math.PI / 180;
 
		public function DigitsRotation() {
			_cX			= stage.stageWidth  / 2;
			_cY			= stage.stageHeight / 2;
			positionDigits();
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
 
		private function onEnterFrame(e:Event):void {
			_initialAngle += _increment;
			for (var i:int = 0; i < _allDigits.length; i++) {
				_allDigits[i].x		= _cX + Math.cos((_initialAngle + (i * _angleStep)) * _degRad) * _faceRadius;
				_allDigits[i].y		= _cY + Math.sin((_initialAngle + (i * _angleStep)) * _degRad) * _faceRadius;
			}
		}
 
		private function positionDigits():void {
			for (var i:int = 1; i < 13; i++) {
				var tf:TextField = new TextField();
				tf.text				= String(i);
				tf.x				= _cX + Math.cos((_initialAngle + (i * _angleStep)) * _degRad) * _faceRadius;
				tf.y				= _cY + Math.sin((_initialAngle + (i * _angleStep)) * _degRad) * _faceRadius;
				_allDigits.push(tf);
				addChild(tf);
			}
		}
	}
}

Надеюсь идея ясна