Случайная выборка из XMLList

[Ivanaka]

Здравствуйте,
Из XMLList, к примеру со ста элементами, необходимо выбрать 10 случайных и уникальных (не повторяющихся) элементов. Как такое реализовать? Пока в голову лезут трехэтажные алгоритмы сомнительной пользы...

[wvxvw]

private function randomTake():void 
{
	var list:XMLList = 
	<>
		<foo attribute="0"/>
		<foo attribute="1"/>
		<foo attribute="2"/>
		<foo attribute="3"/>
		<foo attribute="4"/>
		<foo attribute="5"/>
		<foo attribute="6"/>
		<foo attribute="7"/>
		<foo attribute="8"/>
		<foo attribute="9"/>
	</>;
	var result:XMLList = list.copy();
	while (result.length() > 5)
	{
		delete result[Math.random() * result.length() >> 0];
	}
	trace(result);
}

[Ivanaka]

Спасибо, wvxvw! Работает! Что-то подобное я и имел ввиду, сам бы до такого не додумался

[Astraport]

Пример конечно очень прост, но не перемешивает итемы, они идут по порядку возрастания.

[proxiServer]

Нафига их мешать, если и так выдает в случайном порядке?

[Astraport]

Нафига их мешать, если и так выдает в случайном порядке?

Они все идут примерно так 1,4,5,8,9 или 0,2,3,5,8
Это считаете правильно?

[wvxvw]

Про порядок никто не говорил

private function test():void 
{
    var list:XMLList = 
    <>
        <foo attribute="0"/>
        <foo attribute="1"/>
        <foo attribute="2"/>
        <foo attribute="3"/>
        <foo attribute="4"/>
        <foo attribute="5"/>
        <foo attribute="6"/>
        <foo attribute="7"/>
        <foo attribute="8"/>
        <foo attribute="9"/>
    </>;
    var child:int;
    var result:XMLList = new XMLList();
    while (result.length() < 5)
    {
        child = Math.random() * list.length();
        result += list[child];
        delete list[child];
    }
    trace(result);
}

[proxiServer]

Тьфу) присмотрелся. первый вариант вообще на шутку похож)

[Astraport]

Можно перемешать элементы массива вот так:

protected function randomize(a:Array):void {
				var i:Number = a.length;
				if (i > 0) {
					while (--i) {
						var j:Number = Math.floor(Math.random() * (i + 1));
						var tmpi:Object = a[i];
						var tmpj:Object = a[j];
						a[i] = tmpj;
						a[j] = tmpi;
					}
				}
			}