[Хемуль]

2 Rot pfeffer:
Предлагаю более совершенный и облагороженный пример. Можно ставить сколько угодно кнопок и мувиклипов. В моём примере их 4. Обратите внимание на то, как упростилось всё на сцене. Причём я даю вам гибкий в настройке код. Полагайтесь больше на скрипты...
Код:

var moviesNumber:Number = 4;
var left:Number = 20;
var top:Number = 20;
var moviesInterval:Number = 30;
var buttonsYOffset:Number = 120;
var movieBaseName:String = "movie";
var buttonBaseName:String = "button";

var moviesXOffset:Number = 0;
for (var index:Number = 0; index < moviesNumber; index++)
{
	var newMovieName:String = movieBaseName + index;
	var newButtonName:String = buttonBaseName + index;
	var newMovie:MovieClip = this.attachMovie("myMovie", newMovieName, this.getNextHighestDepth());
	var newButton:MovieClip = this.attachMovie("myButton", newButtonName, this.getNextHighestDepth());	
	newMovie.white.gotoAndStop(1);
	newMovie._x = left + moviesXOffset;
	newMovie._y = top;
	newButton._x = newMovie._x;
	newButton._y = top + buttonsYOffset;
	newButton.id = index;
	newButton.onRollOver = function()
	{
		var movieClipName:String = movieBaseName + this.id;
		var whiteThing:MovieClip = this._parent[movieClipName].white;
		delete whiteThing.onEnterFrame;
		whiteThing.gotoAndPlay(1);
	};
	newButton.onRollOut = function()
	{
		var movieClipName:String = movieBaseName + this.id;
		var whiteThing:MovieClip = this._parent[movieClipName].white;		
		whiteThing.onEnterFrame = function()
		{
			if (this._currentframe > 1)
			{
				this.prevFrame();
			}
			else
			{
				delete this.onEnterFrame;
			}
		};
	};	
	moviesXOffset += (newMovie._width + moviesInterval);
}

Обратите внимание на то, как теперь устроены ваши мувиклипы. И не стоит использовать кнопки...
Исходник прикрепляю...