Глюки при работе с Path

[ommm]

Здравствуйте
Есть задача автоматически генерировать карту области. Объекты карты(районы) лежат в виде набора Path'ей в XML. На каждый район при создании назначается event при срабатывании которого отображается информация. Саму процедуру отрисовки я написал но возникла такая проблема - при выборе некоторых районов происходит выбор соседнего района

как с этим бороться или кто предложит лучший вариант этой задачи

import mx.collections.XMLListCollection;
import mx.events.FlexEvent;
import mx.graphics.IFill;
import mx.graphics.IStroke;
import mx.graphics.SolidColor;
import mx.graphics.SolidColorStroke;

import spark.components.Button;
import spark.primitives.Graphic;
import spark.primitives.Path;

private var fill_MouseOut:IFill=new SolidColor(0xFEFEE9,1.0);
private var fill_MouseOver:IFill=new SolidColor(0xFFCC00,1.0);

private var stroke:IStroke=new SolidColorStroke(0x646464, 0.1, 1.0, false, "normal", "none", "miter", 10);

protected function initAction():void
{
	for (var id:String in myXML.area)
	{
		var name:String=myXML.area.@name[id];
		var x:Number=myXML.area.@x[id];
		var y:Number=myXML.area.@y[id];
		var data:String=myXML.area.@data[id];

		var path:Path=new Path();
		path.data=data;
		path.winding="nonZero";
		path.fill=fill_MouseOut;
		path.stroke=stroke;

		var dist:Graphic=new Graphic();
		dist.addElementAt(path,0);
		dist.name=name;
		dist.id="dist_"+id;
		dist.x=x;
		dist.y=y;
					
		dist.addEventListener(MouseEvent.ROLL_OVER, MouseOver);
		dist.addEventListener(MouseEvent.ROLL_OUT, MouseOut);

		addElement(dist);
	}
}

public function MouseOver(event:MouseEvent):void
{
	txt.text=event.currentTarget.name;
	event.currentTarget.getElementAt(0).fill=fill_MouseOver;
}

public function MouseOut(event:MouseEvent):void
{
	event.currentTarget.getElementAt(0).fill=fill_MouseOut;
}

прикрепил архив с mxml и xml

[alatar]

Добавьте:

dist.mouseEnabledWhereTransparent = false;

[ommm]

2 alatar

помогло спасибо )