[Papervision] Назначить интерактивную карту

[TanaTiX]

Есть 3Д-фигура(сфера). Необходимо назначить в качестве материала мувик/спрайт так, чтоб сохранить его интерактивность (мышиные события и пр.) При назнаначении объекту Sphere материала MovieMaterial похоже, что объект преобразуется в битмапу. С pv3d раньше дел не имел, поэтому ответ может быть очевидным, но найти не получилось... Заранее спасибо.

Upd. Тема уже не актуальна, но интересует вопрос как такое можно реализовать. Движок значения не имеет.

[cr0w312]

мувиклипы так и остаются мувиклимпами(в битмап ничего не конвертируется, кнопки остаются кнопками, текстовые поля - полями).
Если в примере чего будет не понятно, прокомментирую

package {
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Rectangle;
	import flash.text.TextField;
 
	import org.papervision3d.materials.MovieAssetMaterial;
	import org.papervision3d.materials.utils.PrecisionMode;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;
 
	public class InteractiveMaterial extends BasicView
	{
		private var plane:Plane;
 
		public function InteractiveMaterial()
		{
			stage.frameRate = 40;
 
			init();
			startRendering();
		}
 
		private function init():void
		{
			viewport.interactive = true;
 
			var material:MovieAssetMaterial = new MovieAssetMaterial("material",false,true,false,true);
			material.doubleSided = true;
			material.rect = new Rectangle(0,0,200,200);
			material.smooth = true;
			material.precisionMode = PrecisionMode.STABLE;
			material.interactive = true;
 
			MovieClip(MovieClip(material.movie).getChildByName("btn")).mouseChildren = false;
			MovieClip(material.movie).getChildByName("btn").addEventListener(MouseEvent.CLICK,click);
			MovieClip(material.movie).getChildByName("btn").addEventListener(MouseEvent.MOUSE_OVER,mouseOver);
			MovieClip(material.movie).getChildByName("btn").addEventListener(MouseEvent.MOUSE_OUT,mouseOut);
 
			plane = new Plane(material,500,500);
			scene.addChild(plane);
		}
 
		private function click(e:MouseEvent):void
		{
			var buttonText:TextField = MovieClip(e.target).getChildByName("label") as TextField;
			switch(buttonText.text)
			{
				case "start":
					buttonText.text = "stop";
					MovieClip( MovieClip(e.target).parent ).play();
				break;
				default:
					buttonText.text = "start";
					MovieClip( MovieClip(e.target).parent ).stop();
			}
		}
 
		private function mouseOver(e:MouseEvent):void
		{
			viewport.buttonMode = true;
		}
 
		private function mouseOut(e:MouseEvent):void
		{
			viewport.buttonMode = false;
		}
 
		override protected function onRenderTick(e:Event=null):void
		{
			plane.localRotationY++;
			super.onRenderTick();
		}
	}
}