Проблема с наследуемым от URLLoader классом

[DimG]

Добрый день, столкнулся со следующей проблемой:
есть наследуемый от URLLoader класс:

package main
{
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.events.*;
	import main.*;
	
	public class xmlData extends URLLoader
	{
		public static var  iconsList:XML = null;
		
		public function xmlData():void
		{
			super();
		}
		public function loadIconsList():void
		{
			var request:URLRequest = new URLRequest("data/List.xml");
			addEventListener("complete",onComplete);
			load(request);
		}
		
		public function onComplete(event:Event):void
		{
			iconsList = XML(URLLoader(event.target).data);
			trace(URLLoader(event.target));
			trace(iconsList);
			removeEventListener("complete",onComplete);
			
		}
	}
}

из другого файла создаю объект xmlData, вызываю ф-ию loadIconsList();
в output выводит:

TypeError: Error #1034: Type Coercion failed: cannot convert flash.net::URLStream@4254461 to flash.net.URLLoader.
	at main::xmlData/onComplete()

проверял в debugger'e, всюду выходит так что event.target у ф-ии onComplete ссылается на объект класса URLStream,а не URLLoader, как ожидалось . Откуда он там взялся? Причем св-во data = undefined. Если заменить

URLLoader(event.target)

на просто data, то, естественно, ничего не получается, т.к. data = undefined. Если загружать файл стандаотным спосбом(создавая объект URLLoader, вешая слушатель на него), то в ф-ии, на которую слушатель указывает, event.target указывает на объект URLLoader и все в порядке. Объясните, пожалуйста, что происходит. Надеюсь все понятно изложил.

[wvxvw]

package
{
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.events.*;
	
	public class XMLData extends URLLoader
	{
		public var iconsList:XML;
		
		public function XMLData():void
		{
			super();
			addEventListener(Event.COMPLETE, onComplete);
			addEventListener(IOErrorEvent.IO_ERROR, onIOError);
		}
		public function loadIconsList():void
		{
			var request:URLRequest = new URLRequest("test.xml");
			load(request);
		}
		
		private function onComplete(event:Event):void
		{
			iconsList = XML((event.target as URLLoader).data);
			trace(event.target is URLLoader);
			trace(iconsList);
		}
		private function onIOError(evt:IOErrorEvent):void
		{
			trace(evt.text)
		}
	}
}

import XMLData;
var xd:XMLData = new XMLData();
xd.loadIconsList();

Output:

true
<data>
  <foo/>
</data>

У меня все работает в таком виде...
Не называйте классы с маленькой буквы, используйте константы вместо их строковых значений. А вообще, ошибка, скорее всего не в этом коде, просто, наверное, классы перепутали, и не тот использовали...

[DimG]

package main 
{
	import flash.events.Event;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	
	public class Myloader extends URLLoader
	{
		
		public function Myloader() 
		{
			super();
			
			addEventListener( Event.COMPLETE, onComplete);
			load(new URLRequest("data/list.xml"));
			
			
		}
		
		public function onComplete(e:Event):void
		{
			
			trace(e.target is URLLoader);
			trace(data);
		}
		
	}
	
}

скажите, а чем Ваш код принципиально отличается от выше приведенного?
Мой код не работает, Flash упорно выводит false и undefined. Ваш код прекрасно работает.
Ужас какой-то(((

[wvxvw]

Ошибка оказалась интересной =) очевидно, у URLLoader есть публичный метод onComplete() т.е. если я делаю его приватным, то все работает, если публичным - такой же результат, как и у вас. Соответсвенно, если меняю название на что-то другое - то тоже работает =)
Т.е. нужно понимать, что схема с евентами построена по принципу АС2 EventDispatcher'a:
Т.е. когда мы добавляем функцию в слушателей диспатчер создает у этого объекта дополнительную функцию с именем события, на которое мы подписались, которая и будет вызвана когда случится событие и уже она вызовет подписаную функцию.

[DimG]

действительно, так все работает.Спасибо за помощь! =)