[Dmitriy154]

А ведь я также использую код caseyryan, я думаю он не будет против, только одну переменную добавил

package {
 
	import flash.display.Stage;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
 
	public class Key {
 
		private static var initialized:Boolean = false;		
		private static var keysDown:Object = new Object();
		static var keysDownNow:Boolean; //моя переменная
 
		public static function initialize(stage:Stage):void {
			if (!initialized) {
				stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
				stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
				stage.addEventListener(Event.DEACTIVATE, clearKeys);
				initialized = true;
			}
		}
 
		public static function isDown(keyCode:uint):Boolean {
			if (!initialized) {
				throw new Error("Key class has not yet been initialized.");
			}
			return Boolean(keyCode in keysDown);
		}
 
		private static function keyPressed(event:KeyboardEvent):void {
			keysDown[event.keyCode] = true;
			keysDownNow = true;
		}
 
		private static function keyReleased(event:KeyboardEvent):void {
			if (event.keyCode in keysDown) {
				delete keysDown[event.keyCode];
			}
			keysDownNow = false;
		}
 
		private static function clearKeys(event:Event):void {
			keysDown = new Object();
		}
	}
}

А шаблоны проектирования, наверное, пока не для моего ума, слишком громоздко