[undefined]

Вот с массивами у меня засада. Никак не могу в них разобраться. Я и этот-то код с грехом пополам сваял, без шпаргалок не смог обойтись. Может покажете, как он должен выглядеть, чтобы работал?

import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.*;
import flash.display.Loader;
 
var xmlLoader:URLLoader = new URLLoader(new URLRequest("xml/my.xml"));
var xmlData:XML;
var xmlList:XMLList;
var picLoader:Loader;
var curImage:int=0;
var images:Array=[];
xmlLoader.addEventListener(Event.COMPLETE, getXML);
next_btn.addEventListener(MouseEvent.CLICK,onClick);
prev_btn.addEventListener(MouseEvent.CLICK,onClick);
function getXML(e:Event):void
{
	trace("загрузился");
	xmlData = XML(e.target.data);
	var list:XMLList=xmlData.pages;
	for (var i:uint=0;i<list.children().length();i++) {
		var picLoader:Loader = new Loader();
		picLoader.load(new URLRequest(list.children()[i]));
		picLoader.x = 0;
		picLoader.y = 0;
		addChild(picLoader);
		picLoader.visible=(i==curImage);
		images.push(picLoader);
	}
}
function onClick(e:MouseEvent):void
{
	if (e.target==next_btn) {
		images[curImage].visible=false;
		curImage++;
		if(curImage>images.length-1) curImage=0;
		images[curImage].visible=true;
	} else if (e.target==prev_btn) {
		images[curImage].visible=false;
		curImage--;
		if(curImage<0) curImage=images.length-1;
		images[curImage].visible=true;
	}
}

next_btn,prev_btn - кнопки листания.Должны лежать на сцене и иметь именно такие имена.