проблема с enabled, возврат нажатие кнопки по условию

[Зубило]

Здравствуйте!
Ответьте вот на такой вопрос-как создать условие например если какой-то мувиклип имеет _Alpha>0 то кнопка неактивна, а если этот мувиклип стал _alpha=0 то кнопка сразу стала активной?Надеюсь вы поняли мой бред

[mooncar]

btn.enabled =  !mc._alpha ;

Этого достаточно.

По поводу "сразу".
Если надо непрерывно отслеживать, то поместите эту строку в onEnterFrame или в функцию под setInterval -ом.
Например так:

mc.onEnterFrame = function  () {
	btn.enabled =  !this._alpha ;
};

[Зубило]

Не мог бы ты сам посмотреть что там не так!?

[mooncar]

smoke.onEnterFrame = function  () {
	but.enabled =  !this._alpha>0;
};

Зачем эта конструкция у вас в onRelease прописана?

А что вы хотите, собственно? Развернуто напишите.

[Зубило]

mooncar при удержании в нажатом состоянии кнопки,идет дым,а при отпускании дым начинает становится прозрачным,так вот я хочу чтобы когда отпущу кнопку и алфа(мувика)>0 кнопка была неактивна,и как только мувик стал полностью прозрачным кнопка опять стала активной!

[mooncar]

import mx.transitions.Tween;
var ea:Number = 0; //конечная альфа
var t:Number = 2; //время на затухание
 
but.onRelease = but.onReleaseOutside = function()
{	
	this.enabled = false ;
	this.useHandCursor = false ; //чтобы "неактивность" была очевидна юзеру
	var tw:Tween = new Tween(smoke, '_alpha', mx.transitions.easing.None.easeNone, smoke._alpha, ea, t, true);
	tw.onMotionFinished  = twEnd; //определяем событие по завершению уменьшения альфы до 0
};
 
but.onPress = function()
{	
	smoke.gotoAndPlay(1);
	smoke._alpha = 100;
	smoke._x = 251;
	smoke._y = 180
};
 
function twEnd() 
{
	but.enabled = true ;
	but.useHandCursor = true ;
}

[Зубило]

Ваш код ругается

[mooncar]

В следующий раз пишите, как именно "ругается".
Обычно там еще слова какие-то бывают

[Зубило]

**Error** Scene=Scene 1, layer=Layer 1, frame=1:Line 10: There is no property with the name 'onMotionFinished'.
     	tw.onMotionFinished  = twEnd; //определяем событие по завершению уменьшения альфы до 0

Total ActionScript Errors: 1 	 Reported Errors: 1

Кстати у меня AS2 ,ваш неподдерживает

[mooncar]

Тогда так попробуйте, без класса Tween:

but.onPress = function()
{
	smoke.gotoAndPlay(1);
	smoke._alpha = 100;
	smoke._x = 251;
	smoke._y = 180
};
 
but.onRelease = but.onReleaseOutside = function()
{
	this.useHandCursor = false ;		
	this.enabled = false ;
	smoke.onEnterFrame = smokeHide;
};
 
function smokeHide() 
{
	if (this._alpha > 0) 
	{
		this._alpha -= 5;
	}
	else 
	{
		delete this.onEnterFrame ;
		but.enabled = true ;
		but.useHandCursor = true ;		
	}
}