Вопрос по dispatchEvent

[eXplozive]

Всем доброго дня, вот возник вопрос по dispatchEvent.

Задача такая чтобы из одного класса вызывать функцию в другом.
Попытаюсь поястнить.

Вот создал класс кнопки для своих проектов:

import mx.utils.Delegate;
import mx.utils.Proxy;
import mx.transitions.Tween;


class pf.EasyButton extends MovieClip {
	public var dispatchEvent:Function;
	private var bMovie:MovieClip;

	public function EasyButton(bMovie, evName) {

		bMovie.onRollOver = Proxy.create(this, this.buttonOver, [bMovie]);
		bMovie.onRollOut = Proxy.create(this, this.buttonOut, [bMovie]);
		bMovie.onRelease = Proxy.create(this, this.buttonRelease, [evName]);

	}
	private function buttonOver(param) {
		delete param[0].onEnterFrame;
		param[0].gotoAndPlay(2);
	}

	private function buttonOut(param) {
		param[0].onEnterFrame = function() {
			this.gotoAndStop(this._currentframe-1);
		};
		if (this._currentframe == 1) {
			delete param[0].onEnterFrame;
		}
	}


	private function buttonRelease(param) {

		dispatchEvent({type:param[0], target:this});

	}
}

В родительском классе код например такой:

closeHelpToolButton = new EasyButton(_root.mcCloseImage, "closeHelpTool");

closeHelpToolButton.addEventListener("closeHelpTool",Proxy.create(this, this.closeBigImage, []));

Задача такова чтобы при нажатии на кнопку срабатывала функция, в данном случае - closeHelpTool. Но она не отрабатывает, подскажите в чем проблема.

Заранее огромное спасибо.

[CrazyFlasher]

вот наваял простой пример и, по-моему, очень понятный

создаём 2 класса:
MotherClass.as

import mx.utils.Delegate;

class MotherClass {
	
	public function MotherClass(){
		var child:ChildClass = new ChildClass();
		
		child.addEventListener("update", Delegate.create(this, callsFromChild));
		child.callMother();
	}
	
	private function callsFromChild(callObj:Object){
		switch(callObj.event){
			case "motherFeedMe":
				trace("ok child, I feed you!");
				break;
				
			default:
				trace("I DON'T UNDERSTAND YOU DEAR CHILD!");
				break;
		}
	}
}

ChildClass.as

import mx.events.EventDispatcher;

class ChildClass {
	public function ChildClass(){
		EventDispatcher.initialize(this);
	}
	
	public function callMother(){
		dispatchEvent({type:"update", event:"motherFeedMe"});
	}
	
	//dispatcher methods
	public function dispatchEvent():Void {};
	public function addEventListener():Void {};
	public function removeEventListener():Void {};
}

во fla файле пишем:

var mom:MotherClass = new MotherClass();

[etc]

Необходимо сначала проинициализировать экземпляр класса с помощью EventDispatcher.

[eXplozive]

Да, огромное спасибо! Вы даже не представляете как вы мне помогли! Кстати думаю достойный пост для FAQ

Еще раз спасибо.