Замыкание

[rs7]

Напишите рабочий пример замыкания в as3. Что-то не получается у меня воспроизвести эту штуку

[Wolsh]

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
			var arr:Array = [1, 2, 3];
			var x:int = 10;
			var arr2:Array = calc(arr, function(elem:int):int { return x * elem } );
			trace(arr2); // 10, 20, 30
		}
 
		private function calc(arr:Array, method:Function):Array
		{
			var array:Array = [];
			for (var index:int = 0; index < arr.length; index++ )
			{
				array.push(method(arr[index]));
			}
			return array;
		}
	}
}

Добавлено через 2 минуты
хотя.. инты всеравно передаются не по ссылке, надо помудрёней пример придумать.

[КорДум]

Дык

btn.addEventListener(MouseEvent.CLICK, function(event:MouseEvent) { trace(event.target); } );

[Wolsh]

Во.

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Main extends Sprite 
	{
		private var _arrLength:int = 3;
 
		public function Main():void 
		{
			var arr:Array = [1, 2, 3];
			calc(function(modifier:int, index:int):void { arr[index] *= modifier } );
			trace(arr); // 10, 20, 30
		}
 
		private function calc(method:Function):void
		{
			var mod:int = 10;
			for (var i:int = 0; i < _arrLength; i++ )
			{
				method(mod, i);
			}
		}
	}
}

Добавлено через 3 минуты
КорДум, анонимная функция еще не closure. Фишка в сохранении контекста, то есть в моем примере анонимка, исполняясь в calc, "помнит" ссылку на arr. Это и есть замыкание.

[Silicium]

а, кстати, что плохого в замыкании кроме того, что она анонимка?

[strangedk]

Недавно экспериментировал с замыканиями и scope'ами, и в итоге накрутил вот такое:

function summ(a:Number):Function {
	return function(b:Number):Function {
		return function(c:Number):Function {
			return function(d:Number):String {
				return (a+b+c+d).toFixed();
			}
		}
	}
}
 
var total:String = summ(1)(2)(3)(4);
 
trace(total);

[Silicium]

жуть какая)