<img> в htmlText

[OutSide]

Можно встроить графику или любой DisplayObject либо указать URL-адрес местоположения графики.

Можно вставить картинку из URL источника:
text.htmlText += "<img src=\"http://blablabla.ru/123.jpg\" />"

А как вставить просто графику или DisplayObject, которые загружены в сам флеш?

[Wolsh]

В новой технологии TLF это возможно "нативными" методами. При использовании обычного TextField такое возможно только через энное место. Но - возможно.

[OutSide]

В новой технологии TLF это возможно "нативными" методами

Дай пожалуйста код, как. Сегодня с утра уже начал изучать TLF потихоньку, но пока так и не понял как это указать

[Wolsh]

package 
{
	import flash.text.engine.*;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
 
	public class Main extends Sprite 
	{
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.showDefaultContextMenu = false;
			// entry point
			// Текстовые элементы:
			var fd:FontDescription = new FontDescription("Arial");
			var format:ElementFormat = new ElementFormat(fd);
			var string1:TextElement = new TextElement("The HTML importer now preserves unrecognized element tags, for example <foo>Text</foo>", format);
			var string2:TextElement = new TextElement(", by creating a TLF element and setting its typeName to be an element of that tag.", format);
			// Графический элемент:
			var sprite:Sprite = new Sprite();
				sprite.graphics.beginFill(0x000000);
				sprite.graphics.drawCircle(16, 16, 16);
				sprite.graphics.beginFill(0xFF0000);
				sprite.graphics.drawCircle(16, 16, 10);
			var image:GraphicElement = new GraphicElement(sprite, 32, 32, format);
			// Группируем элементы:
			var content:GroupElement = new GroupElement(Vector.<ContentElement>([string1, image, string2]));
			// Создаем абзац:
			var tb:TextBlock = new TextBlock(content);
			// Создаем блок Отображения:
			var textLine:TextLine = tb.createTextLine();
			addChild(textLine);
			textLine.x = 50, textLine.y = 50;
		}
	}
}

[OutSide]

Wolsh, Спасибо. А можно это как то прикреплять к TLFTextField? через htmlText например. Или нужно к TextLine, приведенному выше прикреплять слайдер? И если к TLFTextField прикрепить нельзя, можно ли текстлайн сделать выделяемым текстом?

Еще вот нашел:
http://livedocs.adobe.com/flash/9.0/...=00000937.html

Но это для АС2, На АС3 это вообще не работает?

http://www.flasher.ru/forum/showthread.php?t=123787 - в ту же дверь..

Добавлено через 34 часа 9 минут
никто не знает?(

[zerAlex2]

TLF пока глючный. Смотрите аккуратнее, а то потом всё переделывать придется.

[NikolyA]

через CDATA

[OutSide]

как именно? пример пожалуйста..