Узнать путь к изображению

[art_maestro]

Здравствуйте,

Подскажите можно ли как то решить мою задачу. Есть мувик, в который добавлен объект Loader ( загружал изображение и добавил его в мувик).
Задача такая, необходимо при клике на мувик узнать путь к изображению. Возможно ли это реализовать используя taeget или currentTarget.

Куда копать дальше

private  function clickBuilding(e:MouseEvent):void
	{	
		var _mcClip:MovieClip = new MovieClip();
		     _mcClip = e.currentTarget as MovieClip;
        }

[AlexCooper]

Зачем Вам путь? Мне кажется Вы недавно перешли из AS2 на AS3, в первом из которых путь играл очень важную роль.

[art_maestro]

Да, Вы верно поняли. Получается узнать путь не как мне не удастся таким способом, который я описал выше?

[KumoKairo]

Самый простой и "грязный" способ - динамически добавить свойство в ваш мувик при загрузке, в этом свойстве храните путь:

movie["path"] = "http//example.com/littlepony.png"

А потом как вы написали, только

private  function clickBuilding(e:MouseEvent):void
{	
    var _mcClip:MovieClip = new MovieClip();
    _mcClip = e.currentTarget as MovieClip;
    trace(_mcClip["path"]);
}

Есть мувик, в который добавлен объект Loader ( загружал изображение и добавил его в мувик).

Что значит в который добавлен объект Loader?
Если вы наследовали класс MovieClip и добавляли новое поле, то точно таким же способом можно добавить свойство path, и это уже будет не грязный способ, а вполне вменяемый)

[AlexCooper]

KumoKairo тут речь немного о другом.

Сообщение от art_maestro

Да, Вы верно поняли. Получается узнать путь не как мне не удастся таким способом, который я описал выше?

Скажите что конкретно вы хотите сделать. Думаю в действительности Вам этот путь абсолютно не нужен.

Добавлено через 30 минут
Мне кажется у Вас написанно что-то подобное ( если конечно Вы пишите не в кадрах)

package  {
 
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.MouseEvent;
 
	public class TestLoad extends Sprite {
 
		public function TestLoad() {
 
			var clip:Sprite = new Sprite();
 
			addChild(clip);
 
			 var loader:Loader = new Loader();
			 var url:URLRequest = new URLRequest("http://www.flasher.ru/forum/image.php?u=58397&dateline=1222217437");
 
			clip.addChild(loader);
 
			loader.load(url);
 
			loader.addEventListener(MouseEvent.MOUSE_DOWN, mouseHandler) ;
		}
 
		private function mouseHandler(e:MouseEvent):void {
			trace('mouse down');
		}
	}
}

Но я бы посоветовал написать вот так

package  {
 
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.MouseEvent;
	import flash.events.Event;	
 
	public class TestLoad extends Sprite {
 
		private var clip:Sprite;
 
		public function TestLoad() {
 
			clip = new Sprite();
 
			addChild(clip);
 
			 var loader:Loader = new Loader();
			 var url:URLRequest = new URLRequest("http://www.flasher.ru/forum/image.php?u=58397&dateline=1222217437");
 
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeLoad);
 
			loader.load(url);
 
		}
 
		private function completeLoad(e:Event):void {
 
			e.currentTarget.removeEventListener(Event.COMPLETE, completeLoad);
 
			var image:Sprite = new Sprite();
				image.addEventListener(MouseEvent.MOUSE_DOWN, mouseHandler) ;
				image.addChild(e.currentTarget.content);
 
			clip.addChild(image);
 
			trace('load complete');
		}
 
		private function mouseHandler(e:MouseEvent):void {
			trace('mouse down');
			trace('Clip Conteiner' + clip);
			trace('Image ' + e.currentTarget);
		}
	}
 
}

В таком случае у вас при выполнении mouseHandler имеет Ваши искомые пути,
1 - clip - контейнер, для удаления, добавления элементов
2 - e.currentTarget - спрайт с изображением по которому осуществился клик.

[art_maestro]

Спасибо, разобрался!