включение в код ролика через тег Embed

[firsoff]

[Embed(source='../../../../../assets/rate.swf')]
private var _rateSWFClass:Class;
private var _rate:MovieClip;
.........................................
.........................................
 
_rate = new _rateSWFClass() as MovieClip;

почему totalFrames = 0.
пробовал EnterFrame подключить все время = 0, хотя на таймлайне 5 кадров.

[silin]

когда ты ембедишь флешку целиком, то это некий контейнер, в котором находится лоадер, в который грузится основной таймлайн флешки,
вот так увидишь:

public class Main extends Sprite 
{
	[Embed(source='rate.swf')]
	private var _rateSWFClass:Class;
	private var _rate:MovieClip;
	private var _loader:Loader;
 
	public function Main():void 
	{
		_rate = new _rateSWFClass() as MovieClip;
		_loader = Loader(_rate.getChildAt(0));
		_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
	}
 
	private function onComplete(event:Event):void 
	{
		var mc:MovieClip = _loader.content as MovieClip;
		trace( "mc.totalFrames : " + mc.totalFrames );
	}
}

дешевле положить этот таймлайн в библиотечный смимвол и эмбедить его

[Embed(source='rate.swf',symbol="rateSymbol")]
private var _rateSWFClass:Class;
private var _rate:MovieClip= new _rateSWFClass() as MovieClip;

в таком раскладе _rate будет мувиком без всяких оболочек