Zoom с помощью transitions

[DrugON]

function loaderCompleteHandler(evt:Event):void {
	var vars:URLVariables = new URLVariables();
	vars.decode(evt.currentTarget.data);
	pictures = new Array();
	transitions = new Array();
	for (var i:int = 0; i < vars.Totalnumber_of_entries; i++) {
		try {
			var picture:Picture = new Picture(vars["foto_url" + i]);
			addChild(picture);
			pictures.push(picture);
			picture.posX = 100;
			picture.posY = 100;
			picture.addEventListener(MouseEvent.MOUSE_OVER, mouseOverBox);
		} catch (err:Error) {
			trace("BAD");
		}
	}
}
 
function mouseOverBox(evt:Event):void {
	var selectedBox:MovieClip = MovieClip(evt.target);
	selectedBox.removeEventListener(MouseEvent.MOUSE_OVER, mouseOverBox);
	var myTransitionManager:TransitionManager = new TransitionManager(selectedBox);
	myTransitionManager.startTransition({type:Zoom, direction:Transition.IN, duration:1, easing:Regular.easeOut, shape:Iris.CIRCLE});
	transitions.push(myTransitionManager);
	myTransitionManager.addEventListener("allTransitionsInDone", animationComplete);
}
 
function animationComplete(evt:Event):void {
	evt.target.content.addEventListener(MouseEvent.MOUSE_OVER, mouseOverBox);
}

Не получается сделать zoom для картинок. При наведении на картинки пишет ошибку

TypeError: Error #1034: Type Coercion failed: cannot convert Picture@10e2cd29 to flash.display.MovieClip.
	at index_fla::MainTimeline/mouseOverBox()

Помогите разобраться.

[CrazyFlasher]

попробуйте так...а еще лучше покажите класс Picture

var selectedBox:Picture = evt.target as Picture;

хотя если Picture экстендит MovieClip, то проблемы не должно быть

[cihexe]

сравни это :

                                  var picture:Picture = new Picture(vars["foto_url" + i]);
			addChild(picture);
			pictures.push(picture);
			picture.posX = 100;
			picture.posY = 100;
			picture.addEventListener(MouseEvent.MOUSE_OVER, mouseOverBox);

и это:

var selectedBox:MovieClip = MovieClip(evt.target);

попробуй подставить:

var selectedBox:Picture = Picture(evt.target);

[DrugON]

вот класс Picture

package {
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.*;
	import flash.display.Bitmap;
	public class Picture extends Sprite {
		public var posX:Number;
		public var posY:Number;
		public function Picture(url:String):void {
			var urlRequest:URLRequest = new URLRequest(url);
			var loader:Loader = new Loader();
			loader.load(urlRequest);
			loader.contentLoaderInfo.addEventListener(Event.INIT, initListener);
		}
		private function initListener(event:Event):void {
			var bmp:Bitmap = event.target.content;
			bmp.x = -bmp.width/2;
			bmp.y = -bmp.height/2;
			addChild(bmp);
		}
	}
}

cihexe исправил как вы сказали получил ошибку

1067: Implicit coercion of a value of type Picture to an unrelated type flash.display:MovieClip.

[CrazyFlasher]

public class Picture extends Sprite {

ну правильно делает, что кидает ошибку.

делайте так

var selectedBox:Picture = evt.target as Picture;

или так

var selectedBox:Sprite = evt.target as Sprite;

[DrugON]

CrazyFlasher в первом варианте выдает ошибку

1067: Implicit coercion of a value of type Picture to an unrelated type flash.display:MovieClip.

а во втором

1118: Implicit coercion of a value with static type flash.display:Sprite to a possibly unrelated type flash.display:MovieClip.

[cihexe]

тебе проще зайти в дебаггер, и поставить брейпоинт на

var selectedBox:MovieClip = MovieClip(evt.target);

и посмотреть что именно приходит в

evt.target

(просто добавь в watches)

Добавлено через 1 минуту
а лучше проверь

evt.currentTarget

если у тебя MouseEvent

[DrugON]

Ни чего не приходило.
Просто в классе поменял Sprite на MovieClip. Сейчас ошибку не пишет.

[cleptoman]

var bmp:Bitmap = event.target.loader.content as Bitmap;

[DrugON]

cleptoman, спасибо! Работает, как хотелось!