Можно компилировать флешки, например в notepad++. Для этого создаем make.bat в папке bin flex 3 sdk:
Код:
@ECHO off
if "%~x1" == ".as" goto PARSEAS
if "%~x1" == ".mxml" goto PARSEAS
GOTO NOTFOUND
:PARSEAS
REM ------Description------------------------------------------------------
REM Drag your .as file onto this .bat to create a new .bat that will
REM compile and, if compilation successful, open the resulting swf.
REM -----------------------------------------------------------------------
REM ------User-Variables---------------------------------------------------
REM mxmlcPath: Path to mxmlc command line compiler. You may need
REM to change this based on your installation
SET mxmlcPath="%~dp0mxmlc.exe"
chdir %~dp0
REM Path to Flash Player
SET mpath=..\runtimes\player\10\win\FlashPlayer.exe
REM opts: Command line options for mxmlc if any. You can get a list
REM of the available options from:
REM http://livedocs.macromedia.com/labs/1/flex/00001191.html
REM or by running:
REM mxmlc.exe -help list advanced details
REM in the command prompt (properly referencing mxmlc.exe)
SET opts=-benchmark=true -creator="NotepadPP"
REM -----------------------------------------------------------------------
REM Generate .bat code and save to file
ECHO @ECHO OFF ^& (IF EXIST "%%~dp0%~n1.swf" (DEL "%%~dp0%~n1.swf")) ^& %mxmlcPath% %opts% -file-specs "%%~dp0%~nx1" ^& (IF EXIST "%%~dp0%~n1.swf" (%mpath% "%%~dp0%~n1.swf") ELSE (PAUSE)) > "%~dpn1.bat"
REM Immediately execute the generated bat
@ECHO off
CALL "%~dpn1.bat"
DEL "%~dpn1.bat"
goto END
:NOTFOUND
ECHO "FLEX Compiler Error - Incorrect extension!"
:END
А в блокнотике запускаем через F6 и пишем туда что-то типа
Код:
F:\flex\bin\make.bat "$(FULL_CURRENT_PATH)"
В дальнейшем запускаем ctrl+f6. Все трейсы попадают в консольку. А если в браузере, то допиши код wvxvw в бат файл.