Изменение скина scrollbar'a в TextArea

[MonkDead]

Как добраться до scrollbar'a в TextArea что бы программно изменить skin scrollbar'a?

[terbooter]

Почитайте про setStyle в хелпе.
Я делал так: В подгружаемую флешку кидаю все скиновые мувики
(они там сами появляются если компонент вытащить на сцену или в либу)
Переобзываю их как надо и ставлю галочку экспортировать в первом кадре.
Весь код только в подгружающей флешке.

private function createJoinButton():Button {
			
			if (this.applicationDomain == null) {
				throw Error("Acordion: set Application Domain of skin assets");
			}
			
			var bb:Button = new Button();
			
			bb.setStyle("upSkin"			, g("Simple_ChatButton_upSkin"));
			bb.setStyle("overSkin"			, g("Simple_ChatButton_overSkin"));
			bb.setStyle("downSkin"			, g("Simple_ChatButton_downSkin")); 
			bb.setStyle("disabledSkin"		, g("Simple_ChatButton_disabledSkin")); 
			bb.setStyle("selectedDisabledSkin", g("Simple_ChatButton_selectedDisabledSkin"));
			bb.setStyle("selectedUpSkin"	, g("Simple_ChatButton_selectedUpSkin"));
			bb.setStyle("selectedDownSkin"	, g("Simple_ChatButton_selectedDownSkin")); 
			bb.setStyle("selectedOverSkin"	, g("Simple_ChatButton_selectedOverSkin")); 
			
			var tf:TextFormat = new TextFormat();
			tf.font = "Verdana";
			tf.bold = true;
			tf.color = 0x000099;
			
			bb.label = "Join Room";
			bb.setStyle("textFormat"	, tf);
			//bb.textField.border = true;
			//bb.addEventListener(MouseEvent.CLICK, buttonHandler);
			bb.height = 18;
			
			return bb;
		}
		
		private function g(className:String):Class {
			return (applicationDomain.getDefinition(className) as Class)
		}

Со скролерами примерно так же только писанины больше.
Стили стандартных компонентов можно получить статическим методом
getStyleDefinition() или открыть класс и посмотреть -))

[MonkDead]

))) Я именно так и делаю скинование, все в отдельной библиотеке загружается в основной проект и идет выборка. Только насколько я понимаю компонент scrollbar вложен в компонент TextArea, в этом и вопрос как ему задать стиль?

[terbooter]

Конкретно TextArea я не скиновал динамически, но не вижу никаких проблем. Вот скролпэйн:

private function createScrollPane():ScrollPane {
            
            if (this.applicationDomain == null) {
                throw Error("Acordion: set Application Domain of skin assets");
            }
            
            var sp:ScrollPane = new ScrollPane();
            sp.setStyle("downArrowDisabledSkin"    , g("Avics_ScrollArrowDown_disabledSkin"));
            sp.setStyle("disabledSkin"            , g("Avics_ScrollPane_disabledSkin"));
            sp.setStyle("upSkin"                , g("Avics_ScrollPane_upSkin"));
            sp.setStyle("downArrowDownSkin"        , g("Avics_ScrollArrowDown_downSkin"));
            sp.setStyle("downArrowOverSkin"        , g("Avics_ScrollArrowDown_overSkin"));
            sp.setStyle("downArrowUpSkin"        , g("Avics_ScrollArrowDown_overSkin"));
            sp.setStyle("thumbDisabledSkin"        , g("Avics_ScrollThumb_upSkin"));
            sp.setStyle("thumbDownSkin"            , g("Avics_ScrollThumb_downSkin"));
            sp.setStyle("thumbOverSkin"            , g("Avics_ScrollThumb_overSkin"));
            sp.setStyle("thumbUpSkin"            , g("Avics_ScrollThumb_upSkin"));
            sp.setStyle("trackDisabledSkin"        , g("Avics_ScrollTrack_skin"));
            sp.setStyle("trackOverSkin"            , g("Avics_ScrollTrack_skin"));
            sp.setStyle("trackUpSkin"            , g("Avics_ScrollTrack_skin"));
            sp.setStyle("trackDownSkin"            , g("Avics_ScrollTrack_skin"));
            sp.setStyle("upArrowDisabledSkin"    , g("Avics_ScrollArrowUp_disabledSkin"));
            sp.setStyle("upArrowDownSkin"        , g("Avics_ScrollArrowUp_downSkin"));
            sp.setStyle("upArrowOverSkin"        , g("Avics_ScrollArrowUp_overSkin"));
            sp.setStyle("upArrowUpSkin"            , g("Avics_ScrollArrowUp_upSkin"));
            sp.setStyle("skin"                    , g("Avics_ScrollPane_upSkin"));
            sp.setStyle("thumbIcon"                , g("Avics_ScrollBar_thumbIcon"));
            //sp.setStyle("", g(""));
            //sp.setStyle("", g(""));
            return sp;

        }

ShowObject(TextArea.getStyleDefinition());//ShowObject рекурсивно трейсит дерево объекта

говорит что у TextArea есть стили задающие скин скроллера (Все имена классов которые начинаются со слов Scroll):

-thumbDisabledSkin=ScrollThumb_upSkin
-thumbDownSkin=ScrollThumb_downSkin
-thumbOverSkin=ScrollThumb_overSkin
-thumbUpSkin=ScrollThumb_upSkin
-thumbIcon=ScrollBar_thumbIcon
-textFormat=null
-trackDisabledSkin=ScrollTrack_skin
-trackDownSkin=ScrollTrack_skin
-trackOverSkin=ScrollTrack_skin
-trackUpSkin=ScrollTrack_skin
-upSkin=TextArea_upSkin
-repeatDelay=500
-repeatInterval=35
-disabledSkin=TextArea_disabledSkin
-textPadding=3
-downArrowDisabledSkin=ScrollArrowDown_disabledSkin
-embedFonts=false
-focusRectSkin=null
-downArrowOverSkin=ScrollArrowDown_overSkin
-focusRectPadding=null
-downArrowUpSkin=ScrollArrowDown_upSkin
-downArrowDownSkin=ScrollArrowDown_downSkin
-upArrowDisabledSkin=ScrollArrowUp_disabledSkin
-upArrowDownSkin=ScrollArrowUp_downSkin
-disabledTextFormat=null
-upArrowOverSkin=ScrollArrowUp_overSkin
-upArrowUpSkin=ScrollArrowUp_upSkin

[MonkDead]

Хех только что сам тем же самым занимался )))


Усе тему закрываем действительно можно напрямую задавать скины, под утро мозг плохо варит )))

terbooter - спасибо за потраченное время.