запустить функцию в главной swf

[54321go]

У меня есть главный клип main, в него гружу temp. В main есть функция goVideo() мне надо её вызвать из temp.

MovieClip(root).goVideo()

Так не получается.

[bav]

Попробуйте диспачить событие в temp, ловить его в main, и в ответ на него запускать свою функцию.

[54321go]

А сделать в main функцию которую видно в temp можно?

[bav]

Можно. Вот например:
Подгружаемая флешка:

package  
{
    import flash.display.MovieClip;
    import flash.events.Event;
 
    public class Test extends MovieClip
    {
        public function Test():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
 
        private function init(event:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
 
            if (parent != stage)
                parent["parentFunc"]();
            else
                trace("in child");
        }
    }
}

Главная (подгружающая) флешка:

package  
{
    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.net.URLRequest;
 
    public class Main extends MovieClip
    {
        public function Main():void
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
 
        private function init(event:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
 
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            loader.load(new URLRequest("test.swf"));
        }
 
        private function loadHandler(event:Event):void
        {
            var mc:MovieClip = event.target.content as MovieClip;
            addChild(mc);
        }
 
        // обратите внимание на спецификатор public
        public function parentFunc():void
        {
            trace("in parent");
        }
    }
}

[Vishapakahr]

да , public static function myFunc():*{} в temp е вызеваеш main.myFunc();

[cleptoman]

передать ссылку на main в temp.

но не нужно.

Добавлено через 1 минуту
Vishapakahr, не надо сбивать с толку. вы написали метод класса, тогда как нужен метод экземпляра.