сглаживание картинок загружаемых MovieClipLoader'ом

[Cha]

Доброго времени!
Подскажите пожалуйста, как сделать сглаживание картинок, загружаемых с помощью MovieClipLoader?

[skald]

в каком смысле сглаживать?
после увеличения?? или просто заблерить?

[Cha]

без увеличения. до поворота горизонтальные и вертикальные края картинки ровные, граница идет по прямой линии. после поворота линия границы становится похожей на лесенку)
могу скрин приложить, если объяснил непонятно.

[iNils]

Загнать картинку в BitmapData, и выводить ее со сглаживанием.

[Cha]

ога, в BitmapData то понятно как это сделать. но как загнать в него картинку, грузящуюся MoveiClipLoader'ом? Подскажите пожалуйста!
сейчас реализовано так:

function LoadPhoto(i){
		_root.pages.cont2.mcl = new MovieClipLoader ();
		_root.pages.cont2.mcl.addListener (this);
		num = "ph" + i;
		_root.pages.cont2.s = _root.pages.cont2.pic.duplicateMovieClip ("ph" +i, 999 - i);
 
		if (i < 10) {
			var adress = "images/Концерты/concert_0" + i + ".jpg";
		} else {
			var adress = "images/Концерты/concert_" + i + ".jpg";
		}
		_root.pages.cont2.mcl.loadClip (adress, _root.pages.cont2.s);		
		this.onLoadInit = function (target:MovieClip){
			trace("Iz load photo: "+target);
			_global.lower_level--;
			_global.lower_element=i;
			var phw = (736 - target._width) / 2;
			var phh = (572 - target._height) / 2;			
 
			_global["pocazatel_x"+i]=-377+phw+(7*rotations[i]);
 
			target._x = -377+phw+(2*rotations[i]);
			target._y = -287+phh-(2*rotations[i]);	
			target._rotation = rotations[i];
			trace("ROTATION "+target+" = "+target._rotation);
			 _global.nextph++;
			trace("---");
			if(_global.nextph <= _global.N1)
				nextFrame();
 
 
		}
	}

[Art_133]

Только недавно делал подобное. Может поможет

import flash.display.*;
 
// Создаём загрузчик и т.п.
mcl.onLoadInit = function() {
 
		var bmpData1:BitmapData = new BitmapData(1000, 1000, true, 0x0);
	bmpData1.draw(container);
	container.attachBitmap(bmpData1,2,"auto",true);
};
 
mcl.loadClip(_root.pic,container);

[Cha]

Art_133, спасибо большое, загнать картинку получилось!
но, возникла проблема с BitmapData, картинка не сглаживается, хотя ставлю сглаживание - true. и на простом тестовом примере тоже не пашет.
посмотрите пожалуйста в приложении мой тестовый пример, и если можете, подскажите, почему нет сглаживания?

[Cha]

Или может у кого есть исходник с работающим сглаживанием BitmapData? Помогите плиииз, очень надо!

[scarbo]

Уважаемый,а Вы не тот клип то крутите,Вам надо крутить pic,а не tmpic.
Посмотрите куда у Вас битмапа аттачится.
Вот так должно быть:

import flash.display.*;
_root.createEmptyMovieClip("pic",_root.getNextHighestDepth());
_root.createEmptyMovieClip("tmpic",_root.getNextHighestDepth());
var l:MovieClipLoader = new MovieClipLoader();
var lo:Object = new Object();
l.addListener(lo);
lo.onLoadInit = function(tmpic) {
	var bitmap:BitmapData = new BitmapData(tmpic._width, tmpic._height, true, 0);
	bitmap.draw(tmpic);
	pic.attachBitmap(bitmap,2,"auto",true);
	tmpic.removeMovieClip()
	pic._rotation = 30
	//tmpic._rotation = 2;// сие ошибочка
};
l.loadClip("pic2.jpg",tmpic)

[Cha]

scarbo, огромное спасибо тебе! теперь всё получилось. понял свою ошибку.