как в приложении сохранять данные после выхода из него?

[Артур177]

как можно без сервера сделать так что бы предложение после выхода сохраняло данные? есть предложение (я его прикрепил к вопросу) которое осуществляет вход только если в пароле написать "123" а так оно сохраняет данные и после входа показывает их.. я хочу чтобы после того как я выйду с его и войду заново то эти данные сохранялись. как мне это сделать??

[strangedk]

http://www.flasher.ru/forum/showthread.php?t=181983

[CyberDude]

package utils
{
	import flash.display.Sprite;
	import flash.net.SharedObject;
 
	public class Saver extends Sprite
	{
		private static var sharedObject:SharedObject;
 
		public function Saver()
		{
			super();
		}
 
		/**
		 * Инициализация хранилища.
		 * @param name - название хранилища.
		 * 
		 */		
		public static function init (name:String):void
		{
			sharedObject = SharedObject.getLocal(name);
		}
 
		/**
		 * Сохранение данных.
		 * @param name - имя сохраняемого свойства.
		 * @param data - сохраняемые данные.
		 * 
		 */		
		public static function save (name:String, data:*):void
		{
			sharedObject.data[name] = data;
		}
 
		/**
		 * Загрузка данных.
		 * @param name - имя загружаемого свойства.
		 * @return
		 * 
		 */		
		public static function load (name:String):*
		{
			var response;
			if (sharedObject.data[name])
			{
				response = sharedObject.data[name];
			}
			else
			{
				response = undefined;
			}
			return response;
		}
 
		/**
		 * Проверка есть ли доступное сохранение.
		 * @param name - имя сохранённого свойства.
		 * @return - доступно или нет.
		 * 
		 */		
		public static function checkData(name:String):Boolean
		{
			return (sharedObject.data[name] != undefined);
		}
 
		/**
		 * Очистить опредеённое свойство.
		 * @param name - имя свойства.
		 * 
		 */		
		public static function clear (name:String):void
		{
			delete sharedObject.data[name];
		}
 
		/**
		 * Очистить все данные связанные с данным приложением.
		 * 
		 */		
		public static function clearAll ():void
		{
			delete sharedObject.clear();
		}
	}
}