подгрузка html в swf.

[DimDima]

Здравствуйте, уважаемые пользователи данного форума
У меня есть вопрос, думаю Вам не составит труда ответить мне на него.
Рисую во флэше давно и хорошо, но никогда небыло такого опыта.
Нужно что бы в конце (мультика) в последней сцене были указаны тел. адрес и тп... так вот они должны быть в html. Как сказал заказчик: "Текст, который будет на заключительном экране, должен подгружаться из файла. в формате html." так вот как это сделать.? как сделать эту самую подгрузку?
Всем заранее спасибо огромное!

[vrabik]

loadVariablesNum("filename.htm", 0);

[CEBEP]

Флеш поддерживает скудный набор тегов HTML (если не вру HTML1), всё остальное игнорит.

[vrabik]

Вот пример для ActionScript 3.0

package {
	import flash.display.*;
	import flash.text.*;
	import flash.events.*;
	import flash.net.*;
	public class HTMLloading extends Sprite {
		private var _output:TextField;
		public function HTMLloading() {
			initializeOutput();
			loadData();
		}
		private function initializeOutput():void {
			_output=new TextField  ;
			_output.width=stage.stageWidth;
			_output.height=stage.stageHeight;
			addChild(_output);
		}
		private function loadData():void {
			var loader:URLLoader=new URLLoader  ;
			// Указываем загрузчику, что файл читать как простой 
			// текст - эту строку можно опустить, поскольку 
			// dataFormat по умолчанию URLLoaderDataFormat.TEXT. 
			loader.dataFormat=URLLoaderDataFormat.TEXT;
			// Регистрируем обработчик события завершения загрузки данных 
			loader.addEventListener(Event.COMPLETE,handleComplete);
			// Загружаем HTML-текст из файла example.html 
			loader.load(new URLRequest("example.html"));
		}
		private function handleComplete(event:Event):void {
			var loader:URLLoader=URLLoader(event.target);
			// Присваиваем свойству htmlText текстового поля 
			// HTML-текст из example.html. Свойство data 
			// экземпляра URLLoader - это содержимое файла, 
			_output.htmlText=loader.data;
		}
	}
}