[Dendroid]

Есть очень хороший класс от Mario Klingemann. Я его использовала вот в таком упрощённом, адаптированном виде:

// ColorMatrix Class v1.2
//
// Author: Mario Klingemann
// http://www.quasimondo.com

package {

import flash.filters.ColorMatrixFilter;

public class ColorMatrix
{
	
	// RGB to Luminance conversion constants as found on
	// Charles A. Poynton's colorspace-faq:
	// http://www.faqs.org/faqs/graphics/colorspace-faq/
	
	private static var r_lum:Number = 0.212671;
	private static var g_lum:Number = 0.715160;
	private static var b_lum:Number = 0.072169;
	
	/*
	
	// There seem  different standards for converting RGB
	// values to Luminance. This is the one by Paul Haeberli:
	
	private static var r_lum:Number = 0.3086;
	private static var g_lum:Number = 0.6094;
	private static var b_lum:Number = 0.0820;
	
	*/
	
	private static var IDENTITY:Array =      [1,0,0,0,0,
											  0,1,0,0,0,
											  0,0,1,0,0,
											  0,0,0,1,0];
	
	public var matrix:Array;
	
	
	/*
   Function: ColorMatrix
   
	  Constructor

   Parameters:

      mat - if omitted matrix gets initialized with an
			identity matrix. Alternatively it can be 
			initialized with another ColorMatrix or 
			an array (there is currently no check 
			if the array is valid. A correct array 
			contains 20 elements.)
			
			
	*/

	
	public function ColorMatrix ( mat:Object=null )
	{
		if (mat instanceof ColorMatrix )
		{
			matrix = mat.matrix.concat();
		} else if (mat instanceof Array )
		{
			matrix = mat.concat();
		} else 
		{
			reset();
		}
		
	}
	
	/*
   Function: reset

	  resets the matrix to the neutral identity matrix. Applying this
	  matrix to an image will not make any changes to it.

   Parameters:

      none
	  
	Returns:
	
		nothing
			
			
	*/
	
	public function reset()
	{
		matrix = IDENTITY.concat();
	}
	
	
	public function clone():ColorMatrix
	{
		return new ColorMatrix( matrix );
	}
	
	
	
	public function adjustSaturation ( s:Number )
	{
		var s1:Number=1-s;
		
	    var irlum:Number = s1 * r_lum;
		var iglum:Number = s1 * g_lum;
		var iblum:Number = s1 * b_lum;
		
		var mat:Array =        [irlum + s, iglum    , iblum    , 0, 0,
					  			irlum    , iglum + s, iblum    , 0, 0,
					    		irlum    , iglum    , iblum + s, 0, 0,
					    		0        , 0        , 0        , 1, 0 ];
	
		
		concat(mat);
	}
	
	public function adjustContrast ( r:Number, g:Number, b:Number )
	{
		g = g || r;
		b = b || r;
		
		r+=1;
		g+=1;
		b+=1;
		
		var mat:Array =       [r,0,0,0,128*(1-r),
					 		   0,g,0,0,128*(1-g),
					 		   0,0,b,0,128*(1-b),
							   0,0,0,1,0];
	
		
		concat(mat);
	}
	
	public function adjustBrightness (r:Number, g:Number, b:Number)
	{
		g = g || r;
		b = b || r;
		
		var mat:Array =       [1,0,0,0,r,
					 		   0,1,0,0,g ,
					 		   0,0,1,0,b ,
							   0,0,0,1,0 ];
 	
		
		concat(mat);
		
	}
	
	public function adjustHue( angle:Number )
	{
			angle *= Math.PI/180;
			
			var c:Number = Math.cos( angle );
            var s:Number = Math.sin( angle );
			
            var f1:Number = 0.213;
            var f2:Number = 0.715;
            var f3:Number = 0.072;
			
            var mat:Array = [(f1 + (c * (1 - f1))) + (s * (-f1)), (f2 + (c * (-f2))) + (s * (-f2)), (f3 + (c * (-f3))) + (s * (1 - f3)), 0, 0, (f1 + (c * (-f1))) + (s * 0.143), (f2 + (c * (1 - f2))) + (s * 0.14), (f3 + (c * (-f3))) + (s * -0.283), 0, 0, (f1 + (c * (-f1))) + (s * (-(1 - f1))), (f2 + (c * (-f2))) + (s * f2), (f3 + (c * (1 - f3))) + (s * f3), 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1];
			
			concat(mat);
	}
	
	public function colorize ( rgb:Number, amount:Number)
	{
		
		var r:Number = ( ( rgb >> 16 ) & 0xff ) / 255;
		var g:Number = ( ( rgb >> 8  ) & 0xff ) / 255;
		var b:Number = (   rgb         & 0xff ) / 255;
		
		amount = amount||1;
		var inv_amount:Number = 1 - amount;
		
		
		var mat:Array =        [ inv_amount + amount*r*r_lum, amount*r*g_lum,  amount*r*b_lum, 0, 0,
					  			 amount*g*r_lum, inv_amount + amount*g*g_lum, amount*g*b_lum, 0, 0,
					   			 amount*b*r_lum,amount*b*g_lum, inv_amount + amount*b*b_lum, 0, 0,
					    		 0 , 0 , 0 , 1, 0 ];
		
		
		concat(mat);
	}
	
	
	public function concat(mat:Array)
	{
		
		var temp:Array = [];
		var i:Number = 0;
		
		for (var y:Number = 0; y < 4; y++ )
		{
			
			for (var x:Number = 0; x < 5; x++ )
			{
				temp[i + x] = mat[i    ] * matrix[x     ] + 
							   mat[i+1] * matrix[x +  5] + 
							   mat[i+2] * matrix[x + 10] + 
							   mat[i+3] * matrix[x + 15] +
							   (x == 4 ? mat[i+4] : 0);
			}
			i+=5;
		}
		
		matrix = temp;
		
	}
	
	public function get filter():ColorMatrixFilter
	{
		return new ColorMatrixFilter( matrix );
	}

	
}
}

пользоваться очень просто:

		var colorMatrix:ColorMatrix = new ColorMatrix();
		if (hue) {
			colorMatrix.adjustHue(hue*180);
		}
		if (saturation) {
			colorMatrix.adjustSaturation(saturation+1);
		}
		if (brightness) {
			colorMatrix.adjustBrightness(255*brightness, 255*brightness, 255*brightness);
		}
		if (contrast) {
			colorMatrix.adjustContrast(contrast, contrast, contrast);
		}
		movie.filters = [colorMatrix.filter];

Нулевые значения - оригинальные цвета.
"saturation=-1" - черно-белый вариант.
"saturation=-2" - инверсия цвета.