Аналог кода AS2 на AS3

[kemerover]

Начал изучать AS3, но не понял как сделать аналог attachMovie();
Вот есть такой код, помогите его перевести из AS2 в AS3

add_mc.onPress=function(){//по нажатию на кнопку
	n_of_awar++//увеличиваем число в конце названия мувиклипа
	_root.attachMovie("awarl_mc", "awar"+n_of_awar+"_mc", _root.getNextHighestDepth(), {_x:_xmouse, _y:_ymouse});//добовляем мувик, координаты как у мыши
	_root["awar"+i+"_mc"].startDrag();//мувик автоматически двигается
}

Спасибо!

[DaFive]

В as 3.0 нет метода attachMovie. Клипу в библиотеке нужно дать имя класса, а потом создать экземпляр этого класса.

[kemerover]

Как этот экземпляр создать?

[etc]

new MyMC()

[kemerover]

Ну так у меня же он будет не один, лучше дай полностью аналог этого кода, пожалуйста. Так лучше понять, чем читать какие-то обрывистые команды.

[tsarapkabel]

При условии, что в библиотеке твой MovieClip в связке с классом "Awarl_mc"

var awarl_mc:Awarl_mc;
var n_of_awar:uint = 0;
 
stage.addEventListener(MouseEvent.MOUSE_DOWN, onAwarlDown);
stage.addEventListener(MouseEvent.MOUSE_UP, onAwarlUp);
 
function onAwarlDown(event:MouseEvent):void {
	awarl_mc = new Awarl_mc();
	n_of_awar++;
	trace (n_of_awar);
 
	stage.addChild (awarl_mc);
	awarl_mc.x = mouseX;
	awarl_mc.y = mouseY;
 
	awarl_mc.startDrag();
}
 
function onAwarlUp(event:MouseEvent):void {
	awarl_mc.stopDrag();
}

[kemerover]

спасибо, вот только как ["awar"+n_of_awar+"_mc"] реализовать в AS3? У меня он на это ругается

[tsarapkabel]

Забудь, это тебе не нужно.

[kemerover]

мне надо будет передвигать их в будущем

[tsarapkabel]

Просто реализуй иначе. Я не понимаю полной задачи, но скорее всего тебе не нужны эти имена.

var awarl_mc:Awarl_mc;
var n_of_awar:uint = 0;
 
stage.addEventListener(MouseEvent.MOUSE_DOWN, onAwarlDown);
stage.addEventListener(MouseEvent.MOUSE_UP, onAwarlUp);
 
function onAwarlDown(event:MouseEvent):void {
	awarl_mc = new Awarl_mc();
	n_of_awar++;
	trace (n_of_awar);
 
	stage.addChild (awarl_mc);
	awarl_mc.x = mouseX;
	awarl_mc.y = mouseY;
 
	awarl_mc.startDrag();
}
 
function onAwarlUp(event:MouseEvent):void {
	stopDrag();
	if (n_of_awar == 7) {
		goDrag();
	}
}
 
function goDrag ():void {
	stage.removeEventListener(MouseEvent.MOUSE_DOWN, onAwarlDown);
	stage.removeEventListener(MouseEvent.MOUSE_UP, onAwarlUp);
 
	stage.addEventListener(MouseEvent.MOUSE_DOWN, secondMouseDown);
	stage.addEventListener(MouseEvent.MOUSE_UP, secondMouseUp);
}
 
function secondMouseDown(event:MouseEvent):void {
	if (event.target != stage) {(event.target).startDrag();}
}
function secondMouseUp(event:MouseEvent):void {
	stopDrag();
}

После создания 7-го объекта, awarl_mc перестаёт добавляться на сцену и можно их двигать.