Почему прелоадер не выводит загруженный swf

[CyberGenius]

День добрый. Столкнулся с такой проблемой: прелоадер не хочет выводить загруженный swf использующий API VK.
Код прелоадера:

package 
{
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.ProgressEvent;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
 
	public class Main extends MovieClip 
	{
		private var loadStatus: TextField = new TextField();
		private var loader: Loader = new Loader();
 
		public function Main():void 
		{	
			loader.load(new URLRequest("http://cs6102.vk.com/u122246923/2e6dfe23bf74ce.zip"));
			loader.contentLoaderInfo.addEventListener(Event.OPEN, displayPreloader);
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, OnComplete);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, OnProgress);
		}
		private function displayPreloader(evt: Event): void
		{
			loadStatus.autoSize = TextFieldAutoSize.LEFT;
			addChild(loadStatus);
		}
		private function OnProgress(evt: ProgressEvent): void
		{
			loadStatus.text = evt.bytesLoaded + " из " + evt.bytesTotal + " " + ((evt.bytesLoaded/evt.bytesTotal)* 100 ) + "%";
		}
		private function OnComplete(evt: Event): void
		{
			removeChild(loadStatus);
			addChild(loader);
		}
	}
 
}

код загружаемого swf:

package 
{
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	import vk.APIConnection;
 
	public class Main extends MovieClip 
	{
 
		public function Main():void 
		{
			var FlashVars: Object = stage.loaderInfo.parameters as Object;
			var VK: APIConnection = new APIConnection(FlashVars);
 
			VK.api("putVariable" , { key:1300, user_id:FlashVars.viewer_id, value:"З1" } );
 
			var txt: TextField = new TextField;
			txt.text = "Какой то текст";
			addChild(tTx);
		}
 
 
	}
 
}

Прелоадер имеет функцию, которая выводит процесс загрузки - и прелоадер показывает, что swf загружен. Но после загрузки он не хочет выводится на экран. Если заменить загружаемый swf на другой - не использующий API VK, то после загрузки он выводится на экран. В чем может быть проблема?

[maxkar]

Ставим debug-player и наслаждаемся жизнью и сообщениями об ошибках. Скорее всего, stage в конструкторе загружаемого swf еще равен null. Просто потому, что объект еще не добавлен в список отображения (конструктор то еще не отработал). Смотрите Event.ADDED_TO_STAGE.

А еще я сильно сомневаюсь в наличии loaderInfo у stage а также в том, что loaderInfo.parameters будет тем, что вам нужно. Потрейсите, посмотрите под отладчиком.

[CyberGenius]

жесть, буду разбираться. Спасибо

[caseyryan]

Нужно в подгружаемой флешке добавить код проверки наличия stage:

package 
{
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	import vk.APIConnection;
 
	public class Main extends MovieClip 
	{
 
		public function Main():void 
		{
                                 if (stage) init();
                                 else addEventListener(Event.ADDED_TO_STAGE, init);
 
		}
                      private function init(e:Event = null):void { // тут уже можно делать все остальное
                                removeEventListener(Event.ADDED_TO_STAGE, init);
                                var FlashVars: Object = stage.loaderInfo.parameters as Object;
			var VK: APIConnection = new APIConnection(FlashVars);
 
			VK.api("putVariable" , { key:1300, user_id:FlashVars.viewer_id, value:"З1" } );
 
			var txt: TextField = new TextField;
			txt.text = "Какой то текст";
			addChild(tTx);
                      }
 
	}
 
}

Не отладочная версия плеера просто проглотит ошибку и ничего не выдаст, но ошибка тут явно будет null pointer reference

[CyberGenius]

Аааа, работает!!!! Спасибо тебе большое, добрый человек!