1172: Не удалось найти определение fl.controls:Button и другие ошибки

[Bazel]

почему примеры с офф справочника не работают?

вот код

package
{
    import flash.display.MovieClip;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import fl.controls.Button;
 
    public class ButtonExample extends MovieClip
    {
        private var b1:Button;
        private var b2:Button;        
        private var b3:Button;
        private var tf:TextField;
 
        public function ButtonExample() {
            createTraceField();
            setupButtons();
        }
        private function createTraceField():void {
            tf = new TextField();
            tf.width = 200;
            tf.height = 400;
            tf.x = 200;
            tf.y = 10;
            addChild(tf);
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();
            b3 = new Button();
 
            b1.move(10,10);
            b2.move(10,40);
            b3.move(10,70);
 
            b1.label = "Default Button";
            b2.label = "Custom Styled Button";
            b3.label = "Toggleable Button";
            b2.setStyle("textFormat", new TextFormat("Georgia"));
            b3.width = 120;
            b3.toggle = true;
 
            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);
            b3.addEventListener(MouseEvent.CLICK,buttonClick);
 
            addChild(b1);
            addChild(b2);
            addChild(b3);
        }
        private function buttonClick(e:MouseEvent) {
            var button:Button = Button(e.target);
            tf.appendText(button.label + "\n");
        }
    }
}

выдало милион ошибок, ни один тип не распознан что за брэйнфакинг?

Добавлено через 1 минуту
1172: Не удалось найти определение fl.controls:Button.
1180: Вызов предположительно неопределенного метода Button.
1180: Вызов предположительно неопределенного метода Button.
1180: Вызов предположительно неопределенного метода Button.
1180: Вызов предположительно неопределенного метода Button.
1046: Тип не найден или не является константой времени компиляции: Button.
и тд тп

Добавлено через 8 минут
http://help.adobe.com/ru_RU/FlashPla...ls/Button.html
здесь лежит пример в самом самом низу

[Bgg]

Вы это все сделали?

1. Добавьте Button в библиотеку.
2. Сохраните этот код под именем ButtonExample.as в том же каталоге, где и FLA-файл.
3. Присвойте параметру DocumentClass в FLA-файле значение ButtonExample.

Пакет fl доступен только во FlashCS

[Bazel]

у меня FlashCs4 , 2 и 3 пункт да, на первый пункт не обратил внимание..вручную закинуть в папку где все базовые классы лежат? или как?

[incvizitor]

во flash есть такое окошко - компоненты window > components. найдите там компонент button и перетяните его на сцену.

[Bazel]

понял,большое спасибо