Как записать код с обработчиками событий короче?

[Yulia_V]

Здравствуйте. На сцене присутствует некоторое количество мувиклипов. Как сделать их объектами событий Click (с функцией передачи параметра visible = true разным картинкам), не вешая обработчик событий отдельно на каждый мувиклип? Может класс какой есть для этих целей, или ещё что-нибудь?

[Chum]

Может как то так:

// Заносим мувики в массив
var arr:Array = [mc0, mc1, mc2, mc3];
var arr2:Array = [mc01, mc11, mc21, mc31];
for(var i:int = 0; i < arr.length; i++){
    arr[i].addEventListener(MouseEvent.CLICK, otrabotka);
	function otrabotka(sob:MouseEvent):void{
	    drugaiaFunc(i);
	}
}
 
function drugaiaFunc(arg1:int):void{
    arr2[arg1].visible = false;  // или true;
}

[Asfel]

Вешаешь событие на контейнер, а в событии смотришь таргет, и карент таргет

[amesqit]

Не люблю вложнные функции, они как-то запутывают

var arrButton:Array = [b1, b2, b3, b4];
var arrPicture:Array = [p1, p2, p3, p4];
 
for(var i:int = 0; i < arrButton.length; i++)
{
     arrButton[i].addEventListener(MouseEvent.CLICK, clickListener);
}
 
function clickListener(e:MouseEvent):void
{
     var index :int = arrButton.indexOf(e.currentTarget)
     if(index!=-1)
     {
          arrPicture[index].visible = !arrPicture[index].visible;
     }
}

или если не хочется искать по массиву, по каким-либо соображениям:

var arrButton:Array = [b1, b2, b3, b4];
var arrPicture:Array = [p1, p2, p3, p4];
var dictinaryButton: Dictionary = new Dictionary() 
for(var i:int = 0; i < arrButton.length; i++)
{
     dictinaryButton[arrButton[i]] = arrPicture[i]
     arrButton[i].addEventListener(MouseEvent.CLICK, clickListener);
}
 
function clickListener(e:MouseEvent):void
{
	dictinaryButton[e.currentTarget].visible = !dictinaryButton[e.currentTarget].visible;
}

[Asfel]

Зачем тут вообще массивы какие либо?

[Nooob]

можно просто слушать в родительской контейнере на фазе всплытия

[etc]

bubbling

[Yulia_V]

amesqit Спасибо, в принципе работает! Только вот чего не понимаю: почему я не могу задать свойство visible = false массиву, картинки всё равно видны:

var arrButton:Array = [platki.pl1, platki.pl2, platki.pl3, platki.pl4];
var arrPicture:Array = [platok_1, platok_2, platok_1, platok_1];
arrPicture.visible = false; // Вот эта строчка
 
for(var i:int = 0; i < arrButton.length; i++)
{
     arrButton[i].addEventListener(MouseEvent.CLICK, clickListener);
}
 
function clickListener(e:MouseEvent):void
{
     var index :int = arrButton.indexOf(e.currentTarget)
     if(index!=-1)
     {
          arrPicture[index].visible = true;
     }

[Wolsh]

Потому что массив это не визуальный объект, и у него не может быть свойства, отвечающего за отображение.
Вот если бы ваши платки лежали в одном DisplayObjectContainer (например, Sprite), то можно было бы сделать их видимыми или невидимыми, управляя видимостью этого общего контейнера.

[Yulia_V]

Wolsh, хорошо. Но почему function clickListener тогда работает?