залить спрайт картинкой

[yaflasher]

Здравствуйте!
Создал спрайт

this.sprite = new Sprite();
this.sprite.graphics.lineStyle(1, 0, 1);
this.sprite.graphics.beginFill(0xFF0000);
 
				var intt:int;
				intt=150;
				this.sprite.graphics.moveTo(1, 60);
                this.sprite.graphics.lineTo(intt, 60-intt/4);
				this.sprite.graphics.lineTo(intt, 60-intt/4+90);
				this.sprite.graphics.lineTo(1, 60-1/4+90);
 
 
                this.sprite.graphics.endFill();

Вместо красного цвета, мне надо его залить текстурой из файла. Как я понял, копаясь в мануалах, надо вместо this.sprite.graphics.beginFill(0xFF0000); использовать this.sprite.graphics.beginBitmapFill();
Вопрос! Как все-таки залить текстурой из файла? Покажите пример кода, если можно. Я все перерыл так и не понял. В гугле в основном на adobe.com все ссылается, но там скудное пояснение.
Впоследствии я хочу еще эту фигуру трансформировать с помощью Matrix.

[caseyryan]

С помощью файла - никак.
Сначала нужно одним из способов (embed, загрузка Loader'ом, или ссылка из библиотеки флеша) вставить этот файл в код, чтобы привязать его к переменной с типом Bitmap или BitmapData (в зависимости от того, как он был прикреплен), скажем он прикреплен к переменной

var someImage:BitmapData = new SomeImage() as BitmapData; // допустим в библиотеке флеша он был экспортирован для ActionScript в класс SomeImage

а дальше все просто, вместо

sprite.graphics.beginFill(0xFF0000);

пишем

sprite.graphics.beginBitmapFill(someImage);

[yaflasher]

Сообщение от caseyryan

чтобы привязать его к переменной с типом Bitmap или BitmapData (в зависимости от того, как он был прикреплен)

Вот этот момент я и не могу понять. Я картинку на сцену добавляю лоадером, все ок. А как ее привязать к BitmapData не доходит до меня.
Пробую вот так, не работает:

var loaderr = new Loader();			
var fileRequessst:URLRequest = new URLRequest("big.jpg");
loaderr.load(fileRequessst);
 
var someImage:BitmapData = loaderr as BitmapData; 
 
this.sprite.graphics.beginBitmapFill(someImage);

[belv]

Во-первых нужно дождаться пока будет загружен ваш jpeg.Для этого добавляем слушатель события Event.COMPETE
Второе : Вы пытаетесь привести объект Loader к типу данных BitmapData , что вызывает ошибку.
Вот так работает

import flash.display.Loader;
import flash.events.Event;
import flash.net.URLRequest;
import flash.display.BitmapData;
 
 
 
var loaderr = new Loader();			
var fileRequessst:URLRequest = new URLRequest("big.jpg");
loaderr.contentLoaderInfo.addEventListener(Event.COMPLETE, completeListener);
loaderr.load(fileRequessst);
 
function completeListener(e:Event):void
{
	var someImage:BitmapData = e.target.content.bitmapData as BitmapData;
	var sprite = new Sprite();            
    sprite.graphics.beginBitmapFill(someImage);
    sprite.graphics.drawRect(0, 0, 550,400);
    sprite.graphics.endFill();
    addChild(sprite);
}

[yaflasher]

спасибо, то, что надо