Растягивание BitmapData

[Котяра]

Нужно растянуть битмапдату по x или y.
Как это сделать не создавая объекта Bitmap?
Т.е. вариант с использованием

/**
		 * Растягивание битмапдаты
		 * @param	bitmapData 		исходное изображение
		 * @param	w				ширина
		 * @param	h				высота		
		 * @return					растянутое изображение
		 */
		public static function stretchBitmap(bitmapData:BitmapData,w:int,h:int):BitmapData
		{
			var ret:BitmapData = new BitmapData(w, h,true,0);
			var bitmap:Bitmap = new Bitmap(bitmapData);
			var matrix:Matrix = new Matrix();
			var sx:Number = w / bitmapData.width;
			var sy:Number = h / bitmapData.height;
			matrix.scale(sx, sy);
			ret.draw(bitmap,matrix);
			return ret;
		}

не подходит (по религиозным соображениям )
Может кто предложит алгоритм растягивания основанный на copyPixels?

Ps:модераторы: измените пожалуйста название темы - очепятка.

[flash33]

Если такой алгоритм и есть, он очень долгий для флеш, возможно в шейдере это будет работать быстрее, но если не заморачиваться, то трансформ самое то. А что за религия такая строгая?

[Котяра]

Религиозный вопрос в создании лишнего экземпляра bimap. Пока пусть будет как есть.. интерфейс ф-ции не поменяется в дальнейшем.. и хорошо)

[flash33]

А что битмап, каши просит? Создали его локально, локально уничтожили.

[iNils]

А почему не сразу новый bitmapData с draw и матрицей? А copyPixels это

Представляет собой процедуру быстрой обработки точек изображений без растяжения, поворота и цветовых эффектов.

[Котяра]

Сообщение от iNils

А почему не сразу новый bitmapData с draw и матрицей?

хм.. в описании ф-ции draw написано следующее:

Экранный объект или объект BitmapData для рисования объекта BitmapData. Классы DisplayObject и BitmapData реализуют интерфейс IBitmapDrawable

.

То, что можно использовать битмапдату сразу, я как-то упустил)))))
вопрос и соответственно сам топик самоуничтожились)

               /**
		 * Растягивание битмапдаты
		 * @param	sourceBitmapData 		        исходное изображение
		 * @param	w						ширина
		 * @param	h						высота		
		 * @return							растянутое изображение
		 */
		private static function stretchBitmap(sourceBitmapData:BitmapData,w:int,h:int):BitmapData
		{
			var ret:BitmapData = new BitmapData(w, h,true,0);
			var matrix:Matrix = new Matrix();
			var sx:Number = w / sourceBitmapData.width;
			var sy:Number = h / sourceBitmapData.height;
			matrix.scale(sx, sy);
			ret.draw(sourceBitmapData,matrix);
			return ret;
		}