Проблема с масштабированием

[oleg989]

Привет. написал такой код. при наведении курсора клип плавно масштабируется. но только один раз. когда навожу второй раз клип масштабируется резко и не полностью.
даю сам код. посмотрите.(только не строго судите - я два дня как AS3 програмист).

var xMax:Number = 100;
var xMin:Number = 50;	
///////////////////////////////////////////////////
clp.addEventListener(MouseEvent.MOUSE_OVER, zoomIN);
function zoomIN(e:MouseEvent):void{
 
		addEventListener(Event.ENTER_FRAME, prr); 
			function prr(e:Event):void{
				for (var i:Number=clp.width; i<xMax; i++){
  					clp.width +=.2;
    				clp.height +=.2;
				}
			}
		}
////////////////////////////////////////////////////
clp.addEventListener(MouseEvent.MOUSE_OUT, zoomOUT);
function zoomOUT(e:MouseEvent):void{
 
		addEventListener(Event.ENTER_FRAME, prr); 
			function prr(e:Event):void{
				for (var i:Number=clp.width; i>xMin; i--){
					clp.width -=.2;		
					clp.height -=.2;
				}
			}	
		}

[proxiServer]

делайте removeEventListener в функции prr()

[oleg989]

добавляю вот эту строчку

clp.removeEventListener(Event.ENTER_FRAME, prr);

не работает. вставлял повсюду(в цикл, за циклом)...

[proxiServer]

на всякий случай. в обе функции вставляете эту строчку?

Думаю с циклами вы намудрили. Читаемость хромает, отсюда и ошибка вылезла скорей всего. Так с ходу не пойму.

var xMax:Number = 50;
 
///////////////////////////////////////////////////
clp.addEventListener(MouseEvent.MOUSE_OVER, zoomIN);
function zoomIN(e:MouseEvent):void{
 
		addEventListener(Event.ENTER_FRAME, prr); 
			function prr(e:Event):void{
				for (var i:Number=0; i<xMax; i++){
  					clp.width +=.2;
    				clp.height +=.2;
				}
			}
		}
////////////////////////////////////////////////////
clp.addEventListener(MouseEvent.MOUSE_OUT, zoomOUT);
function zoomOUT(e:MouseEvent):void{
 
		addEventListener(Event.ENTER_FRAME, prr); 
			function prr(e:Event):void{
				for (var i:Number=0; i<xMax; i++){
					clp.width -=.2;		
					clp.height -=.2;
				}
			}	
		}

Почему не так сделали?

И в цикле счетчиком лучше int делать или uint.

[oleg989]

ок. спасибо.

[Котяра]

блин, ненавижу кложуры..
нельзя было сделать вместо двух вложенных prr - два нормальных метода? zoomInEnterFrameHandler и zoomOutEnterFrameHandler ?
или слишком много букоф печатать надо?

а ремувлистенер не работает потому что после выхода из ф-ции zoomOUT или zoomIN нет никакого prr - это локальная ф-ция.

И вообще: код в кадрах писать на надо.

[proxiServer]

Котяра, так я же предлагал в обе функции prr вставить удаление листнера. так же нормлально?

[Котяра]

zoomClip.zip

package  
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	public class ZoomedClip extends Sprite
	{
		private var xMax:int = 100;
		private var xMin:int = 50;
		private var zoomSpeed:Number = 2;
 
		public function ZoomedClip() 
		{
			super();
			addEventListener(MouseEvent.MOUSE_OUT, zoomOUT);
			addEventListener(MouseEvent.MOUSE_OVER, zoomIN);
		}
 
		private function zoomIN(e:MouseEvent):void 
		{
			stopZoom();
			addEventListener(Event.ENTER_FRAME, drawZoomIN); 
		}
 
		private function stopZoom():void
		{
			removeEventListener(Event.ENTER_FRAME, drawZoomIN); 
			removeEventListener(Event.ENTER_FRAME, drawZoomOUT);
 
		}
 
		private function drawZoomIN(e:Event):void 
		{
			if (width > xMin)
			{
					width -=zoomSpeed;		
					height -= zoomSpeed;
			}
			else
			{
				stopZoom();
			}
 
		}
 
 
		private function zoomOUT(e:MouseEvent):void 
		{
			stopZoom();
			addEventListener(Event.ENTER_FRAME, drawZoomOUT); 
		}
 
		private function drawZoomOUT(e:Event):void 
		{
			if (width < xMax)
			{
					width +=zoomSpeed;		
					height += zoomSpeed;
			}
			else
			{
				stopZoom();
			}
		}	
 
	}
 
}